RFLU_ConvFluxOLES.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute convective fluxes using optimal LES approach.
!
! Description: None.
!
! Input: region = data of current region.
!
! Output: region%mixt%rhs = convective fluxes added to the residual.
!
! Notes: 
!   1. No boundary fluxes because present implementation works only for 
!      isotropic turbulence
!   2. No grid speeds implemented.
!
!******************************************************************************
!
! $Id: RFLU_ConvFluxOLES.F90,v 1.7 2008/12/06 08:44:29 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflu_convfluxoles(region)

  USE modglobal, ONLY: t_global
  USE moddatatypes
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid  
  USE moderror
  USE modparameters
  
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i,ifc,ifcp,ipatch,j,k

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: c1,c2,ic1l,ic1g,ic2l,ic2g,ncells,netmassfluxcntr
  INTEGER, DIMENSION(:), POINTER :: f2fp
  INTEGER, DIMENSION(:,:), POINTER :: fs,f2c
  REAL(RFREAL) :: el,er,irl,irr,netmassflux,nm,nx,ny,nz,ql,qr,rl,rm,rr,vcont, & 
                  ul,ur,vl,vr,wl,wr,pl,pr
  REAL(RFREAL) :: fc(5),fl(3),fq(3),v1(3),v2(3)
  REAL(RFREAL), DIMENSION(:,:), POINTER :: cv,dv,rhs,fn
  REAL(RFREAL), DIMENSION(:,:,:,:), POINTER :: wtl
  REAL(RFREAL), DIMENSION(:,:,:,:,:,:), POINTER :: wtq
  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_ConvFluxOLES.F90,v $ $Revision: 1.7 $'

  global => region%global

  CALL registerfunction(global,'RFLU_ConvFluxOLES',&
  'RFLU_ConvFluxOLES.F90')

! get dimensions and pointers -------------------------------------------------

  cv  => region%mixt%cv
  dv  => region%mixt%dv
  rhs => region%mixt%rhs
  
  f2c  => region%grid%f2c
  fn   => region%grid%fn

  fs   => region%grid%fsOLES 
  f2fp => region%grid%f2fpOLES
  wtl  => region%grid%wtLinOLES
  wtq  => region%grid%wtQuadOLES

  netmassfluxcntr = 0
  netmassflux     = 0.0_rfreal

! stationary grid -------------------------------------------------------------
! flux (except through boundary)

  ncells = SIZE(fs,1) ! Get size of optimal LES stencil

  DO ifc = 1,region%grid%nFaces
    ifcp = f2fp(ifc) ! Get prototype face
  
    c1 = f2c(1,ifc)
    c2 = f2c(2,ifc)
                        
    nx = fn(xcoord,ifc)
    ny = fn(ycoord,ifc)
    nz = fn(zcoord,ifc)
    nm = fn(xyzmag,ifc)
  
    rl  = cv(cv_mixt_dens,c1)
    irl = 1.0_rfreal/rl
    
    ul  = cv(cv_mixt_xmom,c1)*irl
    vl  = cv(cv_mixt_ymom,c1)*irl
    wl  = cv(cv_mixt_zmom,c1)*irl
    el  = cv(cv_mixt_ener,c1)*irl
    pl  = dv(dv_mixt_pres,c1)
    
    ql  = ul*nx + vl*ny + wl*nz
    
    rr  = cv(cv_mixt_dens,c2)
    irr = 1.0_rfreal/rr
    
    rm  = 0.5_rfreal*(rl + rr)
    
    ur  = cv(cv_mixt_xmom,c2)*irr
    vr  = cv(cv_mixt_ymom,c2)*irr
    wr  = cv(cv_mixt_zmom,c2)*irr
    er  = cv(cv_mixt_ener,c2)*irr
    pr  = dv(dv_mixt_pres,c2)
    
    qr  = ur*nx + vr*ny + wr*nz    
   
! - Fluxes: mass and energy
      
    fc(1) = 0.5_rfreal*(ql* rl          + qr* rr         )*nm
    fc(5) = 0.5_rfreal*(ql*(rl*el + pl) + qr*(rr*er + pr))*nm    
    
! - Fluxes: momenta    

    fl(:) = 0.0_rfreal
    fq(:) = 0.0_rfreal

    DO i = 1,3  
      DO ic1l = 1,ncells           
        ic1g = fs(ic1l,ifc)

        v1(1:3) = cv(cv_mixt_xmom:cv_mixt_zmom,ic1g)/cv(cv_mixt_dens,ic1g)

        DO j = 1,3
          fl(i) = fl(i) + wtl(i,j,ic1l,ifcp)*v1(j)          
        END DO ! j
      
        DO ic2l = 1,ncells
          ic2g = fs(ic2l,ifc)
          v2(1:3) = cv(cv_mixt_xmom:cv_mixt_zmom,ic2g)/cv(cv_mixt_dens,ic2g)
        
          DO j = 1,3
            DO k = 1,3              
              fq(i) = fq(i) + wtq(i,j,k,ic1l,ic2l,ifcp)*v1(j)*v2(k)
            END DO ! k
          END DO ! j
         
        END DO ! ic2l
      END DO ! ic1l
         
      fl(i) = rm*fl(i)*nm
      fq(i) = rm*fq(i)*nm*sign(1.0_rfreal,fn(ifcp,ifc))     
    
      fc(i+1) = fl(i) + fq(i)
    END DO ! i     

! - Add pressure fluxes (simple central difference)

    fc(2) = fc(2) + 0.5_rfreal*(pl + pr)*nx*nm
    fc(3) = fc(3) + 0.5_rfreal*(pl + pr)*ny*nm    
    fc(4) = fc(4) + 0.5_rfreal*(pl + pr)*nz*nm

! - Add/subtract from residual
    
    rhs(cv_mixt_dens,c1) = rhs(cv_mixt_dens,c1) + fc(1)
    rhs(cv_mixt_xmom,c1) = rhs(cv_mixt_xmom,c1) + fc(2)
    rhs(cv_mixt_ymom,c1) = rhs(cv_mixt_ymom,c1) + fc(3)
    rhs(cv_mixt_zmom,c1) = rhs(cv_mixt_zmom,c1) + fc(4)
    rhs(cv_mixt_ener,c1) = rhs(cv_mixt_ener,c1) + fc(5)

    rhs(cv_mixt_dens,c2) = rhs(cv_mixt_dens,c2) - fc(1)
    rhs(cv_mixt_xmom,c2) = rhs(cv_mixt_xmom,c2) - fc(2)
    rhs(cv_mixt_ymom,c2) = rhs(cv_mixt_ymom,c2) - fc(3)
    rhs(cv_mixt_zmom,c2) = rhs(cv_mixt_zmom,c2) - fc(4)
    rhs(cv_mixt_ener,c2) = rhs(cv_mixt_ener,c2) - fc(5) 
    
! - Periodic boundary fluxes

    IF ( max(c1,c2) > region%grid%nCells ) THEN
      netmassfluxcntr = netmassfluxcntr + 1 
      netmassflux = netmassflux + fc(1)
    END IF ! MAX        
  END DO ! ifc

! finalize --------------------------------------------------------------------

  CALL deregisterfunction(global)

END SUBROUTINE rflu_convfluxoles

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ConvFluxOLES.F90,v $
! Revision 1.7  2008/12/06 08:44:29  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:17:42  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2003/06/04 22:52:30  haselbac
! Removed unnecessary interface
!
! Revision 1.4  2003/04/10 14:38:36  haselbac
! Changed interface statement
!
! Revision 1.3  2003/01/28 14:33:45  haselbac
! Use parameters in fn
!
! Revision 1.2  2002/09/09 15:46:05  haselbac
! complete basic coding, global now under regions, several bug fixes
!
! Revision 1.1  2002/07/25 14:18:28  haselbac
! Initial revision
!
!******************************************************************************