RFLU_ModBoundaryTests.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Collection of routines for testing whether vertices or cells are on
!   boundaries.
!
! Description: None.
!
! Notes: None. 
!
! ******************************************************************************
!
! $Id: RFLU_ModBoundaryTests.F90,v 1.3 2008/12/06 08:44:20 mtcampbe Exp $
!
! Copyright: (c) 2006 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modboundarytests

  USE modparameters
  USE moddatatypes  
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modbndpatch, ONLY: t_patch  
  USE moddatastruct, ONLY: t_region
  USE moderror
  USE modmpi

  USE modsortsearch    

  IMPLICIT NONE
  
! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Private data
! ==============================================================================

  CHARACTER(CHRLEN), PRIVATE :: & 
    RCSIdentString = '$RCSfile: RFLU_ModBoundaryTests.F90,v $ $Revision: 1.3 $'        

! ==============================================================================
! Public functions
! ==============================================================================
  
  PUBLIC :: rflu_testisboundarycell, & 
            rflu_testisboundaryvertex

! ==============================================================================
! Private functions
! ==============================================================================



! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS
  
  
  
  
  
  
  
! ******************************************************************************
!
! Purpose: Determine whether cell is adjacent to boundaries.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
!   icg                 Global cell index
!
! Output: 
!   RFLU_TestIsBoundaryCell = .TRUE.     If cell adjacent to boundaries
!   RFLU_TestIsBoundaryCell = .FALSE.    If cell not adjacent to boundaries
!
! Notes: 
!   1. This routine is not efficient if calling it for large numbers of cells.
!      Would need to consider sorting actual boundary-face lists which would
!      avoid the need to sort them (repeatedly) here.
!
! ******************************************************************************

LOGICAL FUNCTION rflu_testisboundarycell(pRegion,icg)
      
  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: icg
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag,ifl,iloc,ipatch
  INTEGER, DIMENSION(:), ALLOCATABLE :: bf2csorted
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_patch), POINTER :: ppatch

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_TestIsBoundaryCell',&
  'RFLU_ModBoundaryTests.F90')

! ==============================================================================
! Set grid pointer and initialize RFLU_TestIsBoundaryCell
! ==============================================================================

  pgrid => pregion%grid
  
  rflu_testisboundarycell = .false.

! ******************************************************************************
! Check whether point is on boundaries
! ******************************************************************************

  DO ipatch = 1,pgrid%nPatches
    ppatch => pregion%patches(ipatch)
  
    ALLOCATE(bf2csorted(ppatch%nBFacesTot),stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_allocate,__line__,'bf2cSorted')
    END IF ! global%error
    
    DO ifl = 1,ppatch%nBFacesTot ! Explicit loop because of ASCI White
      bf2csorted(ifl) = ppatch%bf2c(ifl)
    END DO ! ifl
    
    CALL quicksortinteger(bf2csorted,ppatch%nBFacesTot)
    
    CALL binarysearchinteger(bf2csorted,ppatch%nBFacesTot,icg,iloc)
    
    IF ( iloc /= element_not_found ) THEN 
      rflu_testisboundarycell = .true.
    END IF ! iLoc
    
    DEALLOCATE(bf2csorted,stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_deallocate,__line__,'bf2cSorted')
    END IF ! global%error   
    
    IF ( rflu_testisboundarycell .EQV. .true. ) THEN 
      EXIT
    END IF ! RFLU_TestIsBoundaryCell         
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END FUNCTION rflu_testisboundarycell


   
   
   
! ******************************************************************************
!
! Purpose: Determine whether vertex is on boundaries.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
!   ivg                 Global vertex index
!
! Output: 
!   RFLU_TestIsBoundaryVertex = .TRUE.     If vertex on boundaries
!   RFLU_TestIsBoundaryVertex = .FALSE.    If vertex not on boundaries
!
! Notes: None.
!
! ******************************************************************************

LOGICAL FUNCTION rflu_testisboundaryvertex(pRegion,ivg)
      
  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: ivg
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag,iloc,ipatch
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_patch), POINTER :: ppatch

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_TestIsBoundaryVertex',&
  'RFLU_ModBoundaryTests.F90')

! ==============================================================================
! Set grid pointer and initialize RFLU_TestIsBoundaryVertex
! ==============================================================================

  pgrid => pregion%grid
  
  rflu_testisboundaryvertex = .false.

! ******************************************************************************
! Check whether vertex is on boundary
! ******************************************************************************

  DO ipatch = 1,pgrid%nPatches
    ppatch => pregion%patches(ipatch)
    
    CALL binarysearchinteger(ppatch%bv,ppatch%nBVertTot,ivg,iloc)
    
    IF ( iloc /= element_not_found ) THEN 
      rflu_testisboundaryvertex = .true.

      EXIT
    END IF ! RFLU_TestIsBoundaryVertex        
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END FUNCTION rflu_testisboundaryvertex
   
   
   
  


END MODULE rflu_modboundarytests

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModBoundaryTests.F90,v $
! Revision 1.3  2008/12/06 08:44:20  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:31  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2006/08/04 02:59:30  haselbac
! Initial revision
!
! ******************************************************************************