RFLO_CopyTopologyLevels.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: copy topology and BC data to all coarse grids.
!
! Description: none.
!
! Input: regions = dimensions and topology on finest grid.
!
! Output: regions = dimensions and topology on all coarse grids.
!
! Notes: conducted only for currently active regions on the own processor.
!
!******************************************************************************
!
! $Id: RFLO_CopyTopologyLevels.F90,v 1.4 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_copytopologylevels( regions )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_copyboundarydata
  USE moderror
  USE modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, ilev, ipatch

! ... local variables
  INTEGER :: nlevels, npatches, ipc, jpc, kpc, bctype, errorflag

  TYPE(t_patch), POINTER  :: patch, patchprev
  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_CopyTopologyLevels',&
  'RFLO_CopyTopologyLevels.F90' )

! loop over all regions

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &   ! region active and
        regions(ireg)%active==active) THEN              ! on my processor

      nlevels  = regions(ireg)%nGridLevels
      npatches = regions(ireg)%nPatches

! --- loop over coarse grid levels

      DO ilev=2,nlevels
        ipc = regions(ireg)%levels(ilev-1)%grid%ipc     ! no. of physical cells
        jpc = regions(ireg)%levels(ilev-1)%grid%jpc
        kpc = regions(ireg)%levels(ilev-1)%grid%kpc
        regions(ireg)%levels(ilev)%grid%ipc = ipc/2
        regions(ireg)%levels(ilev)%grid%jpc = jpc/2
        regions(ireg)%levels(ilev)%grid%kpc = kpc/2

! ----- loop over patches

        ALLOCATE( regions(ireg)%levels(ilev)%patches(npatches),stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global,err_allocate,&
        __line__ )

        DO ipatch=1,npatches
          patchprev => regions(ireg)%levels(ilev-1)%patches(ipatch)
          patch     => regions(ireg)%levels(ilev  )%patches(ipatch)

! ------- current patch

          patch%bcType    = patchprev%bcType
          patch%bcCoupled = patchprev%bcCoupled
          patch%srcRegion = patchprev%srcRegion
          patch%srcPatch  = patchprev%srcPatch
          patch%align     = patchprev%align
          patch%lbound    = patchprev%lbound
          patch%l1beg     = (patchprev%l1beg-1)/2 + 1
          patch%l1end     = patchprev%l1end/2
          patch%l2beg     = (patchprev%l2beg-1)/2 + 1
          patch%l2end     = patchprev%l2end/2
          patch%srcLbound = patchprev%srcLbound

          patch%mixt%bcSet     = patchprev%mixt%bcSet
          patch%mixt%distrib   = patchprev%mixt%distrib
          patch%mixt%nData     = patchprev%mixt%nData
          patch%mixt%nSwitches = patchprev%mixt%nSwitches

! ------- source patch (if there is an adjacent region)

          bctype = patch%bcType

          IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR.&
              (bctype>=bc_regionint  .AND. bctype<=bc_regionint +bc_range) .OR.&
              (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range) .OR.&
              (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR.&
              (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
            IF (patch%srcL1beg < patch%srcL1end) THEN
              patch%srcL1beg = (patchprev%srcL1beg-1)/2 + 1
              patch%srcL1end = patchprev%srcL1end/2
            ELSE
              patch%srcL1beg = patchprev%srcL1beg/2
              patch%srcL1end = (patchprev%srcL1end-1)/2 + 1
            ENDIF
            IF (patch%srcL2beg < patch%srcL2end) THEN
              patch%srcL2beg = (patchprev%srcL2beg-1)/2 + 1
              patch%srcL2end = patchprev%srcL2end/2
            ELSE
              patch%srcL2beg = patchprev%srcL2beg/2
              patch%srcL2end = (patchprev%srcL2end-1)/2 + 1
            ENDIF
          ELSE                                     ! no adjacent region
            patch%srcL1beg = patchprev%srcL1beg
            patch%srcL1end = patchprev%srcL1end
            patch%srcL2beg = patchprev%srcL2beg
            patch%srcL2end = patchprev%srcL2end
          ENDIF  ! bcType

! ------- distributions of boundary values

          IF ((bctype>=bc_slipwall   .AND. bctype<=bc_slipwall  +bc_range) .OR.&
              (bctype>=bc_noslipwall .AND. bctype<=bc_noslipwall+bc_range) .OR.&
              (bctype>=bc_inflow     .AND. bctype<=bc_inflow    +bc_range) .OR.&
              (bctype>=bc_outflow    .AND. bctype<=bc_outflow   +bc_range) .OR.&
              (bctype>=bc_farfield   .AND. bctype<=bc_farfield  +bc_range) .OR.&
              (bctype>=bc_injection  .AND. bctype<=bc_injection +bc_range)) THEN
            CALL rflo_copyboundarydata( global,patchprev,patch )
          ENDIF  ! bcType

        ENDDO    ! iPatch

      ENDDO      ! iLev

    ENDIF        ! active region on my processor
  ENDDO          ! iReg

! finalize

  CALL deregisterfunction( global )

END SUBROUTINE rflo_copytopologylevels

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_CopyTopologyLevels.F90,v $
! Revision 1.4  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/08/19 15:38:00  mparmar
! Renamed patch variables
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.6  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.3  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.2  2002/10/25 18:36:19  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.1  2002/10/19 00:40:30  jblazek
! Added utility (rflosurf) to write out surface grids for GenX.
!
! Revision 1.6  2002/09/27 00:57:10  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.5  2002/09/05 17:40:21  jblazek
! Variable global moved into regions().
!
! Revision 1.4  2002/03/18 23:11:33  jblazek
! Finished multiblock and MPI.
!
! Revision 1.3  2002/02/27 18:38:20  jblazek
! Changed extrapol. to dummy cells at injection boundaries and slip walls.
!
! Revision 1.2  2002/02/21 23:25:06  jblazek
! Blocks renamed as regions.
!
! Revision 1.1  2002/01/23 03:51:25  jblazek
! Added low-level time-stepping routines.
!
! Revision 1.5  2002/01/11 17:20:19  jblazek
! Added time stamp or iteration number to file names.
!
! Revision 1.4  2001/12/22 00:09:39  jblazek
! Added routines to store grid and solution.
!
! Revision 1.3  2001/12/19 23:09:22  jblazek
! Added routines to read grid and solution.
!
! Revision 1.2  2001/12/08 00:18:42  jblazek
! Added routines to read BC input file.
!
! Revision 1.1.1.1  2001/12/03 21:44:04  jblazek
! Import of RocfluidMP
!
!******************************************************************************