PerfgasTransportVars.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute transport variables for a thermally and calorically
!          perfect gas using various mdoels.
!
! Description: none.
!
! Input: inBeg    = first value to update
!        inEnd    = last value to update
!        indCp    = indicates if cp varies over cells (=1) or is constant (=0)
!        indMol   = indicates if the mol mass varies over cells (=1) or is
!                     constant (=0)
!        viscModel= viscosity Model
!        prLam    = laminar Prandtl number
!        refVisc  = reference viscosity
!        refTemp  = reference temperature
!        suthCoef = reference SutherLand coefficient
!        cv       = conservative variables
!        dv       = dependent variables
!        gv       = gas variables (cp, Mol)
!
! Output: tv = transport variables (viscosity, heat conductivity)
!
! Notes: values are calculated for laminar flow only.
!
!******************************************************************************
!
! $Id: PerfgasTransportVars.F90,v 1.3 2008/12/06 08:44:09 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE perfgastransportvars( inBeg,inEnd,indCp,indMol,viscModel,prLam, &
                                 refvisc,reftemp,suthcoef,cv,dv,gv,tv )

  USE moddatatypes
  USE modparameters
  IMPLICIT NONE

! ... parameters
  INTEGER :: inbeg, inend, indcp, indmol, viscmodel

  REAL(RFREAL)          :: prlam, reftemp, refvisc, suthcoef
  REAL(RFREAL), POINTER :: cv(:,:), dv(:,:), gv(:,:), tv(:,:)

! ... loop variables
  INTEGER :: ic

! ... local variables
  REAL(RFREAL) :: abstemp, s1, s2, s12, s3, s4, prrl, rat

!******************************************************************************

  prrl = 1._rfreal/prlam

  SELECT CASE (viscmodel)

! - Sutherland formula --------------------------------------------------------

    CASE (visc_suthr)
      s1  = reftemp
      s2  = suthcoef
      s12 = 1._rfreal + s1/s2

      DO ic=inbeg,inend
        rat = sqrt(dv(dv_mixt_temp,ic)/s2) &
            * s12/(1._rfreal+s1/dv(dv_mixt_temp,ic))

        tv(tv_mixt_muel,ic) = refvisc*rat
        tv(tv_mixt_tcol,ic) = gv(gv_mixt_cp,ic*indcp)*tv(tv_mixt_muel,ic)*prrl
      ENDDO ! ic

! - constant viscosity --------------------------------------------------------

    CASE (visc_fixed)
      DO ic=inbeg,inend
        tv(tv_mixt_muel,ic) = refvisc
        tv(tv_mixt_tcol,ic) = gv(gv_mixt_cp,ic*indcp)*tv(tv_mixt_muel,ic)*prrl
      ENDDO ! ic     

! - Antibes formula -----------------------------------------------------------

    CASE (visc_antib) 
      s1 = 110.0_rfreal
      s2 = 120.0_rfreal
      s3 = 230.0_rfreal
      s4 = 1._rfreal/reftemp * sqrt(s2/reftemp) *(reftemp+s1)/s3
            
      IF ( reftemp <= s2 ) THEN
        DO ic=inbeg,inend
          abstemp = abs( dv(dv_mixt_temp,ic) )
        
          IF ( abstemp < s2 ) THEN
            rat = abstemp/reftemp
          ELSE
            rat = sqrt(abstemp/s2) *(abstemp/reftemp) *( s3/(abstemp+s1) )
          ENDIF ! absTemp
        
          tv(tv_mixt_muel,ic) = refvisc*rat
          tv(tv_mixt_tcol,ic) = gv(gv_mixt_cp,ic*indcp)*tv(tv_mixt_muel,ic)*prrl
        ENDDO ! ic
      
      ELSE 
        DO ic=inbeg,inend
          abstemp = abs( dv(dv_mixt_temp,ic) )
        
          IF ( abstemp < s2 ) THEN
            rat = s4
          ELSE
            rat = sqrt(abstemp/reftemp) *( abstemp/reftemp ) &
                * ( reftemp+s1 )/( abstemp+s1 )
          ENDIF ! absTemp
        
          tv(tv_mixt_muel,ic) = refvisc*rat
          tv(tv_mixt_tcol,ic) = gv(gv_mixt_cp,ic*indcp)*tv(tv_mixt_muel,ic)*prrl
        ENDDO ! ic      
      ENDIF ! refTemp 
      
  END SELECT ! viscModel
  
END SUBROUTINE perfgastransportvars

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PerfgasTransportVars.F90,v $
! Revision 1.3  2008/12/06 08:44:09  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:23  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 16:50:06  haselbac
! Initial revision after changing case
!
! Revision 1.6  2003/05/06 20:05:39  jblazek
! Corrected bug in grid motion (corner "averaging").
!
! Revision 1.5  2003/04/10 23:27:29  fnajjar
! Added 2 new viscosity models and aligned calling sequence
!
! Revision 1.4  2002/09/05 17:40:20  jblazek
! Variable global moved into regions().
!
! Revision 1.3  2002/02/09 01:47:01  jblazek
! Added multi-probe option, residual smoothing, physical time step.
!
! Revision 1.2  2002/01/23 03:51:24  jblazek
! Added low-level time-stepping routines.
!
! Revision 1.1  2002/01/10 00:02:06  jblazek
! Added calculation of mixture properties.
!
!******************************************************************************