RFLU_ComputeVertexVariables.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Compute variables other than conserved variables at vertices.
!
! Description: None.
!
! Input: 
!   pRegion             Pointer to region data
!
! Output: None.
!
! Notes: 
!   1. This routine should only be used to compute variables at vertices 
!      which can be computed exclusively from variables already interpolated 
!      to vertices.
!
! ******************************************************************************
!
! $Id: RFLU_ComputeVertexVariables.F90,v 1.11 2008/12/06 08:45:05 mtcampbe Exp $
!
! Copyright: (c) 2003-2006 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_computevertexvariables(pRegion)

  USE moddatatypes
  USE modglobal, ONLY: t_global 
  USE modparameters
  USE moderror
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid
  
  USE modinterfaces, ONLY: mixtgasliq_c, &
                           mixtgasliq_p, &
                           mixtliq_c2_bp, &
                           mixtliq_d_dobpppobttto, &
                           mixtperf_c_dgp, & 
                           mixtperf_c_grt, &
                           mixtperf_c2_grt, &
                           mixtperf_cv_cpr, &
                           mixtperf_d_prt, &
                           mixtperf_g_cpr, & 
                           mixtperf_p_deogvm2, & 
                           mixtperf_r_m, &
                           mixtperf_t_cveovm2, & 
                           mixtperf_t_dpr
  
  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Local variables
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: indcp,indmol,ivg
  REAL(RFREAL) :: bg2,bl2,bp,bt,bv2,cg2,cl2,cv2,cp,cvg,cvl,cvm,cvv,eo,g,gc, &
                  ir,mw,p,po,r,reo,rg,rgas,rl,ro,ru,rv,rvap,rw,ryg,ryl,ryv, &
                  to,u,v,vfg,vfl,vfv,vm2,w
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pdv,pgv
#ifdef SPEC
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcvspec
#endif
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_ComputeVertexVariables.F90,v $ $Revision: 1.11 $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_ComputeVertexVariables', &
                        'RFLU_ComputeVertexVariables.F90')

  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Computing vertex variables...'
  END IF ! global%verbLevel

! ******************************************************************************
! Set pointers and variables
! ******************************************************************************

  pgrid => pregion%grid
  
  pcv   => pregion%mixt%cvVert ! NOTE vertex variables
  pdv   => pregion%mixt%dvVert
  pgv   => pregion%mixt%gvVert

#ifdef SPEC
  pcvspec => pregion%spec%cvVert
#endif

  indcp  = pregion%mixtInput%indCp
  indmol = pregion%mixtInput%indMol
  
! ******************************************************************************
! Compute dependent variables
! ******************************************************************************

  SELECT CASE ( pregion%mixtInput%fluidModel )

! ==============================================================================  
!   Incompressible fluid model
! ==============================================================================  
   
    CASE ( fluid_model_incomp ) 

! ==============================================================================  
!   Compressible fluid model. NOTE check state of solution vector.
! ==============================================================================  
    
    CASE ( fluid_model_comp )   
      IF ( pregion%mixt%cvState /= cv_mixt_state_cons ) THEN 
        CALL errorstop(global,err_cv_state_invalid,__line__)
      END IF ! pRegion%mixt%cvState    

      SELECT CASE ( pregion%mixtInput%gasModel ) 

! ------------------------------------------------------------------------------
!       Gas models without liquid phase
! ------------------------------------------------------------------------------      

        CASE ( gas_model_tcperf, & 
               gas_model_tperf, & 
               gas_model_mixt_tcperf, & 
               gas_model_mixt_tperf, & 
               gas_model_mixt_pseudo )
          DO ivg = 1,pgrid%nVertTot
            r   = pcv(cv_mixt_dens,ivg)
            ru  = pcv(cv_mixt_xmom,ivg)
            rv  = pcv(cv_mixt_ymom,ivg)
            rw  = pcv(cv_mixt_zmom,ivg)
            reo = pcv(cv_mixt_ener,ivg)                

            ir  = 1.0_rfreal/r
            u   = ir*ru
            v   = ir*rv
            w   = ir*rw    
            eo  = ir*reo
            vm2 = u*u + v*v + w*w

            cp = pgv(gv_mixt_cp ,indcp *ivg)
            mw = pgv(gv_mixt_mol,indmol*ivg)

            gc = mixtperf_r_m(mw)
            g  = mixtperf_g_cpr(cp,gc)

            p = mixtperf_p_deogvm2(r,eo,g,vm2)

            pdv(dv_mixt_pres,ivg) = p
            pdv(dv_mixt_temp,ivg) = mixtperf_t_dpr(r,p,gc)
            pdv(dv_mixt_soun,ivg) = mixtperf_c_dgp(r,g,p)     
          END DO ! ivg

! ------------------------------------------------------------------------------
!       Mixture of gas, liquid, and vapor
! ------------------------------------------------------------------------------      

        CASE ( gas_model_mixt_gasliq ) 
#ifdef SPEC
          IF ( pregion%mixt%cvState /= cv_mixt_state_cons ) THEN
            CALL errorstop(global,err_cv_state_invalid,__line__)
          END IF ! pRegion%mixt%cvState

          ro  = global%refDensityLiq
          po  = global%refPressLiq
          to  = global%refTempLiq
          bp  = global%refBetaPLiq
          bt  = global%refBetaTLiq
          cvl = global%refCvLiq

          rgas = mixtperf_r_m(pregion%specInput%specType(1)%pMaterial%molw)
          cvg  = mixtperf_cv_cpr(pregion%specInput%specType(1)%pMaterial%spht, &
                                 rgas)

          rvap = mixtperf_r_m(pregion%specInput%specType(2)%pMaterial%molw)
          cvv  = mixtperf_cv_cpr(pregion%specInput%specType(2)%pMaterial%spht, &
                                 rvap)

          DO ivg = 1,pgrid%nVertTot
            r   = pcv(cv_mixt_dens,ivg)
            ru  = pcv(cv_mixt_xmom,ivg)
            rv  = pcv(cv_mixt_ymom,ivg)
            rw  = pcv(cv_mixt_zmom,ivg)
            reo = pcv(cv_mixt_ener,ivg)

            ir  = 1.0_rfreal/r
            u   = ir*ru
            v   = ir*rv
            w   = ir*rw
            eo  = ir*reo
            vm2 = u*u + v*v + w*w

            ryg  = pcvspec(1,ivg)
            ryv  = pcvspec(2,ivg)
            ryl  = r - ryg - ryv

            cvm  = (ryl*cvl + ryv*cvv + ryg*cvg)/r

            pdv(dv_mixt_temp,ivg) = mixtperf_t_cveovm2(cvm,eo,vm2)

            cl2  = mixtliq_c2_bp(bp)
            cv2  = mixtperf_c2_grt(1.0_rfreal,rvap,pdv(dv_mixt_temp,ivg))
            cg2  = mixtperf_c2_grt(1.0_rfreal,rgas,pdv(dv_mixt_temp,ivg))

            pdv(dv_mixt_pres,ivg) = mixtgasliq_p(ryl,ryv,ryg,cl2,cv2,cg2,r,ro, &
                                                 po,to,bp,bt, &
                                                 pdv(dv_mixt_temp,ivg))
            rl = mixtliq_d_dobpppobttto(ro,bp,bt,pdv(dv_mixt_pres,ivg),po, &
                                        pdv(dv_mixt_temp,ivg),to)
            rv = mixtperf_d_prt(pdv(dv_mixt_pres,ivg),rvap,pdv(dv_mixt_temp,ivg))
            rg = mixtperf_d_prt(pdv(dv_mixt_pres,ivg),rgas,pdv(dv_mixt_temp,ivg))

            vfg = ryg/rg
            vfv = ryv/rv
            vfl = 1.0_rfreal - vfg - vfv

            bl2 = -bt/bp
            bv2 = rv*rvap
            bg2 = rg*rgas

            pdv(dv_mixt_soun,ivg) = mixtgasliq_c(cvm,r,pdv(dv_mixt_pres,ivg), &
                                                 rl,rv,rg,vfl,vfv,vfg,cl2,cv2, &
                                                 cg2,bl2,bv2,bg2) 
          END DO ! ivg       
#else
          CALL errorstop(global,err_reached_default,__line__)
#endif        
        CASE default
          CALL errorstop(global,err_reached_default,__line__)
      END SELECT ! pRegion%mixt%gasModel

! ==============================================================================  
!   Default
! ==============================================================================  

    CASE default
      CALL errorstop(global,err_reached_default,__line__)
  END SELECT ! pRegion%mixtInput%fluidModel 

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Computing vertex variables done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_computevertexvariables

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ComputeVertexVariables.F90,v $
! Revision 1.11  2008/12/06 08:45:05  mtcampbe
! Updated license.
!
! Revision 1.10  2008/11/19 22:18:16  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.9  2006/04/07 15:19:26  haselbac
! Removed tabs
!
! Revision 1.8  2006/03/26 20:28:45  haselbac
! Added support for GL model
!
! Revision 1.7  2005/11/10 02:47:15  haselbac
! Added support for variable properties
!
! Revision 1.6  2005/10/31 21:09:39  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.5  2004/11/14 19:56:57  haselbac
! Added setting of vertex variables for various fluid models
!
! Revision 1.4  2003/12/04 03:32:59  haselbac
! Added missing description of input argument
!
! Revision 1.3  2003/11/25 21:03:54  haselbac
! Added clarifying comment under Notes
!
! Revision 1.2  2003/03/20 20:07:19  haselbac
! Modified RegFun call to avoid probs with long 'RFLU_ComputeVertexVariables.F90' names
!
! Revision 1.1  2003/03/15 19:16:54  haselbac
! Initial revision
!
! ******************************************************************************