PLAG_ReadPdfFromFile.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************

!******************************************************************************
!
! Purpose: read in user defined porbability density function (PDF) of
!          the mass injection process.
!
! Description: none
!
! Input: user input file.
!
! Output: structure with information relative to the imposed pdf
!
! Notes:  none
!
!******************************************************************************
!
! $Id: PLAG_ReadPdfFromFile.F90,v 1.4 2008/12/06 08:44:35 mtcampbe Exp $
!
! Copyright: (c) 2005 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_readpdffromfile(regions, brbeg, brend )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE moderror
  USE modparameters

  USE plag_modparameters

  TYPE(t_region), POINTER :: regions(:)
  INTEGER,INTENT(IN)      :: brbeg,brend

! ... local variables
  TYPE(t_global), POINTER :: global
  CHARACTER(CHRLEN)       :: fname
  REAL(RFREAL),POINTER    :: tmpvec(:,:)
  REAL(RFREAL)            :: tmpscal
  INTEGER                 :: k,tmpint,errorflag,nbins,nrow
!******************************************************************************


  global => regions(1)%global

  CALL registerfunction( global, 'PLAG_ReadPdfFromFile',&
  'PLAG_ReadPdfFromFile.F90' )

!OPEN PDF file
  WRITE(fname,'(A,A,A)') trim(global%inDir),trim(global%casename),'.plag_injcpdf'
  OPEN(if_plag_injcpdf,file=fname,form='formatted',status='old',iostat=errorflag)
  global%error = errorflag
  IF (global%error /= 0) &
       CALL errorstop( global, err_file_open,__line__,'File: '//trim(fname) )
  READ(if_plag_injcpdf,*,err=10,end=10) nbins

!Allocation
  do k = brbeg,brend
     ALLOCATE(regions(k)%plagInput%PDF%pdfvalues(nbins+1,3), stat=errorflag )
  enddo
  global%error = errorflag
  ALLOCATE(tmpvec(nbins+1,5), stat=errorflag)
  global%error = abs(global%error) + abs(errorflag)
  IF (global%error /= 0) CALL errorstop( global, err_allocate,__line__ )

!Read in the discrete PDF
  do k = 1,nbins
     READ(if_plag_injcpdf,*,err=10,end=10) nrow,tmpvec(k,1:2)
  enddo
        
  tmpvec(1,3) = (tmpvec(2,1)-tmpvec(1,1))        
  do k = 2,nbins
     tmpvec(k,3) = 2_rfreal*(tmpvec(k,1)-tmpvec(k-1,1)) - tmpvec(k-1,3)
  enddo

!evaluate the two following cumulative sums 
  tmpvec(1,4:5) = 0_rfreal
  do k = 1,nbins
     tmpvec(k+1,4) = tmpvec(k,4) + tmpvec(k,2)*tmpvec(k,3)
     tmpvec(k+1,5) = tmpvec(k,5) + tmpvec(k,3)
  enddo
  tmpvec(:,4) = tmpvec(:,4) / tmpvec(nbins+1,4)
  tmpvec(:,5) = tmpvec(:,5) + tmpvec(1,1) - tmpvec(1,3)/2_rfreal


!assign the tmp vector entries to the region pointer
  regions(brbeg:brend)%plagInput%PDF%nbins = nbins        
  do k = brbeg,brend
     regions(k)%plagInput%PDF%pdfvalues(:,1:3) = tmpvec(:,3:5)
  enddo

!--find the maximum in the PDF curve. This is the most probable diameter value,
!--the one from which the search will start;                                                        
  tmpscal = 0_rfreal
  do k = 1,nbins
     if(tmpvec(k+1,4) - tmpvec(k,4) > tmpscal) then
        tmpint = k+1
        tmpscal = tmpvec(k+1,4) - tmpvec(k,4)
     endif
  enddo
  tmpscal = tmpvec(tmpint,4)
  regions(brbeg:brend)%plagInput%PDF%locmax = tmpint
  regions(brbeg:brend)%plagInput%PDF%valmax = tmpscal

  DEALLOCATE(tmpvec)
  close(if_plag_injcpdf)

goto 999

10  CONTINUE
  CALL errorstop( global, err_file_read,__line__,'File: '//trim(fname) )

! finalize --------------------------------------------------------------------

999 CONTINUE

  CALL deregisterfunction( global )

END SUBROUTINE plag_readpdffromfile

!******************************************************************************