RFLO_CheckBcInput.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: check BC data specified by the user for all modules.
!
! Description: none.
!
! Input: regions = input parameters for all grid regions.
!
! Output: none.
!
! Notes: also allocates TBC arrays.
!
!******************************************************************************
!
! $Id: RFLO_CheckBcInput.F90,v 1.6 2008/12/06 08:44:26 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_checkbcinput( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modmixture,    ONLY : t_mixt_input
  USE modbndpatch,   ONLY : t_patch, t_bcvalues
  USE moderror
  USE modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, ipatch, ilev, ftype

! ... local variables
  CHARACTER(CHRLEN) :: msg

  INTEGER :: errorflag

  TYPE(t_global),     POINTER :: global
  TYPE(t_mixt_input), POINTER :: input
  TYPE(t_patch),      POINTER :: patch
  TYPE(t_bcvalues),   POINTER :: bc

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_CheckBcInput',&
  'RFLO_CheckBcInput.F90' )

! check if all BCs set (for all active modules), and allocate TBCs

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &   ! region active and
        regions(ireg)%active==active) THEN              ! on my processor
      input => regions(ireg)%mixtInput
      DO ilev=1,regions(ireg)%nGridLevels
        DO ipatch=1,regions(ireg)%nPatches
          patch => regions(ireg)%levels(ilev)%patches(ipatch)
          DO ftype = 1,ftype_max

            SELECT CASE(ftype)
            CASE (ftype_mixt)
              bc => patch%mixt
            CASE (ftype_turb)
              IF (input%turbModel == turb_model_none) cycle
              bc => patch%turb
            CASE (ftype_plag)
              cycle
            CASE (ftype_peul)
              IF (global%peulUsed .eqv. .false.) cycle
              bc => patch%peul
            CASE (ftype_spec)
              IF (input%gasModel == gas_model_tcperf) cycle
              bc => patch%spec
            CASE (ftype_radi)
              IF (input%radiUsed .eqv. .false.) cycle
              bc => patch%valRadi
            END SELECT

            IF (bc%bcSet .eqv. .false.) THEN
              WRITE(msg,1000) ireg,ilev,ipatch,patch%bcType,ftype
              CALL errorstop( global,err_no_bcspecified,__line__,trim(msg) )
            ENDIF

            IF (bc%nData > 0) THEN
              ALLOCATE( bc%tbcs(bc%nData),stat=errorflag )
              global%error = errorflag
              IF (global%error /= 0) &
                CALL errorstop( global,err_allocate,__line__ )
              bc%tbcs(:)%tbcType = tbc_none
            ENDIF

          ENDDO ! fType
        ENDDO ! iPatch
      ENDDO ! iLev
    ENDIF ! region active and on my processor
  ENDDO ! iReg

! finalize

  CALL deregisterfunction( global )

1000 FORMAT('Region ',i5,', level ',i1,', patch ',i3,', bcType ',i3, &
            ', fType ',i3)

END SUBROUTINE rflo_checkbcinput

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_CheckBcInput.F90,v $
! Revision 1.6  2008/12/06 08:44:26  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2008/08/13 17:25:33  mtcampbe
! Fixed IF statements for booleans to use .eqv. .false. instead of .NOT.
! (beats me)
!
! Revision 1.3  2006/08/19 15:39:30  mparmar
! Renamed patch variables
!
! Revision 1.2  2005/10/31 21:09:36  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.1  2004/11/29 20:51:38  wasistho
! lower to upper case
!
! Revision 1.4  2004/03/05 22:09:02  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.3  2003/05/15 02:57:03  jblazek
! Inlined index function.
!
! Revision 1.2  2003/02/26 23:19:48  jferry
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.1  2003/02/11 22:49:53  jferry
! Re-worked BC and TBC input routines to add multi-physics capability
!
! Revision 1.1  2003/02/11 22:30:20  jferry
! Re-worked BC and TBC input routines to add multi-physics capability
!
!******************************************************************************