RFLU_CheckValidity_GL.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Check validity of variables
!
! Description: None.
!
! Input: 
!   pRegion     Region data
!
! Output: None.
!
! Notes: 
!   1. Compute and check pressure here because, it being computed later 
!      through a call to MixtureProperties, an invalid value would not be
!      detected.
!
! ******************************************************************************
!
! $Id: RFLU_CheckValidity_GL.F90,v 1.4 2008/12/06 08:44:11 mtcampbe Exp $
!
! Copyright: (c) 2006 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_checkvalidity_gl(pRegion)

  USE moddatatypes
  USE moderror
  USE modglobal, ONLY: t_global
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid
  USE modparameters
  USE modmpi
  USE modtools, ONLY: isnan
 
  USE modinterfaces, ONLY: mixtgasliq_p, &
                           mixtliq_c2_bp, &
                           mixtperf_c2_grt, &
                           mixtperf_cv_cpr, &
                           mixtperf_r_m, &
                           mixtperf_t_cveovm2, &
                           rflu_printlocinfo
  
  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER, PARAMETER :: max_invalid_locs = 10
  INTEGER :: icg,indcp,indmol,nlocs
  INTEGER :: loc(max_invalid_locs,min_val:max_val)
  REAL(RFREAL) :: bp,bt,cg2,cl2,cpgas,cpvap,cv2,cvg,cvl,cvm,cvv,eo,p,po, &
                  rgas,rho,rhoyg,rhoyl,rhoyv,ro,rrho,rvap,t,to,u,v,vm2,w
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pcvspec,pdv,pgv
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_CheckValidity_GL.F90,v $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_CheckValidity_GL',&
  'RFLU_CheckValidity_GL.F90')

! ******************************************************************************
! Set pointers and variables
! ******************************************************************************

  pgrid => pregion%grid

  pcv => pregion%mixt%cv
  pdv => pregion%mixt%dv
  pgv => pregion%mixt%gv

#ifdef SPEC
  pcvspec => pregion%spec%cv
#endif

  nlocs = 0

  indcp  = pregion%mixtInput%indCp
  indmol = pregion%mixtInput%indMol

  ro  = global%refDensityLiq
  po  = global%refPressLiq
  to  = global%refTempLiq
  bp  = global%refBetaPLiq
  bt  = global%refBetaTLiq
  cvl = global%refCvLiq

  rgas = mixtperf_r_m(pregion%specInput%specType(1)%pMaterial%molw)
  cvg  = mixtperf_cv_cpr(pregion%specInput%specType(1)%pMaterial%spht,rgas)

  rvap = mixtperf_r_m(pregion%specInput%specType(2)%pMaterial%molw)
  cvv  = mixtperf_cv_cpr(pregion%specInput%specType(2)%pMaterial%spht,rvap)

! *****************************************************************************
! Loop over cells and check for positivity
! *****************************************************************************

  DO icg = 1,pgrid%nCells
    rho   = pcv(cv_mixt_dens,icg)
    rrho  = 1.0_rfreal/rho
    rhoyg = pcvspec(1,icg)
    rhoyv = pcvspec(2,icg)
    rhoyl = rho - rhoyg - rhoyv 

    u  = rrho*pcv(cv_mixt_xmom,icg)
    v  = rrho*pcv(cv_mixt_ymom,icg)
    w  = rrho*pcv(cv_mixt_zmom,icg)
    eo = rrho*pcv(cv_mixt_ener,icg)

    vm2 = u*u + v*v + w*w
    cvm = (rhoyl*cvl + rhoyv*cvv + rhoyg*cvg)/rho
    t   = mixtperf_t_cveovm2(cvm,eo,vm2)

    cl2 = mixtliq_c2_bp(bp)
    cv2 = mixtperf_c2_grt(1.0_rfreal,rgas,t)
    cg2 = mixtperf_c2_grt(1.0_rfreal,rvap,t)

    p = mixtgasliq_p(rhoyl,rhoyv,rhoyg,cl2,cv2,cg2,rho,ro,po,to,bp,bt,t)

    IF ( (isnan(rho) .EQV. .true.) .OR. & 
         (isnan(u)   .EQV. .true.) .OR. &
         (isnan(v)   .EQV. .true.) .OR. & 
         (isnan(w)   .EQV. .true.) .OR. & 
         (isnan(p)   .EQV. .true.) .OR. &
         (isnan(t)   .EQV. .true.) ) THEN
      nlocs = nlocs + 1   

      IF ( nlocs == 1 ) THEN 
        WRITE(stdout,'(A,1X,A,1X,I9)') solver_name, & 
              'Invalid variables detected!'
              
        IF ( global%flowType == flow_unsteady ) THEN 
          WRITE(stdout,'(A,3X,A,1X,1PE12.5)') solver_name,'Current time:', &
                                              global%currentTime              
        ELSE 
          WRITE(stdout,'(A,3X,A,1X,I6)') solver_name, &
                                         'Current iteration number:', &
                                         global%currentIter           
        END IF ! global%flowType                 
                                            
        WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                         pregion%iRegionGlobal 
        WRITE(stdout,'(A,6X,A,6(1X,A))') solver_name,'#', &
                                         '   Density   ', &
                                         '  x-velocity ', &
                                         '  y-velocity ', &
                                         '  z-velocity ', &
                                         '   Pressure  ', &
                                         ' Temperature '       
      END IF ! nLocs

      IF ( nlocs <= max_invalid_locs ) THEN 
        WRITE(stdout,'(A,4X,I3,6(1X,E13.6))') solver_name,nlocs, & 
                                              rho,u,v,w,p,t
        loc(nlocs,min_val:max_val) = icg                                   
      END IF ! nLocs
    END IF ! cv    
  END DO ! icg

! *****************************************************************************
! Write out message and call error handling routine
! *****************************************************************************

  IF ( nlocs > 0 ) THEN 
    IF ( nlocs > max_invalid_locs ) THEN 
       WRITE(stdout,'(A,3X,A,1X,I3,1X,A,1X,I9,1X,A)') solver_name, & 
             'Only wrote the first',max_invalid_locs,'of',nlocs, & 
             'cells with invalid variables.'    
      CALL rflu_printlocinfo(pregion,loc,max_invalid_locs, & 
                             locinfo_mode_silent,output_mode_anybody)
    ELSE 
      CALL rflu_printlocinfo(pregion,loc(1:nlocs,min_val:max_val),nlocs, & 
                             locinfo_mode_silent,output_mode_anybody)
    END IF ! nLocs
    
    CALL errorstop(global,err_invalid_value,__line__)   
  END IF ! nLocs

! *****************************************************************************
! End
! *****************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_checkvalidity_gl

! *****************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_CheckValidity_GL.F90,v $
! Revision 1.4  2008/12/06 08:44:11  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:25  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:16  haselbac
! Removed tabs
!
! Revision 1.1  2006/03/26 20:21:00  haselbac
! Initial revision
!
! *****************************************************************************