RFLO_SendCornerEdgeCells.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: send values to edge and corner cells of an adjacent region.
!
! Description: this is for the case if the other region is located
!              on a different processor.
!
! Input: regions = data of all regions
!        iReg    = current region.
!
! Output: new values of conservative variables.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_SendCornerEdgeCells.F90,v 1.3 2008/12/06 08:44:28 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_sendcorneredgecells( regions,iReg )

  USE moddatatypes
  USE modglobal, ONLY     : t_global
  USE moddatastruct, ONLY : t_region, t_level, t_dcelltransf
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

  INTEGER :: ireg

! ... loop variables
  INTEGER :: ir, iedge, icorner, ijk

! ... local variables
  INTEGER :: ilev, iregsrc, icell, ibuff, ndim, dest, tag

  REAL(RFREAL), POINTER :: cv(:,:)

  TYPE(t_global), POINTER      :: global
  TYPE(t_level), POINTER       :: level
  TYPE(t_dcelltransf), POINTER :: sendeccell

!******************************************************************************

  global => regions(ireg)%global

  CALL registerfunction( global,'RFLO_SendCornerEdgeCells',&
  'RFLO_SendCornerEdgeCells.F90' )

  ilev =  regions(ireg)%currLevel
  cv   => regions(ireg)%levels(ilev)%mixt%cv

! fill send buffers

  DO ir=1,global%nRegions
    IF (regions(ir)%procid /= global%myProcid) THEN
    IF (regions(ireg)%levels(ilev)%sendEcCells(ir)%nCells > 0) THEN

      sendeccell => regions(ireg)%levels(ilev)%sendEcCells(ir)
      level      => regions(ir)%levels(ilev)
      ndim       =  sendeccell%nCells
      ibuff      =  0

      DO iedge=1,12
        IF (level%edgeCells(iedge)%interact .AND. &
            level%edgeCells(iedge)%degenrt==degenerat_none) THEN
          DO ijk=1,ubound(level%edgeCells(iedge)%cells,1)
            iregsrc = level%edgeCells(iedge)%cells(ijk)%srcRegion
            icell   = level%edgeCells(iedge)%cells(ijk)%srcCell
            IF (iregsrc == ireg) THEN
              ibuff = ibuff + 1
              sendeccell%buff(ibuff       ) = cv(cv_mixt_dens,icell)
              sendeccell%buff(ibuff+  ndim) = cv(cv_mixt_xmom,icell)
              sendeccell%buff(ibuff+2*ndim) = cv(cv_mixt_ymom,icell)
              sendeccell%buff(ibuff+3*ndim) = cv(cv_mixt_zmom,icell)
              sendeccell%buff(ibuff+4*ndim) = cv(cv_mixt_ener,icell)
            ENDIF
          ENDDO
        ENDIF
      ENDDO
      DO icorner=1,8
        IF (level%cornerCells(icorner)%interact .AND. &
            level%cornerCells(icorner)%degenrt==degenerat_none) THEN
          DO ijk=1,ubound(level%cornerCells(icorner)%cells,1)
            iregsrc = level%cornerCells(icorner)%cells(ijk)%srcRegion
            icell   = level%cornerCells(icorner)%cells(ijk)%srcCell
            IF (iregsrc == ireg) THEN
              ibuff = ibuff + 1
              sendeccell%buff(ibuff       ) = cv(cv_mixt_dens,icell)
              sendeccell%buff(ibuff+  ndim) = cv(cv_mixt_xmom,icell)
              sendeccell%buff(ibuff+2*ndim) = cv(cv_mixt_ymom,icell)
              sendeccell%buff(ibuff+3*ndim) = cv(cv_mixt_zmom,icell)
              sendeccell%buff(ibuff+4*ndim) = cv(cv_mixt_ener,icell)
            ENDIF
          ENDDO
        ENDIF
      ENDDO

#ifdef MPI
      dest = regions(ir)%procid
      tag  = regions(ir)%localNumber
      CALL mpi_isend( sendeccell%buff,cv_mixt_neqs*ndim,mpi_rfreal, &
                      dest,tag,global%mpiComm, &
                      global%requests(sendeccell%iRequest),global%mpierr )
      IF (global%mpierr /= 0) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

    ENDIF      ! some cells to send
    ENDIF      ! not my processor
  ENDDO        ! ir

! finalize

  CALL deregisterfunction( global )

END SUBROUTINE rflo_sendcorneredgecells

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_SendCornerEdgeCells.F90,v $
! Revision 1.3  2008/12/06 08:44:28  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:38  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:40  wasistho
! lower to upper case
!
! Revision 1.9  2004/09/02 01:35:17  wasistho
! replaced 0 with DEGENERAT_NONE
!
! Revision 1.8  2004/09/02 01:23:32  wasistho
! do not exchange and send/recv for degenerated e/c
!
! Revision 1.7  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.6  2003/02/28 21:04:27  jblazek
! Corrected bug in send/recv of CE cells on single processor.
!
! Revision 1.5  2003/02/14 22:32:37  jblazek
! Finished implementation of corener and edge cells.
!
! Revision 1.4  2002/09/05 17:40:22  jblazek
! Variable global moved into regions().
!
! Revision 1.3  2002/03/18 23:11:33  jblazek
! Finished multiblock and MPI.
!
! Revision 1.2  2002/02/21 23:25:06  jblazek
! Blocks renamed as regions.
!
! Revision 1.1  2002/01/31 20:20:13  jblazek
! Added treatment of edge & corner cells.
!
!******************************************************************************