RADI_rFLO_FlimClearSendRequests.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: wait until FLD radiation data is received by other processors 
!          communicating with the current region
!
! Description: none.
!
! Input: regions  = all regions
!        iReg     = current region
!
! Output: none.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RADI_rFLO_FlimClearSendRequests.F90,v 1.3 2008/12/06 08:44:38 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE radi_rflo_flimclearsendrequests( regions,iReg ) ! PUBLIC

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE moderror
  USE modmpi
  USE modparameters
  USE radi_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

  INTEGER, INTENT(IN)     :: ireg

! ... loop variables
  INTEGER :: ipatch, ir

! ... local variables
  INTEGER :: ilev, npatches, bctype, iregsrc, irequest
#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif

  LOGICAL dowait

  TYPE(t_patch),  POINTER :: patch
  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RADI_RFLO_FlimClearSendRequests',&
  'RADI_rFLO_FlimClearSendRequests.F90' )

  IF (regions(ireg)%radiInput%radiModel /= radi_model_fldtran) goto 999

#ifdef MPI
! get dimensions --------------------------------------------------------------

  ilev     = regions(ireg)%currLevel
  npatches = regions(ireg)%nPatches
  
! wait for patch data being received by other processors ----------------------

  DO ipatch=1,npatches

    patch => regions(ireg)%levels(ilev)%patches(ipatch)

    bctype   = patch%bcType
    iregsrc  = patch%srcRegion
    irequest = patch%valRadi%iRequest
    
! - region interface, periodic boundary

    dowait = ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
              (bctype>=bc_regionint  .AND. bctype<=bc_regionint +bc_range) .OR. &
              (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range) .OR. &
              (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
              (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range))

    IF (iregsrc > 0) THEN
      IF (dowait .AND. (regions(iregsrc)%procid /= global%myProcid)) THEN
        CALL mpi_wait( global%requests(irequest), status, global%mpierr )
        IF (global%mpierr /= err_none) &
          CALL errorstop( global,err_mpi_trouble,__line__ )
      ENDIF
    ENDIF

  ENDDO   ! iPatch

! wait for edges & corners being received by other processors -----------------

  IF (global%nProcAlloc>1) THEN
    DO ir=1,global%nRegions
      IF (regions(ireg)%levels(ilev)%sndRadiEcCells(ir)%nCells > 0) THEN
        irequest = regions(ireg)%levels(ilev)%sndRadiEcCells(ir)%iRequest
        CALL mpi_wait( global%requests(irequest),status,global%mpierr )
        IF (global%mpierr /= 0) CALL errorstop( global,err_mpi_trouble,__line__ )
      ENDIF
    ENDDO
  ENDIF
#endif

! finalize --------------------------------------------------------------------

999  CONTINUE

  CALL deregisterfunction( global )

END SUBROUTINE radi_rflo_flimclearsendrequests

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RADI_rFLO_FlimClearSendRequests.F90,v $
! Revision 1.3  2008/12/06 08:44:38  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:50  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/09/30 17:49:10  wasistho
! prepared for full FLD radiation model
!
!
!
!******************************************************************************