RFLO_ModRestartInfo.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Suite for restart info routines
!
! Description: None.
!
! ******************************************************************************
!
! $Id: RFLO_ModRestartInfo.F90,v 1.5 2008/12/06 08:44:17 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
! ******************************************************************************

MODULE rflo_modrestartinfo

  USE modglobal, ONLY    : t_global 
  USE moddatastruct, ONLY: t_region  
  USE modgrid, ONLY      : t_grid
  USE modbndpatch, ONLY  : t_patch
  USE modparameters
  USE moddatatypes
  USE moderror
  USE modmpi
  
  IMPLICIT NONE

  PRIVATE
  PUBLIC :: rflo_readrestartinfo, &
            rflo_writerestartinfo

! private : RFLO_OpenRestartInfo
!           RFLO_CloseRestartInfo
    
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  
   
  CHARACTER(CHRLEN) :: RCSIdentString = & 
    '$RCSfile: RFLO_ModRestartInfo.F90,v $ $Revision: 1.5 $'
             
! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS

! ******************************************************************************
!
! Purpose: Open restart file.
!
! Description: None.
!
! Input: 
!   global              Pointer to global data
!   filePosition        Position at which file to be opened (start or end)
!
! Output: 
!   fileExists          Logical indicating whether file exists
!
! Notes: 
!   1. The filePosition parameter is needed because the restart info file
!      is opened with two goals. The first is to open it with the goal of
!      getting the last output iteration or time (ReadRestartInfo). 
!      The second is to be able to write to it by appending additional 
!      lines (WriteRestartInfo).
!   2. The fileExists parameter is needed because if the file exists
!      on restarting the code, it will need to be read to determine the 
!      last output iteration or time.
!
! ******************************************************************************

SUBROUTINE rflo_openrestartinfo(global,filePosition,fileExists)
  
  USE modbuildfilenames, ONLY: buildfilenameplain

! *****************************************************************************
! Declarations and definitions
! *****************************************************************************

! =============================================================================
! Arguments
! =============================================================================

  INTEGER, INTENT(IN) :: fileposition
  TYPE(t_global), POINTER :: global

  LOGICAL, INTENT(OUT) :: fileexists

! =============================================================================
! Locals
! =============================================================================

  CHARACTER(CHRLEN) :: ifilename
  INTEGER :: errorflag

! *****************************************************************************
! Start
! *****************************************************************************

  CALL registerfunction(global,'RFLO_OpenRestartInfo',&
       'RFLO_ModRestartInfo.F90')

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, &
                             'Opening restart info file...'
  END IF ! global%verbLevel

! =============================================================================
! Open file
! =============================================================================

  CALL buildfilenameplain(global,filedest_outdir,'.rin',ifilename)

  INQUIRE(file=ifilename,exist=fileexists)
    
  IF ( fileexists .EQV. .true. ) THEN
    IF ( fileposition == file_position_start ) THEN 
      OPEN(if_restinfo,file=ifilename,form='FORMATTED',status='OLD', &
           iostat=errorflag) 
    ELSE IF ( fileposition == file_position_end ) THEN 
      OPEN(if_restinfo,file=ifilename,form='FORMATTED',status='OLD', &
           position='APPEND',iostat=errorflag)     
    ELSE 
      CALL errorstop(global,err_reached_default,&
           __line__)
    END IF ! filePosition
  ELSE
    OPEN(if_restinfo,file=ifilename,form='FORMATTED',status='NEW', &
         iostat=errorflag)    
  END IF ! file

  global%error = errorflag
  IF ( global%error /= 0 ) THEN 
    CALL errorstop(global,err_file_open,&
         __line__,'File: '//trim(ifilename))
  END IF ! global%error

! *****************************************************************************
! End
! *****************************************************************************

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, & 
                             'Opening restart info file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflo_openrestartinfo


! ******************************************************************************
!
! Purpose: Close restart info file.
!
! Description: None.
!
! Input: 
!   global              Pointer to global data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflo_closerestartinfo(global)

  USE modbuildfilenames, ONLY: buildfilenameplain  

! *****************************************************************************
! Declarations and definitions
! *****************************************************************************

! =============================================================================
! Arguments
! =============================================================================

  TYPE(t_global), POINTER :: global

! =============================================================================
! Locals
! =============================================================================

  CHARACTER(CHRLEN) :: ifilename
  INTEGER :: errorflag
  
! *****************************************************************************
! Start
! *****************************************************************************

  CALL registerfunction(global,'RFLO_CloseRestartInfo',&
       'RFLO_ModRestartInfo.F90')

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Closing restart info file...'
  END IF ! global%verbLevel

! =============================================================================
! Close file
! =============================================================================

  CALL buildfilenameplain(global,filedest_outdir,'.rin',ifilename)

  CLOSE(if_restinfo,iostat=errorflag)                        
  global%error = errorflag
  IF ( global%error /= 0 ) THEN 
    CALL errorstop(global,err_file_close,&
         __line__,'File: '//trim(ifilename))
  END IF ! global%error

! *****************************************************************************
! End
! *****************************************************************************

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Closing restart info file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflo_closerestartinfo


! ******************************************************************************
!
! Purpose: Read restart info file to get last output iteration or time.
!
! Description: None.
!
! Input: 
!   global              Pointer to global data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflo_readrestartinfo(global)

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_global), POINTER :: global

! ==============================================================================
! Locals
! ==============================================================================

  LOGICAL :: fileexists
  INTEGER :: dummyinteger,errorflag
  REAL(RFREAL) :: dummyrfreal

! ******************************************************************************
! Start
! ******************************************************************************

  CALL registerfunction(global,'RFLO_ReadRestartInfo',&
       'RFLO_ModRestartInfo.F90')

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, &
                             'Reading restart info file...'
  END IF ! global%verbLevel

! ==============================================================================
! Open file
! ==============================================================================

  CALL rflo_openrestartinfo(global,file_position_start,fileexists)

! ==============================================================================
! Set or read restart iteration or time
! ==============================================================================

  IF ( global%flowType == flow_steady ) THEN ! steady flow
    global%currentIter = 0

    IF ( fileexists .EQV. .true. ) THEN
      DO 
        READ(if_restinfo,*,iostat=errorflag) dummyinteger
        
        IF ( errorflag /= err_none ) THEN 
          EXIT
        ELSE 
          global%currentIter = dummyinteger
        END IF ! errorFlag
      END DO ! <empty>
    END IF ! fileExists
  ELSE ! unsteady flow
    global%currentTime = 0.0_rfreal
  
    IF ( fileexists .EQV. .true. ) THEN
      DO 
        READ(if_restinfo,*,iostat=errorflag) dummyrfreal
        
        IF ( errorflag /= err_none ) THEN 
          EXIT
        ELSE 
          global%currentTime = dummyrfreal
          global%timeStamp   = global%currentTime
        END IF ! errorFlag
      END DO ! <empty>
    END IF ! fileExists
  END IF ! global%flowType

! ==============================================================================
! Write info
! ==============================================================================

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_low ) THEN
    IF ( global%flowType == flow_steady ) THEN 
      WRITE(stdout,'(A,3X,A,1X,I6.6)') solver_name, & 
                                       'Restart iteration:',global%currentIter
    ELSE 
      WRITE(stdout,'(A,3X,A,1X,1PE11.5)') solver_name, & 
                                          'Restart time:',global%currentTime      
    END IF ! global%flowType
  END IF ! global%myProcid

! ==============================================================================
! Close file
! ==============================================================================

  CALL rflo_closerestartinfo(global)        

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, & 
                             'Reading restart info file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflo_readrestartinfo


!******************************************************************************
!
! Purpose: Write iteration or time to restart info file.
!
! Description: None.
!
! Input: 
!   global              Pointer to global data
!
! Output: None.
!
! Notes: 
!   1. Only master process writes to file. 
!   2. Every time write to file, open and close it to make sure always have
!      latest data in file.
!
!******************************************************************************

SUBROUTINE rflo_writerestartinfo(global)

! *****************************************************************************
! Declarations and definitions
! *****************************************************************************

! =============================================================================
! Arguments
! =============================================================================

  TYPE(t_global), POINTER :: global

! =============================================================================
! Locals
! =============================================================================

  LOGICAL :: dummylogical

! *****************************************************************************
! Start
! *****************************************************************************

  CALL registerfunction(global,'RFLO_WriteRestartInfo',&
       'RFLO_ModRestartInfo.F90')

! =============================================================================
! Write restart info to file
! =============================================================================

  IF ( global%myProcid == masterproc ) THEN 
    CALL rflo_openrestartinfo(global,file_position_end,dummylogical)

    IF ( global%flowType == flow_steady ) THEN 
      WRITE(if_restinfo,*) global%currentIter
    ELSE 
      WRITE(if_restinfo,*) global%currentTime
    END IF ! global%flowType

    CALL rflo_closerestartinfo(global)
  END IF ! global%myProcid

! *****************************************************************************
! End
! *****************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflo_writerestartinfo


! ******************************************************************************
! End
! ******************************************************************************

END MODULE rflo_modrestartinfo

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ModRestartInfo.F90,v $
! Revision 1.5  2008/12/06 08:44:17  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:28  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/04/07 15:19:17  haselbac
! Removed tabs
!
! Revision 1.2  2006/02/04 03:59:11  wasistho
! global%timeStamp copied from currentTime in ReadRestartInfo
!
! Revision 1.1  2006/02/01 20:03:51  wasistho
! initial import
!
!
!
! ******************************************************************************