RFLU_DerivedInputValues.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Set values derived from user input.
!
! Description: None.
!
! Input:
!   regions        Data for regions
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_DerivedInputValues.F90,v 1.21 2008/12/06 08:44:12 mtcampbe Exp $
!
! Copyright: (c) 2002-2006 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_derivedinputvalues(regions)

  USE moddatatypes
  USE modglobal, ONLY: t_global
  USE modmixture, ONLY: t_mixt_input
  USE moddatastruct, ONLY: t_region
  USE moderror
  USE modparameters
  USE modmpi

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), DIMENSION(:), POINTER :: regions

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: ireg
  TYPE(t_mixt_input), POINTER :: pmixtinput
  TYPE(t_global), POINTER :: global
  TYPE(t_region), POINTER :: pregion

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = & 
    '$RCSfile: RFLU_DerivedInputValues.F90,v $ $Revision: 1.21 $'

  global => regions(1)%global

  CALL registerfunction(global,'RFLU_DerivedInputValues',&
  'RFLU_DerivedInputValues.F90')

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel >= verbose_high ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Setting derived input variables...'
  END IF ! global%verbLevel

! ******************************************************************************
! Region-independent values
! ******************************************************************************

  IF ( global%refREnum > 0.0_rfreal ) THEN
    global%refVisc = global%refDensity*global%RefVelocity*global%refLength/ &
                     global%refREnum
  ELSE
    global%refVisc = 0.0_rfreal
  END IF ! global%refREnum

! ******************************************************************************
! Region-dependent values
! ******************************************************************************

  DO ireg = lbound(regions,1),ubound(regions,1)
    pregion    => regions(ireg)
    pmixtinput => pregion%mixtInput

! ==============================================================================
!   General
! ==============================================================================

    SELECT CASE ( pmixtinput%fluidModel ) 
      CASE ( fluid_model_incomp ) 
        pmixtinput%nCv = 4
        pmixtinput%nDv = 0 ! TEMPORARY
        pmixtinput%nGv = 0 ! TEMPORARY
      CASE ( fluid_model_comp ) 
        pmixtinput%nCv = 5
        pmixtinput%nDv = 3 
        pmixtinput%nGv = 2        

        SELECT CASE ( pmixtinput%gasModel ) 
          CASE ( gas_model_tcperf )
            pmixtinput%nGvAct = 0
             
            pmixtinput%indCp  = 0 
            pmixtinput%indMol = 0 
          CASE ( gas_model_mixt_tcperf )
            pmixtinput%nGvAct = 2          
           
            pmixtinput%indCp  = 1 
            pmixtinput%indMol = 1
          CASE ( gas_model_mixt_pseudo )
            pmixtinput%nGvAct = 2          
           
            pmixtinput%indCp  = 1 
            pmixtinput%indMol = 1 
          CASE ( gas_model_mixt_gasliq ) 
            pmixtinput%nGvAct = 0

            pmixtinput%indCp  = 1 
            pmixtinput%indMol = 1                     
          CASE default
            CALL errorstop(global,err_reached_default,__line__)
        END SELECT ! pMixtInput%gasModel  
      CASE default
        CALL errorstop(global,err_reached_default,__line__)
    END SELECT ! pMixtInput%fluidModel   
       
    IF ( pmixtinput%flowModel == flow_navst ) THEN 
      pmixtinput%computeTv = .true.
    ELSE 
      pmixtinput%computeTv = .false.
    END IF ! pMixtInput%flowModel

    IF ( pmixtinput%computeTv ) THEN ! transport variables
      pmixtinput%nTv = 2
    ELSE
      pmixtinput%nTv = 0
    END IF ! pMixtInput
        
! ==============================================================================
!   Transport coefficients and dimensionless numbers
! ==============================================================================

    IF ( pmixtinput%refVisc < 0.0_rfreal ) THEN ! Was not specified
      pmixtinput%refVisc = global%refVisc
    END IF ! pMixtInput%refVisc

    pmixtinput%prLam   = global%prLam
    pmixtinput%prTurb  = global%prTurb
    pmixtinput%scnLam  = global%scnLam
    pmixtinput%scnTurb = global%scnTurb

! ==============================================================================
!   Stencil dimensionality. NOTE if not using one-dimensional stencils, then
!   set stencil dimensionality to be equal to dimensionality.
! ==============================================================================

    IF ( pmixtinput%stencilDimensCells > 1 ) THEN 
      pmixtinput%stencilDimensCells = pmixtinput%dimens
    END IF ! pMixtInput%stencilDimensCells
    
    IF ( pmixtinput%stencilDimensFaces > 1 ) THEN 
      pmixtinput%stencilDimensFaces = pmixtinput%dimens
    END IF ! pMixtInput%stencilDimensFaces
    
    IF ( pmixtinput%stencilDimensBFaces > 1 ) THEN 
      pmixtinput%stencilDimensBFaces = pmixtinput%dimens
    END IF ! pMixtInput%stencilDimensBFaces        

! ==============================================================================
!   Grid speeds
! ==============================================================================

    IF ( pmixtinput%moveGrid .EQV. .true. ) THEN
      pregion%grid%indGs = 1
    ELSE
      pregion%grid%indGs = 0
    END IF ! pMixtInput

! ==============================================================================
!   Time-stepping scheme
! ==============================================================================

    IF ( global%flowType == flow_steady ) THEN ! steady flow
      global%nrkSteps  = 5
    ELSE ! unsteady flow
      SELECT CASE ( global%rkScheme ) 
        CASE ( rk_scheme_4_classical ) 
          global%nrkSteps = 4
        CASE ( rk_scheme_3_wray ) 
          global%nrkSteps = 3
        CASE default 
          CALL errorstop(global,err_reached_default,__line__)            
      END SELECT ! global%rkScheme
    END IF ! global%flowType

    IF ( global%flowType == flow_steady ) THEN ! steady, upwind scheme
      pmixtinput%ark(1) = 0.0695_rfreal
      pmixtinput%ark(2) = 0.1602_rfreal
      pmixtinput%ark(3) = 0.2898_rfreal
      pmixtinput%ark(4) = 0.5060_rfreal
      pmixtinput%ark(5) = 1.0000_rfreal

      pmixtinput%betrk(1) = 1.0000_rfreal
      pmixtinput%betrk(2) = 0.0000_rfreal
      pmixtinput%betrk(3) = 0.5600_rfreal
      pmixtinput%betrk(4) = 0.0000_rfreal
      pmixtinput%betrk(5) = 0.4400_rfreal

      pmixtinput%ldiss(1) = 1
      pmixtinput%ldiss(2) = 0
      pmixtinput%ldiss(3) = 1
      pmixtinput%ldiss(4) = 0
      pmixtinput%ldiss(5) = 1
    ELSE ! unsteady
      SELECT CASE ( global%rkScheme ) 
        CASE ( rk_scheme_4_classical ) 
          pmixtinput%ark(1) = 0.5_rfreal
          pmixtinput%ark(2) = 0.5_rfreal
          pmixtinput%ark(3) = 1.0_rfreal
          pmixtinput%ark(4) = 1.0_rfreal/6.0_rfreal

          pmixtinput%betrk(1) = 1.0_rfreal
          pmixtinput%betrk(2) = 1.0_rfreal
          pmixtinput%betrk(3) = 1.0_rfreal      
          pmixtinput%betrk(4) = 1.0_rfreal            

          pmixtinput%grk(1) = 1.0_rfreal
          pmixtinput%grk(2) = 2.0_rfreal
          pmixtinput%grk(3) = 2.0_rfreal
          pmixtinput%grk(4) = 1.0_rfreal

          pmixtinput%trk(1) = 0.0_rfreal
          pmixtinput%trk(2) = 0.5_rfreal
          pmixtinput%trk(3) = 0.5_rfreal
          pmixtinput%trk(4) = 1.0_rfreal

          pmixtinput%ldiss(1) = 1
          pmixtinput%ldiss(2) = 1
          pmixtinput%ldiss(3) = 1
          pmixtinput%ldiss(4) = 1                  

          pmixtinput%cfl = min(pmixtinput%cfl,3.0_rfreal) ! stability margin
        CASE ( rk_scheme_3_wray ) 
          pmixtinput%ark(1) = 8.0_rfreal/15.0_rfreal
          pmixtinput%ark(2) = 5.0_rfreal/12.0_rfreal
          pmixtinput%ark(3) = 0.75_rfreal

          pmixtinput%betrk(1) = 0.0_rfreal
          pmixtinput%betrk(2) = 0.0_rfreal
          pmixtinput%betrk(3) = 0.0_rfreal    

          pmixtinput%grk(1) =  0.0_rfreal
          pmixtinput%grk(2) = 17.0_rfreal/25.0_rfreal
          pmixtinput%grk(3) =  5.0_rfreal/ 9.0_rfreal        
 
          pmixtinput%trk(1) = 0.0_rfreal 
          pmixtinput%trk(2) = 8.0_rfreal/15.0_rfreal
          pmixtinput%trk(3) = 2.0_rfreal/3.0_rfreal

          pmixtinput%ldiss(1) = 1
          pmixtinput%ldiss(2) = 1
          pmixtinput%ldiss(3) = 1                 

          pmixtinput%cfl = min(pmixtinput%cfl,2.0_rfreal) ! stability margin        
        CASE default
          CALL errorstop(global,err_reached_default,__line__)
      END SELECT ! global%rkScheme
    END IF ! pMixtInput
  END DO ! iReg

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel >= verbose_high ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Setting derived input variables done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_derivedinputvalues

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_DerivedInputValues.F90,v $
! Revision 1.21  2008/12/06 08:44:12  mtcampbe
! Updated license.
!
! Revision 1.20  2008/11/19 22:17:25  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.19  2006/04/13 18:07:09  haselbac
! Bug fix: Changed indCp and indMol for GASLIQ model
!
! Revision 1.18  2006/04/07 14:42:20  haselbac
! Added setting of stencilDimens params
!
! Revision 1.17  2006/03/26 20:21:32  haselbac
! Added support for GL model
!
! Revision 1.16  2006/01/06 22:06:12  haselbac
! Added setting of stencilDimens
!
! Revision 1.15  2005/11/14 16:54:30  haselbac
! Added setting of variables for pseudo-gas model
!
! Revision 1.14  2005/11/10 02:01:30  haselbac
! Added setting of nGvAct, indCp, indMol depending on gasModel
!
! Revision 1.13  2004/11/17 16:27:36  haselbac
! Added setting of RK3 coeffs
!
! Revision 1.12  2004/11/14 19:38:24  haselbac
! Changed nDv and nGv for incompressible fluid model temporarily
!
! Revision 1.11  2004/11/02 02:27:58  haselbac
! Added setting of nCv etc for various fluid models
!
! Revision 1.10  2004/10/19 19:37:30  haselbac
! Cosmetics only
!
! Revision 1.9  2004/04/15 20:18:47  haselbac
! Major bug fix: Accidentally deleted setting of nrkSteps for unsteady flow
!
! Revision 1.8  2004/04/14 02:07:39  haselbac
! Clean-up
!
! Revision 1.7  2004/03/05 22:09:01  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.6  2004/01/29 23:03:32  haselbac
! Removed unnecessary iLev loop and cosmetic changes
!
! Revision 1.5  2003/12/04 03:23:50  haselbac
! Clean-up
!
! Revision 1.4  2003/11/25 21:02:45  haselbac
! Cosmetic changes only
!
! Revision 1.3  2003/07/03 21:48:45  jblazek
! Implemented dual-time stepping.
!
! Revision 1.2  2003/06/19 22:43:59  haselbac
! Changed trk to correspond to different use in rungeKutta
!
! Revision 1.1  2003/01/28 15:53:31  haselbac
! Initial revision, moved from rocflu, use LBOUND and UBOUND
!
! Revision 1.7  2002/10/12 14:56:24  haselbac
! Initialize trk
!
! Revision 1.6  2002/09/09 15:49:00  haselbac
! global now under regions, set nTv for NS, delete nGrad
!
! Revision 1.5  2002/07/25 14:27:43  haselbac
! Added MASTERPROC distinction for output
!
! Revision 1.4  2002/06/17 13:34:12  haselbac
! Prefixed SOLVER_NAME to all screen output
!
! Revision 1.3  2002/06/14 20:21:26  haselbac
! Cosmetic changes and prepared addition of grid speed stuff
!
! Revision 1.2  2002/05/04 17:06:31  haselbac
! Minor changes
!
! Revision 1.1  2002/03/26 19:27:52  haselbac
! Initial revision
!
! ******************************************************************************