PLAG_ReflectParticleData.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Reflect particle data about patch face. 
!
! Description: None.
!
! Input: 
!  pPatch       Pointer to patch
!  pPlag        Pointer to particle data
!  ifl          Local face index
!  iPcl         Particle index
!  xLocOld      x-component of old particle location
!  yLocOld      y-component of old particle location
!  zLocOld      z-component of old particle location    
!  xLoc         x-component of particle location
!  yLoc         y-component of particle location
!  zLoc         z-component of particle location
!  xTraj        x-component of particle trajectory
!  yTraj        y-component of particle trajectory
!  zTraj        z-component of particle trajectory
!
! Output: 
!  xLocOld      x-component of reflected old particle location
!  yLocOld      y-component of reflected old particle location
!  zLocOld      z-component of reflected old particle location  
!  xLoc         x-component of reflected particle location
!  yLoc         y-component of reflected particle location
!  zLoc         z-component of reflected particle location
!  xTraj        x-component of reflected particle trajectory
!  yTraj        y-component of reflected particle trajectory
!  zTraj        z-component of reflected particle trajectory
!
! Notes: 
!   1. Reflect particle data about centroid of face instead of about point of
!      intersection of particle path and plane defined by face. This is ok 
!      because vector between centroid and intersection lies in plane defined 
!      by face. 
!
! ******************************************************************************
!
! $Id: PLAG_ReflectParticleData.F90,v 1.8 2008/12/06 08:44:36 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE plag_reflectparticledata(pPatch,pPlag,ifl,iPcl,xLocOld,yLocOld, & 
                                    zlocold,xloc,yloc,zloc,xtraj,ytraj,ztraj)

  USE moddatatypes
  USE modparameters
  USE moderror
  USE modglobal, ONLY: t_global
  USE modbndpatch, ONLY: t_patch
  USE modpartlag, ONLY: t_plag
  USE modmpi
  
  USE plag_modparameters    
   
  USE modinterfaces, ONLY: reflectposition, & 
                           reflectvector 
   
  IMPLICIT NONE

! ******************************************************************************
! Declarations
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  INTEGER, INTENT(IN) :: ifl,ipcl
  REAL(RFREAL), INTENT(INOUT) :: xloc,xlocold,yloc,ylocold,zloc,zlocold
  REAL(RFREAL), INTENT(INOUT), OPTIONAL :: xtraj,ytraj,ztraj                                 
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_plag), POINTER :: pplag

! ==============================================================================  
! Locals
! ==============================================================================  

  CHARACTER(CHRLEN) :: rcsidentstring
  REAL(RFREAL) :: nx,ny,nz,xc,xmom,xrhssum,yc,ymom,yrhssum,zc,zmom,zrhssum

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_ReflectParticleData.F90,v $ $Revision: 1.8 $'

! ******************************************************************************
! Reflect particle data
! ******************************************************************************

! ==============================================================================  
! Get face normal and centroid
! ==============================================================================  

  nx = ppatch%fn(xcoord,ifl)
  ny = ppatch%fn(ycoord,ifl)
  nz = ppatch%fn(zcoord,ifl)    

  xc = ppatch%fc(xcoord,ifl)
  yc = ppatch%fc(ycoord,ifl)
  zc = ppatch%fc(zcoord,ifl)    
    
! ==============================================================================  
! Reflect old position, new position, and trajectory
! ==============================================================================  

  CALL reflectposition(nx,ny,nz,xc,yc,zc,xlocold,ylocold,zlocold)
  CALL reflectposition(nx,ny,nz,xc,yc,zc,xloc,yloc,zloc)
  
  IF ( (present(xtraj) .EQV. .true.) .AND. & 
       (present(ytraj) .EQV. .true.) .AND. &
       (present(ztraj) .EQV. .true.) ) THEN 
    CALL reflectvector(nx,ny,nz,xtraj,ytraj,ztraj)
  END IF ! PRESENT
  
! ==============================================================================  
! Reflect particle momentum (and any other data)
! ==============================================================================  
  
  xmom = pplag%cv(cv_plag_xmom,ipcl)
  ymom = pplag%cv(cv_plag_ymom,ipcl) 
  zmom = pplag%cv(cv_plag_zmom,ipcl)
  
  CALL reflectvector(nx,ny,nz,xmom,ymom,zmom)  
  
  pplag%cv(cv_plag_xmom,ipcl) = xmom 
  pplag%cv(cv_plag_ymom,ipcl) = ymom
  pplag%cv(cv_plag_zmom,ipcl) = zmom  
  
  xmom = pplag%cvOld(cv_plag_xmom,ipcl)
  ymom = pplag%cvOld(cv_plag_ymom,ipcl) 
  zmom = pplag%cvOld(cv_plag_zmom,ipcl)
  
  CALL reflectvector(nx,ny,nz,xmom,ymom,zmom)  
  
  pplag%cvOld(cv_plag_xmom,ipcl) = xmom 
  pplag%cvOld(cv_plag_ymom,ipcl) = ymom
  pplag%cvOld(cv_plag_zmom,ipcl) = zmom  

! ==============================================================================  
! Reflect particle rhsSum, needed for RK4 and RK3
! ==============================================================================  
  
  xrhssum = pplag%rhsSum(cv_plag_xmom,ipcl)
  yrhssum = pplag%rhsSum(cv_plag_ymom,ipcl) 
  zrhssum = pplag%rhsSum(cv_plag_zmom,ipcl)
  
  CALL reflectvector(nx,ny,nz,xrhssum,yrhssum,zrhssum)  
  
  pplag%rhsSum(cv_plag_xmom,ipcl) = xrhssum 
  pplag%rhsSum(cv_plag_ymom,ipcl) = yrhssum
  pplag%rhsSum(cv_plag_zmom,ipcl) = zrhssum  
  
  xrhssum = pplag%rhsSum(cv_plag_xpos,ipcl)
  yrhssum = pplag%rhsSum(cv_plag_ypos,ipcl) 
  zrhssum = pplag%rhsSum(cv_plag_zpos,ipcl)
  
  CALL reflectvector(nx,ny,nz,xrhssum,yrhssum,zrhssum)  
  
  pplag%rhsSum(cv_plag_xpos,ipcl) = xrhssum 
  pplag%rhsSum(cv_plag_ypos,ipcl) = yrhssum
  pplag%rhsSum(cv_plag_zpos,ipcl) = zrhssum

! ******************************************************************************
! End
! ******************************************************************************

END SUBROUTINE plag_reflectparticledata

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_ReflectParticleData.F90,v $
! Revision 1.8  2008/12/06 08:44:36  mtcampbe
! Updated license.
!
! Revision 1.7  2008/11/19 22:17:48  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.6  2006/04/07 15:19:24  haselbac
! Removed tabs
!
! Revision 1.5  2005/01/01 21:34:29  haselbac
! Made traj arguments optional
!
! Revision 1.4  2004/11/30 23:34:10  fnajjar
! Included further description in comment for reflection of rhsSum
!
! Revision 1.3  2004/06/17 14:32:16  fnajjar
! Applied reflectivity to rhsSum vectors of positions and momenta
!
! Revision 1.2  2004/05/05 21:01:22  fnajjar
! Bug fixes: Reflect position properly and reflect old momentum
!
! Revision 1.1  2004/04/08 01:32:13  haselbac
! Initial revision
!
! ******************************************************************************