RFLO_ReadBcInflowTotAngSection.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: read in user input related to inflow boundary condition.
!
! Description: present inflow bc is based on total pressure, total temperature
!              and flow angle.
!
! Input: boundary condition file.
!
! Output: regions = BC data.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_ReadBcInflowTotAngSection.F90,v 1.5 2008/12/06 08:44:07 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_readbcinflowtotangsection( regions )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : readpatchsection, rflo_readbcfromfile
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, ipatch

! ... local variables
  CHARACTER(10)  :: keys(7)
  CHARACTER(256) :: fname

  INTEGER :: brbeg, brend, prbeg, prend, distrib, switch
  INTEGER :: n1, n2, ioff, ijbeg, ijend, errorflag

  LOGICAL :: defined(7)

  REAL(RFREAL) :: vals(7)

  TYPE(t_patch), POINTER  :: patch
  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_ReadBcInflowTotAngSection',&
  'RFLO_ReadBcInflowTotAngSection.F90' )

! specify keywords and search for them ----------------------------------------

  keys(1) = 'TYPE'
  keys(2) = 'FIXED'
  keys(3) = 'PTOT'
  keys(4) = 'TTOT'
  keys(5) = 'BETAH'
  keys(6) = 'BETAV'
  keys(7) = 'MACH'

  CALL readpatchsection( global,if_input,7,keys,vals,brbeg,brend, &
                         prbeg,prend,distrib,fname,defined )

! get switches & check if all necessary values defined ------------------------

  DO ireg=brbeg,brend
    DO ipatch=prbeg,min(prend,regions(ireg)%nPatches)

      patch => regions(ireg)%levels(1)%patches(ipatch)

      IF ((patch%bcType>=bc_inflow .AND. &
           patch%bcType<=bc_inflow+bc_range)    .AND. &   ! my boundary type,
          regions(ireg)%procid==global%myProcid .AND. &   ! region active and
          regions(ireg)%active==active) THEN              ! on my processor

        patch%bcType = bc_inflow_totang

        IF (patch%mixt%bcSet.eqv..true.) &
          CALL errorstop( global,err_patch_overspec,&
          __line__,'Inflow boundary.' )

        patch%mixt%nSwitches = 2
        IF (patch%bcCoupled == bc_external) THEN   ! data from outside
          patch%mixt%distrib = bcdat_distrib    ! => always distribution
        ELSE
          patch%mixt%distrib = distrib
        ENDIF

        ALLOCATE( patch%mixt%switches(patch%mixt%nSwitches), &
                  stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global,err_allocate,&
        __line__ )

! ----- check if switch defined
        IF (defined(1).eqv..true.) THEN
          patch%mixt%switches(bcswi_inflow_type)   = bcopt_subsonic
          IF (vals(1) < 0.1) &
            patch%mixt%switches(bcswi_inflow_type) = bcopt_supersonic
          IF (vals(1) > 1.9) &
            patch%mixt%switches(bcswi_inflow_type) = bcopt_mixed
        ELSE
          CALL errorstop( global,err_no_bcswitch,&
          __line__,'(inflow type).' )
        ENDIF

        IF (defined(2).eqv..true.) THEN
          IF (vals(2) < 0.1) &
            patch%mixt%switches(bcswi_inflow_fixed) = bcopt_fixed_no
          IF (vals(2) > 0.9) &
            patch%mixt%switches(bcswi_inflow_fixed) = bcopt_fixed_yes
        ELSE
          patch%mixt%switches(bcswi_inflow_fixed) = bcopt_fixed_no
        ENDIF

! ----- check if appropriate values specified
        IF (patch%mixt%switches(bcswi_inflow_type) == bcopt_subsonic) THEN
          IF (patch%mixt%distrib==bcdat_constant .AND. &
              (.NOT. (defined(3).eqv..true.) .OR. &
               .NOT. (defined(4).eqv..true.) .OR. &
               .NOT. (defined(5).eqv..true.) .OR. &
               .NOT. (defined(6).eqv..true.))) CALL errorstop( global,err_bcval_missing,&
               __line__ )
        ENDIF
        IF (patch%mixt%switches(bcswi_inflow_type) == bcopt_supersonic .OR. &
            patch%mixt%switches(bcswi_inflow_type) == bcopt_mixed) THEN
          IF (patch%mixt%distrib==bcdat_constant .AND. &
              (.NOT. (defined(3).eqv..true.) .OR. &
               .NOT. (defined(4).eqv..true.) .OR. &
               .NOT. (defined(5).eqv..true.) .OR. &
               .NOT. (defined(6).eqv..true.) .OR. &
               .NOT. (defined(7).eqv..true.))) CALL errorstop( global,err_bcval_missing,&
               __line__ )
        ENDIF

! ----- set flag to BC specified
        patch%mixt%bcSet = .true.

      ENDIF   ! my BC & processor, active
    ENDDO
  ENDDO

! copy values/distribution to variables ---------------------------------------

  DO ireg=brbeg,brend
    DO ipatch=prbeg,min(prend,regions(ireg)%nPatches)

      patch => regions(ireg)%levels(1)%patches(ipatch)

      IF ((patch%bcType>=bc_inflow .AND. &
           patch%bcType<=bc_inflow+bc_range)    .AND. &   ! my boundary type,
          regions(ireg)%procid==global%myProcid .AND. &   ! region active and
          regions(ireg)%active==active) THEN              ! on my processor

        switch = patch%mixt%switches(bcswi_inflow_type)
        IF (switch == bcopt_subsonic) THEN
          patch%mixt%nData = 4
        ELSE
          patch%mixt%nData = 5
        ENDIF

! ----- allocate memory for the values

        IF (patch%mixt%distrib == bcdat_distrib) THEN
          n1    = abs(patch%l1end-patch%l1beg)
          n2    = abs(patch%l2end-patch%l2beg)
          ioff  = n1 + 1
          ijbeg = indij( 0, 0,ioff)
          ijend = indij(n1,n2,ioff)
        ELSE
          ijbeg = 0
          ijend = 1
        ENDIF
        ALLOCATE( patch%mixt%vals(patch%mixt%nData,ijbeg:ijend), &
                  stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global,err_allocate,&
        __line__ )

! ----- distribution from file

        IF (patch%mixt%distrib==bcdat_distrib .AND. &
            patch%bcCoupled      /=bc_external  ) THEN
          CALL rflo_readbcfromfile( global,fname,patch )

          IF (switch == bcopt_subsonic) THEN
            patch%mixt%vals(bcdat_inflow_betah,:) = &
              patch%mixt%vals(bcdat_inflow_betah,:)*global%rad
            patch%mixt%vals(bcdat_inflow_betav,:) = &
              patch%mixt%vals(bcdat_inflow_betav,:)*global%rad
          ENDIF

! ----- distribution from external source / constant value

        ELSE
          patch%mixt%vals(bcdat_inflow_ptot ,:) = vals(3)
          patch%mixt%vals(bcdat_inflow_ttot ,:) = vals(4)
          patch%mixt%vals(bcdat_inflow_betah,:) = vals(5)*global%rad
          patch%mixt%vals(bcdat_inflow_betav,:) = vals(6)*global%rad
          IF (switch /= bcopt_subsonic) THEN
            patch%mixt%vals(bcdat_inflow_mach,:) = vals(7)
          ENDIF
        ENDIF  ! distribution?

      ENDIF    ! bcType, active region on my processor

    ENDDO      ! iPatch
  ENDDO        ! iReg

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rflo_readbcinflowtotangsection

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ReadBcInflowTotAngSection.F90,v $
! Revision 1.5  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2008/10/23 18:20:53  mtcampbe
! Crazy number of changes to track and fix initialization and
! restart bugs.  Many improperly formed logical expressions
! were fixed, and bug in allocation for data associated with
! the BC_INFLOWVELTEMP boundary condition squashed in
! RFLO_ReadBcInflowVelSection.F90.
!
! Revision 1.2  2006/08/19 15:38:10  mparmar
! Renamed patch variables
!
! Revision 1.1  2005/04/28 05:48:28  wasistho
! added velocity based inflow BC
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.7  2004/01/29 22:55:30  haselbac
! Read new argument
!
! Revision 1.6  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.3  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.2  2003/02/11 22:30:21  jferry
! Re-worked BC and TBC input routines to add multi-physics capability
!
! Revision 1.1  2002/10/19 00:40:30  jblazek
! Added utility (rflosurf) to write out surface grids for GenX.
!
! Revision 1.13  2002/10/12 03:20:50  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.12  2002/09/27 00:57:10  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.11  2002/09/20 22:22:36  jblazek
! Finalized integration into GenX.
!
! Revision 1.10  2002/09/17 13:43:00  jferry
! Added Time-dependent boundary conditions
!
! Revision 1.9  2002/09/05 17:40:22  jblazek
! Variable global moved into regions().
!
! Revision 1.8  2002/06/22 01:13:38  jblazek
! Modified interfaces to BC routines.
!
! Revision 1.7  2002/03/29 23:15:22  jblazek
! Corrected bug in MPI send.
!
! Revision 1.6  2002/02/21 23:25:06  jblazek
! Blocks renamed as regions.
!
! Revision 1.5  2002/02/09 01:47:01  jblazek
! Added multi-probe option, residual smoothing, physical time step.
!
! Revision 1.4  2002/01/31 20:56:30  jblazek
! Added basic boundary conditions.
!
! Revision 1.3  2002/01/11 17:20:19  jblazek
! Added time stamp or iteration number to file names.
!
! Revision 1.2  2001/12/22 00:09:39  jblazek
! Added routines to store grid and solution.
!
! Revision 1.1  2001/12/08 00:18:42  jblazek
! Added routines to read BC input file.
!
!******************************************************************************