RFLU_ModBoundConvertCv.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Suite of routines to convert state vector.
!
! Description: None.
!
! Notes: 
!
! ******************************************************************************
!
! $Id: RFLU_ModBoundConvertCv.F90,v 1.3 2008/12/06 08:44:20 mtcampbe Exp $
!
! Copyright: (c) 2006 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modboundconvertcv

  USE moddatatypes
  USE modparameters
  USE moderror
  USE modbndpatch, ONLY: t_patch
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE moddatastruct, ONLY: t_region
    
  IMPLICIT NONE
   
  PRIVATE
  PUBLIC :: rflu_bxv_convertcvcons2prim, & 
            rflu_bxv_convertcvprim2cons
   
  SAVE    
     
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  
  
       
! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS




! ******************************************************************************
!
! Purpose: Convert conserved state vector to primitive variables.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to data of current region
!   pPatch              Pointer to data of current patch
!   cvStateFuture       Future state of conserved variables
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_convertcvcons2prim(pRegion,pPatch,cvStateFuture)

  USE modinterfaces, ONLY: mixtperf_r_m, &
                           mixtperf_t_dpr

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: cvstatefuture
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: icg,ifl,indmol
  REAL(RFREAL) :: gc,ir,mw,p,r
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pdv,pgv
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_ConvertCvCons2Prim',&
  'RFLU_ModBoundConvertCv.F90')

! ******************************************************************************
! Set pointers and variables
! ******************************************************************************

  pcv   => ppatch%mixt%cv
  pdv   => ppatch%mixt%dv

  pgv   => pregion%mixt%gv ! pGv taken from interior domain

  indmol = pregion%mixtInput%indMol

! ******************************************************************************
! Actual conversion
! ******************************************************************************

  SELECT CASE ( ppatch%mixt%cvState )

! ==============================================================================
!   Convert from conservative to primitive form
! ==============================================================================

    CASE ( cv_mixt_state_cons )
      SELECT CASE ( cvstatefuture )

! ------------------------------------------------------------------------------
!       Convert to duvwp form
! ------------------------------------------------------------------------------

        CASE ( cv_mixt_state_duvwp )
          ppatch%mixt%cvState = cv_mixt_state_duvwp

          DO ifl = 1,ppatch%nBFaces
            ir = 1.0_rfreal/pcv(cv_mixt_dens,ifl)

            pcv(cv_mixt_xvel,ifl) = ir*pcv(cv_mixt_xmom,ifl)
            pcv(cv_mixt_yvel,ifl) = ir*pcv(cv_mixt_ymom,ifl)
            pcv(cv_mixt_zvel,ifl) = ir*pcv(cv_mixt_zmom,ifl)
            pcv(cv_mixt_pres,ifl) = pdv(dv_mixt_pres,ifl)
          END DO ! ifl

! ------------------------------------------------------------------------------
!       Convert to duvwt form
! ------------------------------------------------------------------------------

        CASE (cv_mixt_state_duvwt)
          ppatch%mixt%cvState = cv_mixt_state_duvwt

          SELECT CASE ( pregion%mixtInput%fluidModel )

! --------- Compressible fluid model -----------------------------------------

            CASE ( fluid_model_comp )
              SELECT CASE ( pregion%mixtInput%gasModel )

! ------------- TC perfect gas or mixture thereof, pseudo-gas

                CASE ( gas_model_tcperf, &
                       gas_model_mixt_tcperf, &
                       gas_model_mixt_pseudo )
                  DO ifl = 1,ppatch%nBFaces
                    icg = ppatch%bf2c(ifl)

                    r  = pcv(cv_mixt_dens,ifl)
                    p  = pdv(dv_mixt_pres,ifl)
                    ir = 1.0_rfreal/r

                    pcv(cv_mixt_xvel,ifl) = ir*pcv(cv_mixt_xmom,ifl)
                    pcv(cv_mixt_yvel,ifl) = ir*pcv(cv_mixt_ymom,ifl)
                    pcv(cv_mixt_zvel,ifl) = ir*pcv(cv_mixt_zmom,ifl)

                    mw = pgv(gv_mixt_mol,indmol*icg)
                    gc = mixtperf_r_m(mw)

                    pcv(cv_mixt_temp,ifl) = mixtperf_t_dpr(r,p,gc)
                  END DO ! ifl

! ------------- Gas-liquid mixture

                CASE ( gas_model_mixt_gasliq )
                  DO ifl = 1,ppatch%nBFaces
                    icg = ppatch%bf2c(ifl)

                    ir = 1.0_rfreal/pcv(cv_mixt_dens,ifl)

                    pcv(cv_mixt_xvel,ifl) = ir*pcv(cv_mixt_xmom,ifl)
                    pcv(cv_mixt_yvel,ifl) = ir*pcv(cv_mixt_ymom,ifl)
                    pcv(cv_mixt_zvel,ifl) = ir*pcv(cv_mixt_zmom,ifl)

                    pcv(cv_mixt_temp,ifl) = pdv(dv_mixt_temp,ifl)
                  END DO ! ifl
                CASE default
                  CALL errorstop(global,err_reached_default,__line__)
              END SELECT ! pRegion%mixtInput%gasModel

! --------- Default ----------------------------------------------------------

            CASE default
              CALL errorstop(global,err_reached_default,__line__)
          END SELECT ! pRegion%mixtInput%fluidModel

! ------------------------------------------------------------------------------
!       Default
! ------------------------------------------------------------------------------

        CASE default
          CALL errorstop(global,err_reached_default,__line__)
      END SELECT ! cvStateFuture

! ==============================================================================
!   Error - invalid input
! ==============================================================================

    CASE default
      CALL errorstop(global,err_reached_default,__line__)
  END SELECT ! pPatch%mixt%cvStateFuture

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_convertcvcons2prim






! ******************************************************************************
!
! Purpose: Convert primitive state vector to consverved variables.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to data of current region
!   pPatch              Pointer to data of current patch
!   cvStateFuture       Future state of conserved variables
!
! Output: None.
!
! Notes:
!   1. Strictly speaking, cvStateFuture is not needed (there is only one
!      state for conserved variables), but kept for consistency with
!      RFLU_ConvertCvCons2Prim.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_convertcvprim2cons(pRegion,pPatch,cvStateFuture)

  USE modinterfaces, ONLY: mixtperf_cv_cpr, &
                           mixtgasliq_eo_cvmtvm2, &
                           mixtperf_eo_dgpuvw, &
                           mixtperf_g_cpr, &
                           mixtperf_r_m

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER, INTENT(IN) :: cvstatefuture
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: icg,ifl,indcp,indmol
  REAL(RFREAL) :: cp,cvm,cvg,cvl,cvv,g,gc,mw,p,r,rg,rv,ryg,ryl,ryv,t,u,v, &
                  vm2,w
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pdv,pgv
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_ConvertCvPrim2Cons',&
  'RFLU_ModBoundConvertCv.F90')

! ******************************************************************************
! Set pointers and variables
! ******************************************************************************

  pcv   => ppatch%mixt%cv
  pdv   => ppatch%mixt%dv

  pgv   => pregion%mixt%gv ! pGv is taken from interior cells

  indcp  = pregion%mixtInput%indCp
  indmol = pregion%mixtInput%indMol

! ******************************************************************************
! Actual conversion
! ******************************************************************************

  IF ( ppatch%mixt%cvState == cv_mixt_state_duvwp .OR. &
       ppatch%mixt%cvState == cv_mixt_state_duvwt ) THEN

! ==============================================================================
!   Convert from primitive to conservative form
! ==============================================================================

    SELECT CASE ( cvstatefuture )
      CASE ( cv_mixt_state_cons )
        ppatch%mixt%cvState = cv_mixt_state_cons

        SELECT CASE ( pregion%mixtInput%gasModel )

! ------------------------------------------------------------------------------
!         Thermally and calorically perfect gas or pseudo-gas
! ------------------------------------------------------------------------------

          CASE ( gas_model_tcperf, &
                 gas_model_mixt_tcperf, &
                 gas_model_mixt_pseudo )
            DO ifl = 1,ppatch%nBFaces
              icg = ppatch%bf2c(ifl)

              r = pcv(cv_mixt_dens,ifl)
              u = pcv(cv_mixt_xvel,ifl)
              v = pcv(cv_mixt_yvel,ifl)
              w = pcv(cv_mixt_zvel,ifl)
              p = pdv(dv_mixt_pres,ifl)

              pcv(cv_mixt_xmom,ifl) = r*u
              pcv(cv_mixt_ymom,ifl) = r*v
              pcv(cv_mixt_zmom,ifl) = r*w

              cp = pgv(gv_mixt_cp,indcp*icg)
              mw = pgv(gv_mixt_mol,indmol*icg)
              gc = mixtperf_r_m(mw)
              g  = mixtperf_g_cpr(cp,gc)

              pcv(cv_mixt_ener,ifl) = r*mixtperf_eo_dgpuvw(r,g,p,u,v,w)
            END DO ! icg

! ------------------------------------------------------------------------------
!         Mixture of gas, liquid, and vapor
! ------------------------------------------------------------------------------

          CASE ( gas_model_mixt_gasliq )
            CALL errorstop(global,err_gasmodel_invalid,__line__, &
                           'Can only be used with species module.')

! ------------------------------------------------------------------------------
!         Other or invalid gas models
! ------------------------------------------------------------------------------

          CASE default
            CALL errorstop(global,err_reached_default,__line__)
        END SELECT ! pRegion%mixtInput

      CASE default
        CALL errorstop(global,err_reached_default,__line__)
    END SELECT ! cvStateFuture

! ==============================================================================
! Error - invalid input
! ==============================================================================

  ELSE
    CALL errorstop(global,err_reached_default,__line__)
  END IF ! pPatch%mixt%cvState

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_convertcvprim2cons






  
! ******************************************************************************
! End
! ******************************************************************************

END MODULE rflu_modboundconvertcv


! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModBoundConvertCv.F90,v $
! Revision 1.3  2008/12/06 08:44:20  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:31  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2006/08/19 15:37:43  mparmar
! Initial revision
!
! ******************************************************************************