RFLU_CheckPositivity.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Check for posivity of variables
!
! Description: None.
!
! Input: 
!   pRegion     Region data
!
! Output: None.
!
! Notes: 
!   1. Compute and check pressure here because, it being computed later 
!      through a call to MixtureProperties, a negative value would not be
!      detected and could cause negative pressure and temperature.
!
! ******************************************************************************
!
! $Id: RFLU_CheckPositivity.F90,v 1.14 2008/12/06 08:44:11 mtcampbe Exp $
!
! Copyright: (c) 2002-2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_checkpositivity(pRegion)

  USE moddatatypes
  USE moderror
  USE modglobal, ONLY: t_global
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid
  USE modparameters
  USE modmpi
  
  USE modinterfaces, ONLY: mixtperf_g_cpr, &
                           mixtperf_p_deogvm2, &
                           mixtperf_r_m, &
                           mixtperf_t_dpr, &
                           rflu_printlocinfo
  
  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER, PARAMETER :: max_negative_locs = 10
  INTEGER :: icg,indcp,indmol,nlocs
  INTEGER :: loc(max_negative_locs,min_val:max_val)
  REAL(RFREAL) :: eo,gamma,p,rgas,rho,rrho,t,u,v,vm2,w
  REAL(RFREAL), DIMENSION(:,:), POINTER :: cv,dv,gv
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_CheckPositivity.F90,v $ $Revision: 1.14 $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_CheckPositivity',&
  'RFLU_CheckPositivity.F90')

! ******************************************************************************
! Set pointers and variables
! ******************************************************************************

  pgrid => pregion%grid

  nlocs = 0

  indcp  = pregion%mixtInput%indCp
  indmol = pregion%mixtInput%indMol 

#ifdef ROCPROF
  CALL fprofiler_begins("RFLU::CheckPositivity")
#endif

! ******************************************************************************
! Loop over cells and check for positivity
! ******************************************************************************

  cv => pregion%mixt%cv
  dv => pregion%mixt%dv
  gv => pregion%mixt%gv

  DO icg = 1,pgrid%nCells
    rho  = cv(cv_mixt_dens,icg)
    rrho = 1.0_rfreal/rho
    u    = rrho*cv(cv_mixt_xmom,icg)
    v    = rrho*cv(cv_mixt_ymom,icg)
    w    = rrho*cv(cv_mixt_zmom,icg)        
    eo   = rrho*cv(cv_mixt_ener,icg)
    
    rgas  = mixtperf_r_m(gv(gv_mixt_mol,icg*indmol))
    gamma = mixtperf_g_cpr(gv(gv_mixt_cp,icg*indcp),rgas)
    vm2   = u*u + v*v + w*w
    
    p = mixtperf_p_deogvm2(rho,eo,gamma,vm2)
    t = mixtperf_t_dpr(rho,p,rgas)

    IF ( (rho <= 0.0_rfreal) .OR. (p <= 0.0_rfreal) ) THEN
      nlocs = nlocs + 1   

      IF ( nlocs == 1 ) THEN 
        WRITE(stdout,'(A,1X,A)') solver_name, & 
              'Negative positive-definite variables detected!'
        WRITE(stdout,'(A,3X,A)') solver_name,'Module: Mixture.'        
              
        IF ( global%flowType == flow_unsteady ) THEN 
          WRITE(stdout,'(A,3X,A,1X,1PE12.5)') solver_name,'Current time:', &
                                              global%currentTime              
        ELSE 
          WRITE(stdout,'(A,3X,A,1X,I6)') solver_name, &
                                         'Current iteration number:', &
                                         global%currentIter           
        END IF ! global%flowType                 
                                            
        WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                         pregion%iRegionGlobal 
        WRITE(stdout,'(A,6X,A,6(1X,A))') solver_name,'#', &
                                         '   Density   ', &
                                         '  x-velocity ', &
                                         '  y-velocity ', &
                                         '  z-velocity ', &
                                         '   Pressure  ', &
                                         ' Temperature '       
      END IF ! nLocs

      IF ( nlocs <= max_negative_locs ) THEN 
        WRITE(stdout,'(A,4X,I3,6(1X,E13.6))') solver_name,nlocs, & 
                                              rho,u,v,w,p,t
        loc(nlocs,min_val:max_val) = icg                                   
      END IF ! nLocs
    END IF ! cv    
  END DO ! icg

! ******************************************************************************
! Write out message and call error handling routine
! ******************************************************************************

  IF ( nlocs > 0 ) THEN 
    IF ( nlocs > max_negative_locs ) THEN 
       WRITE(stdout,'(A,3X,A,1X,I3,1X,A,1X,I9,1X,A)') solver_name, & 
             'Only wrote the first',max_negative_locs,'of',nlocs, & 
             'cells with negative positive-definite variables.'    
      CALL rflu_printlocinfo(pregion,loc,max_negative_locs, & 
                             locinfo_mode_silent,output_mode_anybody)
    ELSE 
      CALL rflu_printlocinfo(pregion,loc(1:nlocs,min_val:max_val),nlocs, & 
                             locinfo_mode_silent,output_mode_anybody)
    END IF ! nLocs
    
    CALL errorstop(global,err_negative_posdef,__line__)   
  END IF ! nLocs

! ******************************************************************************
! End
! ******************************************************************************

#ifdef ROCPROF
  CALL fprofiler_ends("RFLU::CheckPositivity")
#endif

  CALL deregisterfunction(global)

END SUBROUTINE rflu_checkpositivity

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_CheckPositivity.F90,v $
! Revision 1.14  2008/12/06 08:44:11  mtcampbe
! Updated license.
!
! Revision 1.13  2008/11/19 22:17:25  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.12  2006/04/07 15:19:16  haselbac
! Removed tabs
!
! Revision 1.11  2006/03/26 20:21:25  haselbac
! Removed dv declaration and definition
!
! Revision 1.10  2005/07/07 22:44:00  haselbac
! Added profiling calls, cosmetics
!
! Revision 1.9  2004/01/29 22:56:27  haselbac
! Some clean-up and cosmetic changes
!
! Revision 1.8  2004/01/11 02:06:38  jiao
! Eliminated some redundant trailing spaces that made some lines too long.
! This changed was needed to compile with NAG F90 compiler.
!
! Revision 1.7  2003/12/04 03:33:53  haselbac
! Clean-up and minor changes
!
! Revision 1.6  2003/07/22 02:12:58  haselbac
! Cosmetics only
!
! Revision 1.5  2003/06/04 22:00:37  haselbac
! Rewrite to be more informative
!
! Revision 1.4  2003/05/13 23:47:21  haselbac
! Added check for pressure, cosmetics
!
! Revision 1.3  2003/04/10 14:38:24  haselbac
! Changed interface statement
!
! Revision 1.2  2003/03/15 16:48:09  haselbac
! Cosmetics, adapted function calls
!
! Revision 1.1  2002/10/27 18:55:24  haselbac
! Initial revision
!
! ******************************************************************************