RFLU_GetBoundaryValues.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Obtain boundary values from Genx.
!
! Description: None.
!
! Input: 
!   region      Dimensions and topology
!
! Output: 
!   region%levels%patch         Input values for boundary conditions
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_GetBoundaryValues.F90,v 1.18 2008/12/06 08:44:01 mtcampbe Exp $
!
! Copyright: (c) 2002-2004 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_getboundaryvalues(region)

  USE moddatatypes
  USE modglobal, ONLY: t_global
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region
  USE moderror
  USE modparameters
  USE modmpi

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region) :: region

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: errorstring,rcsidentstring
  INTEGER :: ifl,ipatch,bocount,botot
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pvals
  TYPE(t_global), POINTER :: global
  TYPE(t_patch), POINTER :: ppatch

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_GetBoundaryValues.F90,v $ $Revision: 1.18 $'

  global => region%global

  CALL registerfunction(global,'RFLU_GetBoundaryValues',&
  'RFLU_GetBoundaryValues.F90')

! ******************************************************************************
! Loop over ALL boundaries 
! ******************************************************************************


  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel >= verbose_high ) THEN
    WRITE(stdout,'(A,1X,A,1X,I3)') solver_name, &
                                   'Getting values from GENX buffers...'
  END IF ! global%myProcid

  bocount = 0
  DO ipatch=1,region%grid%nPatches
    ppatch  => region%patches(ipatch)
 
    IF ( global%myProcid == masterproc .AND. & 
         global%checkLevel == check_high .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      IF ( ppatch%bcCoupled == bc_not_coupled ) THEN
        WRITE(stdout,'(A,3X,A,1X,I3,1X,A)') solver_name,'Patch:',ipatch, & 
                                            '(not interacting)'
      ELSE IF ( ppatch%bcCoupled == bc_not_burning ) THEN 
        WRITE(stdout,'(A,3X,A,1X,I3,1X,A)') solver_name,'Patch:',ipatch, & 
                                            '(interacting)'      
      ELSE IF ( ppatch%bcCoupled == bc_burning ) THEN
        WRITE(stdout,'(A,3X,A,1X,I3,1X,A)') solver_name,'Patch:',ipatch, & 
                                            '(interacting and burning)'          
      END IF ! pPatch%bcCoupled        
    END IF ! global%myProcid 
           
! ==============================================================================
!   Coupled burning boundary
! ==============================================================================
           
    IF ( ppatch%bcCoupled == bc_burning )THEN    
      pvals => ppatch%mixt%vals
      DO ifl = 1,ppatch%nBFaces      
! TZ DOES NOT WORK PROPERLY WITH THE ROCMAN EVALUATED MDOT (leaving this in for now)
!        pPatch%mdotAlp(ifl) = global%tzRhos*global%tzA*pPatch%pf(ifl)**global%tzN
! Rocman3 has been modified to always pass in the nominal mdots, so we trust the mdot
! coming from Rocman3 now.
!
! We've the BFLAG off for faces that have burned out.  We need to zero these mdots
! in the fluid RK substeps.  The following check accomplishes mdot zeroing for 
! burned out faces.
        IF(ppatch%bflag(ifl) .ne. 0) THEN
           pvals(bcdat_inject_mfrate,ifl) = ppatch%mdotAlp(ifl)
        ELSE
           bocount = bocount + 1
           pvals(bcdat_inject_mfrate,ifl) = 0.0
           ppatch%mdotAlp(ifl) = 0.0
        ENDIF
        pvals(bcdat_inject_temp  ,ifl) = ppatch%tflmAlp(ifl)
      END DO ! ifl

      DO ifl = ppatch%nBFaces+1,ppatch%nBFacesTot
        pvals(bcdat_inject_mfrate,ifl) = REAL(crazy_value_int,kind=rfreal)
        pvals(bcdat_inject_temp  ,ifl) = REAL(crazy_value_int,kind=rfreal)
      END DO ! ifl

      IF ( global%myProcid == masterproc .AND. & 
           global%checkLevel == check_high .AND. & 
           global%verbLevel >= verbose_high ) THEN 
         IF ( ppatch%nBFaces > 0 ) THEN
            WRITE(stdout,'(A,5X,A)') solver_name,'Minimum/maximum values:'      
            WRITE(stdout,'(A,7X,A,2(1X,E15.8))') solver_name,'mdotAlp:    ', & 
                 minval(ppatch%mdotAlp(1:ppatch%nBFaces)), & 
                 maxval(ppatch%mdotAlp(1:ppatch%nBFaces))
            WRITE(stdout,'(A,7X,A,2(1X,E15.8))') solver_name,'TflmAlp:    ', & 
                 minval(ppatch%tflmAlp(1:ppatch%nBFaces)), & 
                 maxval(ppatch%tflmAlp(1:ppatch%nBFaces))
         END IF ! pPatch%nBFaces
      END IF ! global%myProcid       
      
      IF ( minval(ppatch%mdotAlp(1:ppatch%nBFaces)) < 0.0_rfreal ) THEN 
        WRITE(errorstring,*) 'Patch:',ppatch%iPatchGlobal
        CALL errorstop(global,err_mdot_negative,__line__,trim(errorstring))
      END IF ! MINVAL
    
      IF ( minval(ppatch%tflmAlp(1:ppatch%nBFaces)) < 0.0_rfreal ) THEN 
        WRITE(errorstring,*) 'Patch:',ppatch%iPatchGlobal
        CALL errorstop(global,err_tflm_negative,__line__,trim(errorstring))
      END IF ! MINVAL

! ==============================================================================
!   Coupled non-burning boundary. NOTE only copy boundary temperature for 
!   isothermal no-slip walls.
! ==============================================================================    
    
    ELSE IF ( ppatch%bcCoupled == bc_not_burning ) THEN
      IF ( ppatch%bcType == bc_noslipwall_temp ) THEN  
        pvals => ppatch%mixt%vals

        DO ifl = 1,ppatch%nBFaces      
          pvals(bcdat_noslip_t,ifl) = ppatch%tbAlp(ifl)
        END DO ! ifl

        DO ifl = ppatch%nBFaces+1,ppatch%nBFacesTot
          pvals(bcdat_noslip_t,ifl) = REAL(crazy_value_int,kind=rfreal)
        END DO ! ifl

        IF ( global%myProcid == masterproc .AND. & 
             global%checkLevel == check_high .AND. & 
             global%verbLevel >= verbose_high ) THEN 
          IF ( ppatch%nBFaces > 0 ) THEN
            WRITE(stdout,'(A,5X,A)') solver_name,'Minimum/maximum values:'      
            WRITE(stdout,'(A,7X,A,2(1X,E15.8))') solver_name,'TbAlp:    ', & 
                  minval(ppatch%tbAlp(1:ppatch%nBFaces)), & 
                  maxval(ppatch%tbAlp(1:ppatch%nBFaces))
          END IF ! pPatch%nBFaces
        END IF ! global%myProcid       

        IF ( minval(ppatch%tbAlp(1:ppatch%nBFaces)) < 0.0_rfreal ) THEN 
          WRITE(errorstring,*) 'Patch:',ppatch%iPatchGlobal
          CALL errorstop(global,err_tb_negative,__line__,trim(errorstring))
        END IF ! MINVAL 
      END IF ! pPatch%bcType   
    
! ==============================================================================
!   Noncoupled boundary
! ==============================================================================    

    ELSE IF ( ppatch%bcCoupled == bc_not_coupled ) THEN   

! ==============================================================================
!   Impossible combination - defensive programming
! ==============================================================================    
      
    ELSE 
      CALL errorstop(global,err_reached_default,__line__)  
    END IF ! pPatch%bcCoupled  
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%checkLevel == check_high .AND. bocount > 0) THEN
     WRITE(stdout,'(A,3X,A,1X,I9,1X,I9)') solver_name, &
          'Local burned out faces:',bocount,global%myProcid
  ENDIF

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel >= verbose_high ) THEN 
     WRITE(stdout,'(A,1X,A,1X,I3)') solver_name, &
           'Getting values from GENX buffers done.'
  END IF ! global%myProcid

  CALL deregisterfunction(global)

END SUBROUTINE rflu_getboundaryvalues

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_GetBoundaryValues.F90,v $
! Revision 1.18  2008/12/06 08:44:01  mtcampbe
! Updated license.
!
! Revision 1.17  2008/11/19 22:17:15  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.16  2007/04/20 16:07:47  mtcampbe
! Updating for burnout support function RFLU_GENX_InitBFLAG
!
! Revision 1.15  2007/04/14 21:54:45  mtcampbe
! Updated for burnout compatibility.
!
! Revision 1.14  2007/04/14 14:30:32  mtcampbe
! Updated for TZ
!
! Revision 1.13  2006/08/19 15:37:53  mparmar
! Renamed patch variables
!
! Revision 1.12  2005/10/14 13:59:46  haselbac
! Added setting of boundary temperature for non-burning patches
!
! Revision 1.11  2004/10/19 19:23:04  haselbac
! Removed setting of relative velocity on injecting boundaries, cosmetics
!
! Revision 1.10  2003/08/20 02:09:58  haselbac
! Changed verbosity conditions to reduce solver output in GENx runs
!
! Revision 1.9  2003/05/13 23:41:35  haselbac
! Added init of dummy faces and check for temp
!
! Revision 1.8  2003/05/01 20:44:16  haselbac
! Added check for negative mdot
!
! Revision 1.7  2003/05/01 14:06:11  haselbac
! Removed warning for non-burning boundaries
!
! Revision 1.6  2003/04/12 21:33:01  haselbac
! Made parallel: Added MASTERPROC checks
!
! Revision 1.5  2003/01/28 18:22:28  haselbac
! Cosmetics only
!
! Revision 1.4  2002/10/12 19:08:45  haselbac
! Cosmetic changes only
!
! Revision 1.3  2002/10/12 14:48:15  haselbac
! Corrected bcFlag bug, some cosmetic changes
!
! Revision 1.2  2002/10/07 14:09:32  haselbac
! Changed ModBndpatch to ModBndPatch
!
! Revision 1.1  2002/10/05 18:28:18  haselbac
! Initial revision
!
! ******************************************************************************