RFLU_ModCellFaceEdgeInfo.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Suite of functions to determine information on cell and face 
!   types and kinds, before and after renumbering.
!
! Description: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_ModCellFaceEdgeInfo.F90,v 1.12 2008/12/06 08:44:20 mtcampbe Exp $
!
! Copyright: (c) 2002-2005 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modcellfaceedgeinfo

  USE modglobal, ONLY: t_global
  USE moddatatypes
  USE modparameters
  USE moderror
  USE modgrid, ONLY: t_grid

  USE rflu_modcellmapping

  IMPLICIT NONE

  PRIVATE
  PUBLIC :: rflu_getglobalcelltype, & 
            rflu_getglobalcellkind, &  
            rflu_getvirtualcellreg, &  
            rflu_getfacekind, & 
            rflu_getedgekind
  
  
  
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  
     
  CHARACTER(CHRLEN), PRIVATE :: & 
    RCSIdentString = '$RCSfile: RFLU_ModCellFaceEdgeInfo.F90,v $ $Revision: 1.12 $' 
                            
! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS






! ******************************************************************************
!
! Purpose: Determine global cell type (after renumbering).
!
! Description: None.
!
! Input:
!   global      Pointer to global data
!   pGrid       Pointer to grid data
!   icg         Global cell id
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
  
  INTEGER FUNCTION rflu_getglobalcelltype(global,pGrid,icg)

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    INTEGER, INTENT(IN) :: icg
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_global), POINTER :: global

! ******************************************************************************  
!   Start
! ******************************************************************************  

    CALL registerfunction(global,'RFLU_GetGlobalCellType',&
  'RFLU_ModCellFaceEdgeInfo.F90') 

! ******************************************************************************  
!   Determine global cell type
! ******************************************************************************  

    IF ( icg > 0 ) THEN ! Interior cell
      rflu_getglobalcelltype = pgrid%cellGlob2Loc(1,icg) 
    ELSE IF ( icg == cell_type_bnd ) THEN ! Boundary cell
      rflu_getglobalcelltype = cell_type_bnd
    ELSE IF ( icg == cell_type_ext ) THEN ! Exterior cell
      rflu_getglobalcelltype = cell_type_ext 
    ELSE   
      CALL errorstop(global,err_reached_default,__line__)
    END IF ! icg 

! ******************************************************************************  
!   End
! ******************************************************************************  

    CALL deregisterfunction(global)

  END FUNCTION rflu_getglobalcelltype








! ******************************************************************************
!
! Purpose: Determine global cell kind (after renumbering)
!
! Description: None.
!
! Input:
!   global      Pointer to global data
!   pGrid       Pointer to grid data
!   icg         Global cell id
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  INTEGER FUNCTION rflu_getglobalcellkind(global,pGrid,icg)

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    INTEGER, INTENT(IN) :: icg
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_global), POINTER :: global

! ==============================================================================
!   Locals
! ==============================================================================

    CHARACTER(CHRLEN) :: errorstring
    INTEGER :: icl,ict    

! ******************************************************************************  
!   Start
! ******************************************************************************  

    CALL registerfunction(global,'RFLU_GetGlobalCellKind',&
  'RFLU_ModCellFaceEdgeInfo.F90')

! ******************************************************************************  
!   Get global cell kind
! ******************************************************************************  

    IF ( icg > 0 ) THEN 
      ict = pgrid%cellGlob2Loc(1,icg)
      icl = pgrid%cellGlob2Loc(2,icg)  
    ELSE IF ( icg == cell_type_bnd ) THEN
      ict = cell_type_bnd
    ELSE IF ( icg == cell_type_ext ) THEN 
      ict = cell_type_ext
    ELSE   
      CALL errorstop(global,err_reached_default,__line__)
    END IF ! icg

    SELECT CASE (ict) 
      CASE ( cell_type_tet )
        IF ( icl <= pgrid%nTets ) THEN 
          rflu_getglobalcellkind = cell_kind_actual
        ELSE 
          rflu_getglobalcellkind = cell_kind_virtual
        END IF ! icl
      CASE ( cell_type_hex )  
        IF ( icl <= pgrid%nHexs ) THEN 
          rflu_getglobalcellkind = cell_kind_actual
        ELSE 
          rflu_getglobalcellkind = cell_kind_virtual
        END IF ! icl
      CASE ( cell_type_pri ) 
        IF ( icl <= pgrid%nPris ) THEN 
          rflu_getglobalcellkind = cell_kind_actual
        ELSE 
          rflu_getglobalcellkind = cell_kind_virtual
        END IF ! icl
      CASE ( cell_type_pyr )         
        IF ( icl <= pgrid%nPyrs ) THEN 
          rflu_getglobalcellkind = cell_kind_actual
        ELSE 
          rflu_getglobalcellkind = cell_kind_virtual
        END IF ! icl
      CASE ( cell_type_bnd )
        rflu_getglobalcellkind = cell_kind_bnd
      CASE ( cell_type_ext ) 
        rflu_getglobalcellkind = cell_kind_ext
      CASE default
        WRITE(errorstring,'(1X,I3)') ict
        CALL errorstop(global,err_cell_type,__line__,trim(errorstring))
    END SELECT ! icType

! ******************************************************************************
!   End
! ******************************************************************************

    CALL deregisterfunction(global)

  END FUNCTION rflu_getglobalcellkind







! ******************************************************************************
!
! Purpose: Determine virtual cell region index.
!
! Description: Loop over cells which are to be received, if cell among these, 
!   then know region from border index.
!
! Input:
!   global      Pointer to global data
!   pGrid       Pointer to grid data
!   icg         Global cell id
!
! Output: None.
!
! Notes: 
!   1. If the cell is not found in any border list, return ELEMENT_NOT_FOUND.
!
! ******************************************************************************
  
  INTEGER FUNCTION rflu_getvirtualcellreg(global,pGrid,icg)

    USE modborder, ONLY: t_border

    USE modsortsearch

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    INTEGER, INTENT(IN) :: icg
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_global), POINTER :: global

! ==============================================================================
!   Locals
! ==============================================================================

    INTEGER :: iborder,iloc
    TYPE(t_border), POINTER :: pborder

! ******************************************************************************  
!   Start
! ******************************************************************************  

    CALL registerfunction(global,'RFLU_GetVirtualCellReg',&
  'RFLU_ModCellFaceEdgeInfo.F90') 

! ******************************************************************************  
!   Determine global cell type
! ******************************************************************************  

    rflu_getvirtualcellreg = element_not_found  

    borderloop: DO iborder = 1,pgrid%nBorders
      pborder => pgrid%borders(iborder)

      CALL binarysearchinteger(pborder%icgRecv,pborder%nCellsRecv,icg,iloc)
      
      IF ( iloc /= element_not_found ) THEN
        rflu_getvirtualcellreg = pborder%iRegionGlobal

        EXIT borderloop
      END IF ! iLoc
    END DO borderloop

! ******************************************************************************  
!   End
! ******************************************************************************  

    CALL deregisterfunction(global)

  END FUNCTION rflu_getvirtualcellreg







! ******************************************************************************
!
! Purpose: Determine face kind before renumbering.
!
! Description: None.
!
! Input:
!   global      Pointer to global data
!   c1k         Kind of cell 1
!   c2k         Kind of cell 2 
!
! Output: None.
!
! Notes: 
!   1. Can only get FACE_KIND_AB if have partitioned case with no dummy cells, 
!      which must not arise in practice but may be of interest for testing 
!      purposes.
!   2. Can only get FACE_KIND_VX if have partitioned case.
!
! ******************************************************************************
  
  INTEGER FUNCTION rflu_getfacekind(global,c1k,c2k)

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    INTEGER, INTENT(IN) :: c1k,c2k
    TYPE(t_global), POINTER :: global

! ==============================================================================
!   Locals
! ==============================================================================

    CHARACTER(CHRLEN) :: errorstring    

! ******************************************************************************  
!   Start
! ******************************************************************************  

    CALL registerfunction(global,'RFLU_GetFaceKind',&
  'RFLU_ModCellFaceEdgeInfo.F90')

! ******************************************************************************  
!   Get face kind
! ******************************************************************************  

    SELECT CASE (c1k + c2k) 
      CASE ( cell_kind_actual  + cell_kind_actual )
        rflu_getfacekind = face_kind_aa
      CASE ( cell_kind_actual  + cell_kind_virtual ) 
        rflu_getfacekind = face_kind_av
      CASE ( cell_kind_virtual + cell_kind_virtual )
        rflu_getfacekind = face_kind_vv
      CASE ( cell_kind_virtual + cell_kind_bnd )
        rflu_getfacekind = face_kind_vb 
      CASE ( cell_kind_virtual + cell_kind_ext ) 
        rflu_getfacekind = face_kind_vx
      CASE ( cell_kind_actual  + cell_kind_bnd )
        rflu_getfacekind = face_kind_ab           
      CASE default
        WRITE(errorstring,'(1X,I3)') c1k+c2k
        CALL errorstop(global,err_face_kind,__line__,trim(errorstring))
    END SELECT ! c1k + c2k

! ******************************************************************************  
!   End
! ******************************************************************************  

    CALL deregisterfunction(global)    

  END FUNCTION rflu_getfacekind
    
    
    
    
    
! ******************************************************************************
!
! Purpose: Determine edge kind.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
    
  INTEGER FUNCTION rflu_getedgekind(global,pGrid,v1,v2)

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    INTEGER, INTENT(IN) :: v1,v2
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid

! ==============================================================================
!   Locals
! ==============================================================================

    INTEGER :: v1k,v2k    

! ******************************************************************************  
!   Start
! ******************************************************************************  

    CALL registerfunction(global,'RFLU_GetEdgeKind',&
  'RFLU_ModCellFaceEdgeInfo.F90')

! ******************************************************************************  
!   Get face kind
! ******************************************************************************  

    IF ( v1 <= pgrid%nVert ) THEN 
      v1k = vert_kind_actual
    ELSE 
      v1k = vert_kind_virtual
    END IF ! v1

    IF ( v2 <= pgrid%nVert ) THEN 
      v2k = vert_kind_actual
    ELSE 
      v2k = vert_kind_virtual
    END IF ! v2

    SELECT CASE (v1k + v2k) 
      CASE ( vert_kind_actual + vert_kind_actual )
        rflu_getedgekind = edge_kind_aa
      CASE ( vert_kind_actual + vert_kind_virtual ) 
        rflu_getedgekind = edge_kind_av
      CASE ( vert_kind_virtual + vert_kind_virtual )
        rflu_getedgekind = edge_kind_vv 
      CASE default
        CALL errorstop(global,err_cell_type,__line__)
    END SELECT ! v1k + v2k

! ******************************************************************************  
!   End
! ******************************************************************************  

    CALL deregisterfunction(global) 

  END FUNCTION rflu_getedgekind
    
    
    

! ******************************************************************************
! End
! ******************************************************************************
  
END MODULE rflu_modcellfaceedgeinfo


! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModCellFaceEdgeInfo.F90,v $
! Revision 1.12  2008/12/06 08:44:20  mtcampbe
! Updated license.
!
! Revision 1.11  2008/11/19 22:17:31  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.10  2006/04/07 15:19:18  haselbac
! Removed tabs
!
! Revision 1.9  2005/04/15 15:06:45  haselbac
! Added RFLU_GetVirtualCellReg
!
! Revision 1.8  2004/11/03 17:01:20  haselbac
! Rewrite because of removal of vertex anc cell flags, cosmetics
!                                       
! Revision 1.7  2004/01/22 16:03:58  haselbac                                  
! Made contents of modules PRIVATE, only procs PUBLIC, to avoid errors on ALC   and titan
!
! Revision 1.6  2003/11/20 21:30:32  haselbac                                  
! Added register and deregister calls for better error reporting               
!
! Revision 1.5  2003/11/20 16:40:36  mdbrandy                                  
! Backing out RocfluidMP changes from 11-17-03                                 
!
! Revision 1.2  2003/08/19 22:47:54  haselbac                                  
! Improved error reporting                                                     
!
! Revision 1.1  2003/03/15 18:16:29  haselbac                                  
! Formerly called RFLU_ModCellFaceInfo.F90                                     
!
! Revision 1.5  2003/01/28 16:25:14  haselbac                                  
! Made simpler and more self-consistent                                        
!
! Revision 1.4  2002/10/05 19:02:31  haselbac                                  
! Fixed comment                                                                
!
! Revision 1.3  2002/09/09 15:02:02  haselbac                                  
! global now under regions                                                     
!
! Revision 1.2  2002/07/25 14:58:19  haselbac                                  
! Fixed bug in RFLU_GetCellIndexAfter and RFLU_GetCellKindBefore               
!
! Revision 1.1  2002/06/27 15:48:16  haselbac                                  
! Initial revision                                                             
!
! ******************************************************************************