RFLO_ReadRandomState.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: read state of random number generator for structured code
!
! Description: the following solution formats are supported:
!              - RocfloMP ASCII
!              - RocfloMP binary.
!
! Input: regions = dimensions of all regions.
!
! Output: regions(:)%randData = state of RNG for each region
!         global%currentTime  = physical time
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_ReadRandomState.F90,v 1.3 2008/12/06 08:44:07 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_readrandomstate( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE moderror
  USE modmpi
  USE modparameters
  USE modrandom

  USE modinterfaces, ONLY : rflo_readdatafileint, rflo_readdatafilereal
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, i

! ... local variables
  INTEGER, PARAMETER     :: n_rvar = 1
  INTEGER, PARAMETER     :: n_ivar_extra = 1
  INTEGER, PARAMETER     :: randstate_offset = n_ivar_extra+1
  INTEGER, PARAMETER     :: n_randstate = rand_total_size+n_ivar_extra

  CHARACTER(2*CHRLEN+18) :: fname, fhead
  CHARACTER(CHRLEN)      :: rcsidentstring, msg

#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: errorflag, mti, randstate(n_randstate,1)

  REAL(RFREAL) :: rvar(n_rvar,1)

  LOGICAL :: fileexists

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_ReadRandomState',&
  'RFLO_ReadRandomState.F90' )

! begin -----------------------------------------------------------------------

! determine if RNG state file exists ------------------------------------------

  fhead = trim(global%inDir)//trim(global%casename)

  SELECT CASE(global%solutFormat)
  CASE (format_ascii)
    fhead = trim(fhead)//'.randa_'
  CASE (format_binary)
    fhead = trim(fhead)//'.randb_'
  CASE default
    CALL errorstop( global,err_unknown_format,__line__ )
  END SELECT

  IF (global%flowType == flow_unsteady) THEN
    WRITE(fname,'(A,ES11.5)') trim(fhead), global%timeStamp
  ELSE
    WRITE(fname,'(A,I6.6)')   trim(fhead), global%currentIter
  ENDIF

  INQUIRE(file=fname,exist=fileexists)

  IF (.NOT.fileexists) THEN
    IF (global%myProcid == masterproc .AND. &
        global%currentTime > 0._rfreal) THEN
      WRITE(stdout,'(A)') solver_name// &
        '### WARNING: No Random State file found: '// &
        'Random Number Generator re-initialized'
    ENDIF ! MASTERPROC
    go to 999
  ENDIF ! fileExists

! open random state file (only master proc.) ----------------------------------

  IF (global%myProcid == masterproc) THEN

    SELECT CASE(global%solutFormat)
    CASE (format_ascii)
      OPEN(if_rand_state,file=fname,form=  'formatted',status='old', &
        iostat=errorflag)
    CASE (format_binary)
      OPEN(if_rand_state,file=fname,form='unformatted',status='old', &
        iostat=errorflag)
    CASE default
      CALL errorstop( global,err_unknown_format,__line__ )
    END SELECT

    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_open,__line__,'File: '//trim(fname) )

! - Read time stamp of RNG state, and yield an error if not the current time --

    CALL rflo_readdatafilereal( global,if_rand_state,global%solutFormat, &
                                n_rvar,1,rvar )

    IF (global%flowType==flow_unsteady.AND.global%currentTime/=rvar(1,1)) THEN
      WRITE(msg,1000) rvar(1,1),global%currentTime
      CALL errorstop( global,err_time_solution,__line__,msg//' File: '// &
        trim(fname) )
    ENDIF

  ENDIF ! MASTERPROC

! Receive data from master ----------------------------------------------------

  DO ireg=1,global%nRegions

! - Read the RNG state for each region (only master) --------------------------

    IF (global%myProcid == masterproc) THEN

      CALL rflo_readdatafileint( global,if_rand_state,global%solutFormat, &
                                 n_randstate,1,randstate )

      IF (randstate(1,1) /= ireg) &
        CALL errorstop( global,err_region_number,__line__,'File: '// &
          trim(fname) )

! --- Allowable values of mti are within array bounds 0:RAND_BUFFER_SIZE-1,
! --- or the special case mti = RAND_BUFFER_SIZE (generates array refill)

      mti = randstate(rand_mti_index+randstate_offset,1)

      IF (mti < 0 .OR. mti > rand_buffer_size) &
        CALL errorstop( global,err_exceeds_decl_mem,__line__ )

#ifdef MPI
      IF (regions(ireg)%procid /= masterproc) THEN

        CALL mpi_send( randstate,n_randstate,mpi_integer, &
                       regions(ireg)%procid,ireg, &
                       global%mpiComm,global%mpierr )
        IF (global%mpierr /=0) CALL errorstop( global,err_mpi_trouble,__line__ )

      ENDIF

    ELSE ! not the master

      IF (regions(ireg)%procid == global%myProcid) THEN

        CALL mpi_recv( randstate,n_randstate,mpi_integer,masterproc,ireg, &
                       global%mpiComm,status,global%mpierr )
        IF (global%mpierr /=0) CALL errorstop( global,err_mpi_trouble,__line__ )

      ENDIF
#endif

    ENDIF ! MASTERPROC

! - copy temporary array into randData

    IF (regions(ireg)%procid == global%myProcid) THEN
      DO i=0,rand_total_size-1
        regions(ireg)%randData%mt(i) = randstate(i+randstate_offset,1)
      ENDDO ! i
    ENDIF ! global%myProcid

  ENDDO ! iReg

! finalize --------------------------------------------------------------------

  IF (global%myProcid == masterproc) THEN
    CLOSE(if_rand_state,iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname) )
  ENDIF

999  CONTINUE
  CALL deregisterfunction( global )

1000 FORMAT('Time in file is= ',es12.5,' but it should be= ',es12.5,'.')

END SUBROUTINE rflo_readrandomstate

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ReadRandomState.F90,v $
! Revision 1.3  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:21  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.1  2003/11/21 22:28:42  fnajjar
! Added Read capability for Random Number Generator
!
!******************************************************************************