RFLO_WriteRandomState.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: write state of random number generator for structured code
!
! Description: the following solution formats are supported:
!              - RocfloMP ASCII
!              - RocfloMP binary.
!
! Input: regions(:)%randData = state of RNG for each region
!        global%currentTime  = physical time
!
! Output: to file.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_WriteRandomState.F90,v 1.3 2008/12/06 08:44:07 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_writerandomstate( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE moderror
  USE modmpi
  USE modparameters
  USE modrandom

  USE modinterfaces, ONLY : rflo_writedatafileint, rflo_writedatafilereal
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, i

! ... local variables
  INTEGER, PARAMETER     :: n_rvar = 1
  INTEGER, PARAMETER     :: n_ivar_extra = 1
  INTEGER, PARAMETER     :: randstate_offset = n_ivar_extra+1
  INTEGER, PARAMETER     :: n_randstate = rand_total_size+n_ivar_extra

  CHARACTER(2*CHRLEN+18) :: fname, fhead
  CHARACTER(CHRLEN)      :: rcsidentstring, msg

#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: errorflag, randstate(n_randstate,1)

  REAL(RFREAL) :: rvar(n_rvar,1)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_WriteRandomState',&
  'RFLO_WriteRandomState.F90' )

! begin -----------------------------------------------------------------------

! open random state file (only master proc.) ----------------------------------

  IF (global%myProcid == masterproc) THEN

    fhead = trim(global%inDir)//trim(global%casename)

    SELECT CASE(global%solutFormat)
    CASE (format_ascii)
      fhead = trim(fhead)//'.randa_'
    CASE (format_binary)
      fhead = trim(fhead)//'.randb_'
    CASE default
      CALL errorstop( global,err_unknown_format,&
      __line__ )
    END SELECT

    IF (global%flowType == flow_unsteady) THEN
      WRITE(fname,'(A,ES11.5)') trim(fhead), global%currentTime
      rvar(1,1) = global%currentTime
    ELSE
      WRITE(fname,'(A,I6.6)')   trim(fhead), global%currentIter
      rvar(1,1) = 0._rfreal
    ENDIF

    SELECT CASE(global%solutFormat)
    CASE (format_ascii)
      OPEN(if_rand_state,file=fname,form=  'formatted',status='unknown', &
        iostat=errorflag)
    CASE (format_binary)
      OPEN(if_rand_state,file=fname,form='unformatted',status='unknown', &
        iostat=errorflag)
    CASE default
      CALL errorstop( global,err_unknown_format,&
      __line__ )
    END SELECT

    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_open,&
      __line__,'File: '//trim(fname) )

! - Write time stamp to file --------------------------------------------------

    CALL rflo_writedatafilereal( global,if_rand_state,global%solutFormat, &
                                 n_rvar,1,rvar )

  ENDIF ! MASTERPROC

! write data  -----------------------------------------------------------------

  DO ireg=1,global%nRegions

! - copy randData into temporary array

    IF (regions(ireg)%procid == global%myProcid) THEN
      randstate(1,1) = ireg
      DO i=0,rand_total_size-1
        randstate(i+randstate_offset,1) = regions(ireg)%randData%mt(i)
      ENDDO ! i
    ENDIF ! global%myProcid

! - master receives and writes data, others send them -------------------------

    IF (global%myProcid == masterproc) THEN

#ifdef MPI
      IF (regions(ireg)%procid /= masterproc) THEN

        CALL mpi_recv( randstate,n_randstate,mpi_integer, &
                       regions(ireg)%procid,ireg, &
                       global%mpiComm,status,global%mpierr )
        IF (global%mpierr /=0) CALL errorstop(global,err_mpi_trouble,&
        __line__)

      ENDIF
#endif

      CALL rflo_writedatafileint( global,if_rand_state,global%solutFormat, &
                                  n_randstate,1,randstate )

    ELSE ! not the master

#ifdef MPI
      IF (regions(ireg)%procid == global%myProcid) THEN

        CALL mpi_send( randstate,n_randstate,mpi_integer,masterproc,ireg, &
                       global%mpiComm,global%mpierr )
        IF (global%mpierr /=0) CALL errorstop(global,err_mpi_trouble,&
        __line__)

      ENDIF
#endif

    ENDIF ! MASTERPROC

  ENDDO ! iReg

! finalize --------------------------------------------------------------------

  IF (global%myProcid == masterproc) THEN
    CLOSE(if_rand_state,iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_close,&
      __line__,'File: '//trim(fname) )
  ENDIF

999  CONTINUE
  CALL deregisterfunction( global )

END SUBROUTINE rflo_writerandomstate

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_WriteRandomState.F90,v $
! Revision 1.3  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:21  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:17  wasistho
! lower to upper case
!
! Revision 1.1  2003/11/21 22:29:02  fnajjar
! Added Write capability for Random Number Generator
!
!******************************************************************************