PerfgasDependentVars.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute dependent variables for a thermally and calorically
!          perfect gas.
!
! Description: none.
!
! Input: inBeg  = first value to update
!        inEnd  = last value to update
!        indCp  = indicates if cp varies over cells (=1) or is constant (=0)
!        indMol = indicates if the mol mass varies over cells (=1) or is
!                 constant (=0)
!        cv     = conservative variables
!        gv     = gas variables (cp, Mol)
!
! Output: dv = dependent variables (p, T, c and u, v, w for RocfloMP)
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PerfgasDependentVars.F90,v 1.3 2008/12/06 08:44:09 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE perfgasdependentvars( inBeg,inEnd,indCp,indMol,cv,gv,dv )

  USE moddatatypes
  USE modparameters

#ifdef RFLU
  USE modinterfaces, ONLY: mixtperf_c_grt,mixtperf_g_cpr, & 
                           mixtperf_p_deogvm2,mixtperf_r_m,mixtperf_t_dpr
#endif

  IMPLICIT NONE

! ... parameters
  INTEGER :: inbeg, inend, indcp, indmol

  REAL(RFREAL), POINTER :: cv(:,:), gv(:,:), dv(:,:)

! ... loop variables
  INTEGER :: ic

! ... local variables
  REAL(RFREAL) :: rgas,rrho,vm2
#ifdef RFLO
  REAL(RFREAL) :: gam1, g1cp
#endif
#ifdef RFLU
  REAL(RFREAL) :: eo,gamma,rho
#endif

!******************************************************************************

  DO ic=inbeg,inend
#ifdef RFLO
    rgas = 8314.3_rfreal/gv(gv_mixt_mol,ic*indmol)
    gam1 = gv(gv_mixt_cp,ic*indcp)/(gv(gv_mixt_cp,ic*indcp)-rgas) - 1._rfreal
    g1cp = gam1*gv(gv_mixt_cp,ic*indcp)
    rrho = 1._rfreal/cv(cv_mixt_dens,ic)

    dv(dv_mixt_uvel,ic) = cv(cv_mixt_xmom,ic)*rrho
    dv(dv_mixt_vvel,ic) = cv(cv_mixt_ymom,ic)*rrho
    dv(dv_mixt_wvel,ic) = cv(cv_mixt_zmom,ic)*rrho

    vm2 = dv(dv_mixt_uvel,ic)*dv(dv_mixt_uvel,ic) + &
          dv(dv_mixt_vvel,ic)*dv(dv_mixt_vvel,ic) + &
          dv(dv_mixt_wvel,ic)*dv(dv_mixt_wvel,ic)

    dv(dv_mixt_pres,ic) = gam1*(cv(cv_mixt_ener,ic)- &
                                0.5_rfreal*vm2*cv(cv_mixt_dens,ic))
    dv(dv_mixt_temp,ic) = dv(dv_mixt_pres,ic)*rrho/rgas
    dv(dv_mixt_soun,ic) = sqrt(g1cp*dv(dv_mixt_temp,ic))
#endif
#ifdef RFLU
    rgas  = mixtperf_r_m(gv(gv_mixt_mol,ic*indmol))
    gamma = mixtperf_g_cpr(gv(gv_mixt_cp,ic*indcp),rgas)

    rho  = cv(cv_mixt_dens,ic)
    rrho = 1.0_rfreal/rho
    eo   = cv(cv_mixt_ener,ic)*rrho

    vm2 = (cv(cv_mixt_xmom,ic)*cv(cv_mixt_xmom,ic) + &
           cv(cv_mixt_ymom,ic)*cv(cv_mixt_ymom,ic) + &
           cv(cv_mixt_zmom,ic)*cv(cv_mixt_zmom,ic))*rrho*rrho

    dv(dv_mixt_pres,ic) = mixtperf_p_deogvm2(rho,eo,gamma,vm2)
    dv(dv_mixt_temp,ic) = mixtperf_t_dpr(rho,dv(dv_mixt_pres,ic),rgas)
    dv(dv_mixt_soun,ic) = mixtperf_c_grt(gamma,rgas,dv(dv_mixt_temp,ic))
#endif
  ENDDO

END SUBROUTINE perfgasdependentvars

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PerfgasDependentVars.F90,v $
! Revision 1.3  2008/12/06 08:44:09  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:23  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 16:49:56  haselbac
! Initial revision after changing case
!
! Revision 1.12  2003/11/20 16:40:35  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.9  2003/05/13 23:46:52  haselbac
! Reverted to use of MixtPerf routines for RFLU
!
! Revision 1.8  2003/05/06 20:05:39  jblazek
! Corrected bug in grid motion (corner "averaging").
!
! Revision 1.7  2002/07/05 23:20:46  jblazek
! Corrected bug in perfgasDependentVars.F90; did some cosmetics.
!
! Revision 1.6  2002/06/05 18:33:00  haselbac
! Converted to use of mixtPerf routines
!
! Revision 1.5  2002/03/18 22:25:45  jblazek
! Finished multiblock and MPI.
!
! Revision 1.4  2002/02/21 23:25:05  jblazek
! Blocks renamed as regions.
!
! Revision 1.3  2002/02/09 01:47:01  jblazek
! Added multi-probe option, residual smoothing, physical time step.
!
! Revision 1.2  2002/01/23 03:51:24  jblazek
! Added low-level time-stepping routines.
!
! Revision 1.1  2002/01/10 00:02:06  jblazek
! Added calculation of mixture properties.
!
!******************************************************************************