RFLO_FindSourcePatches.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: find source patches for inter-region communication.
!
! Description: none.
!
! Input: regions = dimensions and topology of all regions.
!
! Output: regions%levels(1)%patches = source patches.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_FindSourcePatches.F90,v 1.3 2008/12/06 08:44:27 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_findsourcepatches( regions )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modparameters
  USE moderror
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, ipatch, ipatchsrc

! ... local variables
  CHARACTER(CHRLEN) :: msg

  INTEGER :: bctype, iregsrc, lbs, l1bs, l1es, l2bs, l2es

  TYPE(t_patch), POINTER  :: patch, patchsrc
  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_FindSourcePatches',&
  'RFLO_FindSourcePatches.F90' )

! loop over regions and patches

  DO ireg=1,global%nRegions
    DO ipatch=1,regions(ireg)%nPatches

      patch  => regions(ireg)%levels(1)%patches(ipatch)
      bctype = patch%bcType

      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_regionint  .AND. bctype<=bc_regionint +bc_range) .OR. &
          (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
        iregsrc = patch%srcRegion
        lbs     = patch%srcLbound
        l1bs    = min(patch%srcL1beg,patch%srcL1end)
        l1es    = max(patch%srcL1beg,patch%srcL1end)
        l2bs    = min(patch%srcL2beg,patch%srcL2end)
        l2es    = max(patch%srcL2beg,patch%srcL2end)

! ----- search for corresponding source patch on source region

        patch%srcPatch = -999

        DO ipatchsrc=1,regions(iregsrc)%nPatches
          IF (iregsrc/=ireg .OR. ipatchsrc/=ipatch) THEN
            patchsrc => regions(iregsrc)%levels(1)%patches(ipatchsrc)
            IF (patchsrc%bcType==bctype .AND. &
                patchsrc%lbound==lbs    .AND. &
                patchsrc%l1beg ==l1bs   .AND. &
                patchsrc%l1end ==l1es   .AND. &
                patchsrc%l2beg ==l2bs   .AND. &
                patchsrc%l2end ==l2es) THEN       ! OK, patch found
              patch%srcPatch = ipatchsrc
            ENDIF
          ENDIF
        ENDDO    ! iPatchSrc

        IF (patch%srcPatch < 0) THEN
          WRITE(msg,1000) ireg,ipatch,bctype
          CALL errorstop( global,err_patch_nosource,__line__,msg )
        ENDIF
      ENDIF   ! bcType

    ENDDO     ! iPatch
  ENDDO       ! iReg

! finalize

  CALL deregisterfunction( global )

1000 FORMAT('Region ',i5,', patch ',i3,', BC type ',i3)

END SUBROUTINE rflo_findsourcepatches

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_FindSourcePatches.F90,v $
! Revision 1.3  2008/12/06 08:44:27  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:38  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:39  wasistho
! lower to upper case
!
! Revision 1.9  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.8  2002/09/27 00:57:10  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.7  2002/09/05 17:40:21  jblazek
! Variable global moved into regions().
!
! Revision 1.6  2002/03/18 23:11:33  jblazek
! Finished multiblock and MPI.
!
! Revision 1.5  2002/02/21 23:25:06  jblazek
! Blocks renamed as regions.
!
! Revision 1.4  2002/01/11 17:20:19  jblazek
! Added time stamp or iteration number to file names.
!
! Revision 1.3  2001/12/22 00:09:39  jblazek
! Added routines to store grid and solution.
!
! Revision 1.2  2001/12/19 23:09:22  jblazek
! Added routines to read grid and solution.
!
! Revision 1.1.1.1  2001/12/03 21:44:04  jblazek
! Import of RocfluidMP
!
!******************************************************************************