RFLU_InitFlowScratch.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Initialize flow field in a region from scratch.
!
! Description: Use user input to define initial flow field.
!
! Input: 
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_InitFlowScratch.F90,v 1.5 2008/12/06 08:44:56 mtcampbe Exp $
!
! Copyright: (c) 2002-2006 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_initflowscratch(pRegion)

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY: t_region
  USE modmixture, ONLY: t_mixt_input
  USE modglobal, ONLY: t_global
  USE modparameters
  
  USE modinterfaces, ONLY: mixtgasliq_eo_cvmtvm2, &
                           mixtliq_d_dobpppobttto, &
                           mixtperf_cv_cpr, &
                           mixtperf_d_prt, &
                           mixtperf_eo_dgpuvw, &
                           mixtperf_g_cpr, & 
                           mixtperf_r_m, &                             
                           rflu_getcvloc
  
  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: cvmixtpres,cvmixtxvel,cvmixtyvel,cvmixtzvel,icg,indcp,indmol
  REAL(RFREAL) :: cp,cvm,cvg,cvv,eo,g,gc,mw,r,rhog,rhol,rhov,rg,rv,vm2,yg,yl,yv
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pgv
  TYPE(t_global), POINTER :: global
  TYPE(t_mixt_input), POINTER :: pmixtinput

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_InitFlowScratch.F90,v $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_InitFlowScratch', &
                        'RFLU_InitFlowScratch.F90')
 
  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, &
                             'Initializing flow field from scratch...'
  END IF ! global%verbLevel

! ******************************************************************************
! Set pointers and variables
! ******************************************************************************

  pcv        => pregion%mixt%cv
  pgv        => pregion%mixt%gv  
  pmixtinput => pregion%mixtInput
  
  indcp  = pregion%mixtInput%indCp
  indmol = pregion%mixtInput%indMol  
  
! ******************************************************************************
! Initialize flow field based on user input and fluid model
! ******************************************************************************

  SELECT CASE ( pmixtinput%fluidModel ) 
 
! ==============================================================================  
!   Incompressible fluid model  
! ==============================================================================  

    CASE ( fluid_model_incomp )     
      pregion%mixt%cvState = cv_mixt_state_prim

      cvmixtxvel = rflu_getcvloc(global,pmixtinput%fluidModel,cv_mixt_xvel)
      cvmixtyvel = rflu_getcvloc(global,pmixtinput%fluidModel,cv_mixt_yvel)
      cvmixtzvel = rflu_getcvloc(global,pmixtinput%fluidModel,cv_mixt_zvel)
      cvmixtpres = rflu_getcvloc(global,pmixtinput%fluidModel,cv_mixt_pres)                

      DO icg = 1,pregion%grid%nCellsTot
        pcv(cvmixtxvel,icg) = pregion%mixtInput%iniVelX
        pcv(cvmixtyvel,icg) = pregion%mixtInput%iniVelY
        pcv(cvmixtzvel,icg) = pregion%mixtInput%iniVelZ
        pcv(cvmixtpres,icg) = pregion%mixtInput%iniPress 
      END DO ! icg   
      
! ==============================================================================  
!   Compressible fluid model  
! ==============================================================================  
    
    CASE ( fluid_model_comp )
      pregion%mixt%cvState = cv_mixt_state_cons
          
      SELECT CASE ( pregion%mixtInput%gasModel ) 
      
! ------------------------------------------------------------------------------
!       Gas models without liquid phase
! ------------------------------------------------------------------------------      
      
        CASE ( gas_model_tcperf, & 
               gas_model_tperf, & 
               gas_model_mixt_tcperf, & 
               gas_model_mixt_tperf, & 
               gas_model_mixt_pseudo )     
          DO icg = 1,pregion%grid%nCellsTot
            mw = pgv(gv_mixt_mol,indmol*icg)
            cp = pgv(gv_mixt_cp ,indcp *icg)

            gc = mixtperf_r_m(mw)
            g  = mixtperf_g_cpr(cp,gc)

            r = pregion%mixtInput%iniDens

            pcv(cv_mixt_dens,icg) = r
            pcv(cv_mixt_xmom,icg) = r*pregion%mixtInput%iniVelX
            pcv(cv_mixt_ymom,icg) = r*pregion%mixtInput%iniVelY
            pcv(cv_mixt_zmom,icg) = r*pregion%mixtInput%iniVelZ

            eo = mixtperf_eo_dgpuvw(pcv(cv_mixt_dens,icg),g,    & 
                                    pregion%mixtInput%iniPress, & 
                                    pregion%mixtInput%iniVelX,  & 
                                    pregion%mixtInput%iniVelY,  & 
                                    pregion%mixtInput%iniVelZ)

            pcv(cv_mixt_ener,icg) = pcv(cv_mixt_dens,icg)*eo
          END DO ! icg    

! ------------------------------------------------------------------------------
!       Mixture of gas, liquid, and vapor
! ------------------------------------------------------------------------------      

        CASE ( gas_model_mixt_gasliq ) 
          rg  = mixtperf_r_m(pregion%specInput%specType(1)%pMaterial%molw)
          cvg = mixtperf_cv_cpr(pregion%specInput%specType(1)%pMaterial%spht,rg)

          rv  = mixtperf_r_m(pregion%specInput%specType(2)%pMaterial%molw)
          cvv = mixtperf_cv_cpr(pregion%specInput%specType(2)%pMaterial%spht,rv)

          rhol = mixtliq_d_dobpppobttto(global%refDensityLiq, &
                                        global%refBetaPLiq, &
                                        global%refBetaTLiq, &
                                        pregion%mixtInput%iniPress, &
                                        global%refPressLiq, &
                                        pregion%mixtInput%iniTemp, &
                                        global%refTempLiq)

          DO icg = 1,pregion%grid%nCellsTot
            yg = pregion%specInput%specType(1)%initVal
            yv = pregion%specInput%specType(2)%initVal 
            yl = 1.0_rfreal - yg - yv        

            rhog = mixtperf_d_prt(pregion%mixtInput%iniPress,rg, &
                                  pregion%mixtInput%iniTemp)
            rhov = mixtperf_d_prt(pregion%mixtInput%iniPress,rv, &
                                  pregion%mixtInput%iniTemp) 

            r = 1.0_rfreal/(yg/rhog + yv/rhov + yl/rhol)

            pcv(cv_mixt_dens,icg) = r
            pcv(cv_mixt_xmom,icg) = r*pregion%mixtInput%iniVelX
            pcv(cv_mixt_ymom,icg) = r*pregion%mixtInput%iniVelY
            pcv(cv_mixt_zmom,icg) = r*pregion%mixtInput%iniVelZ        

            cvm = yg*cvg + yv*cvv + yl*global%refCvLiq 

            vm2 = pregion%mixtInput%iniVelX*pregion%mixtInput%iniVelX &
                + pregion%mixtInput%iniVelY*pregion%mixtInput%iniVelY &
                + pregion%mixtInput%iniVelZ*pregion%mixtInput%iniVelZ

            pcv(cv_mixt_ener,icg) = pcv(cv_mixt_dens,icg)* &
             mixtgasliq_eo_cvmtvm2(cvm,pregion%mixtInput%iniTemp,vm2) 
          END DO ! icg

! ------------------------------------------------------------------------------
!       Default
! ------------------------------------------------------------------------------      

        CASE default
          CALL errorstop(global,err_reached_default,__line__)
      END SELECT ! pRegion%mixtInput%gasModel
      
! ==============================================================================  
!   Default
! ==============================================================================  

    CASE default
      CALL errorstop(global,err_reached_default,__line__)
  END SELECT ! pRegion%mixtInput%fluidModel
  
! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name, &
                             'Initializing flow field from scratch done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_initflowscratch

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_InitFlowScratch.F90,v $
! Revision 1.5  2008/12/06 08:44:56  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:18:06  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/03/26 20:22:26  haselbac
! Added support for GL model
!
! Revision 1.2  2005/11/10 02:43:23  haselbac
! Added support for variable properties
!
! Revision 1.1  2005/04/15 15:08:18  haselbac
! Initial revision
!
! ******************************************************************************