RFLO_ReadBcInjectAPNSection.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: read in user input related to APN injection boundary condition.
!
! Description: none.
!
! Input: boundary condition file.
!
! Output: regions = BC data.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_ReadBcInjectAPNSection.F90,v 1.5 2008/12/06 08:44:07 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_readbcinjectapnsection( regions )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : readpatchsection, rflo_readbcfromfile
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, ipatch

! ... local variables
  CHARACTER(10)  :: keys(6)
  CHARACTER(256) :: fname

  INTEGER :: brbeg, brend, prbeg, prend, distrib
  INTEGER :: n1, n2, ioff, ijbeg, ijend, errorflag

  LOGICAL :: defined(6)

  REAL(RFREAL) :: vals(6)

  TYPE(t_patch), POINTER  :: patch
  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_ReadBcInjectAPNSection',&
  'RFLO_ReadBcInjectAPNSection.F90' )

! specify keywords and search for them ----------------------------------------

  keys(1) = 'SDENS'
  keys(2) = 'ACOEFF'
  keys(3) = 'NPOWER'
  keys(4) = 'TEMP'
  keys(5) = 'EXTRAPOL'
  keys(6) = 'MAXCHANGE'

  CALL readpatchsection( global,if_input,6,keys,vals,brbeg,brend, &
                         prbeg,prend,distrib,fname,defined )
  
! check if all values defined -------------------------------------------------

  IF (distrib==bcdat_constant .AND. &
      (.NOT. (defined(1).eqv..true.) .OR. &
       .NOT. (defined(2).eqv..true.) .OR. &
       .NOT. (defined(3).eqv..true.) .OR. &
       .NOT. (defined(4).eqv..true.))) CALL errorstop( global,err_bcval_missing,&
       __line__ )

  IF (.NOT. (defined(5).eqv..true.) .OR. &
      .NOT. (defined(6).eqv..true.))   CALL errorstop( global,err_bcval_missing,&
      __line__ )

! copy values/distribution to variables ---------------------------------------

  DO ireg=brbeg,brend
    DO ipatch=prbeg,min(prend,regions(ireg)%nPatches)

      patch => regions(ireg)%levels(1)%patches(ipatch)

      IF ((patch%bcType>=bc_injection .AND. &
           patch%bcType<=bc_injection+bc_range) .AND. &   ! my boundary type
          regions(ireg)%procid==global%myProcid .AND. &   ! region active and
          regions(ireg)%active==active) THEN              ! on my processor

        patch%bcType = bc_injection_apn

        IF (patch%mixt%bcSet.eqv..true.) &
          CALL errorstop( global,err_patch_overspec,&
          __line__,'Injection boundary.' )

        patch%mixt%nData     = 8
        patch%mixt%nSwitches = 1
        patch%mixt%bcSet     = .true.
        IF (patch%bcCoupled == bc_external) THEN   ! data from outside
          patch%mixt%distrib = bcdat_distrib    ! => always distribution
        ELSE
          patch%mixt%distrib = distrib
        ENDIF

! ----- get value of switch

        ALLOCATE( patch%mixt%switches(patch%mixt%nSwitches), &
                  stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global,err_allocate,&
        __line__ )

          patch%mixt%switches(bcswi_inject_extrap) = extrapol_const
        IF (vals(5) > 0.1) &
          patch%mixt%switches(bcswi_inject_extrap) = extrapol_linear

        patch%mixt%maxChange = vals(6)

! ----- allocate memory for the values

        n1    = abs(patch%l1end-patch%l1beg)
        n2    = abs(patch%l2end-patch%l2beg)
        ioff  = n1 + 1
        ijbeg = indij( 0, 0,ioff)
        ijend = indij(n1,n2,ioff)

        ALLOCATE( patch%mixt%vals(patch%mixt%nData,ijbeg:ijend), &
                  stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global,err_allocate,&
        __line__ )

! ----- distribution from file

        IF (patch%mixt%distrib==bcdat_distrib .AND. &
            patch%bcCoupled      /=bc_external  ) THEN
          patch%mixt%nData = 4
          CALL rflo_readbcfromfile( global,fname,patch )
          patch%mixt%nData = 8

! ----- distribution from external source / constant value

        ELSE
          patch%mixt%vals(bcdat_inject_sdens ,:) = abs( vals(1) )
          patch%mixt%vals(bcdat_inject_acoeff,:) = abs( vals(2) )
          patch%mixt%vals(bcdat_inject_npower,:) = abs( vals(3) )
          patch%mixt%vals(bcdat_inject_temp  ,:) = abs( vals(4) )
        ENDIF  ! distribution?

! ----- patch%mixt%distrib for APN always non-constant for later use

        patch%mixt%distrib = bcdat_distrib

      ENDIF    ! bcType, active region on my processor

    ENDDO      ! iPatch
  ENDDO        ! iReg

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rflo_readbcinjectapnsection

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ReadBcInjectAPNSection.F90,v $
! Revision 1.5  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2008/10/23 18:20:53  mtcampbe
! Crazy number of changes to track and fix initialization and
! restart bugs.  Many improperly formed logical expressions
! were fixed, and bug in allocation for data associated with
! the BC_INFLOWVELTEMP boundary condition squashed in
! RFLO_ReadBcInflowVelSection.F90.
!
! Revision 1.2  2006/08/19 15:38:14  mparmar
! Renamed patch variables
!
! Revision 1.1  2006/01/20 06:17:54  wasistho
! initial import
!
!
!******************************************************************************