PLAG_RFLU_WriteSolutionBinary.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Write flow file for particles in binary ROCFLU format.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: PLAG_RFLU_WriteSolutionBinary.F90,v 1.6 2008/12/06 08:44:35 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE plag_rflu_writesolutionbinary(pRegion)

  USE modglobal, ONLY: t_global
  USE moddatatypes
  USE modparameters
  USE moderror
  USE modgrid, ONLY: t_grid
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region 
  USE modpartlag, ONLY: t_plag,t_tile_plag     
  USE modmpi

  USE plag_modparameters

  USE modbuildfilenames, ONLY: buildfilenameunsteady

  IMPLICIT NONE
  
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  
   
! ==============================================================================
! Local variables
! ==============================================================================

  CHARACTER(CHRLEN) :: ifilename,sectionstring,rcsidentstring
  INTEGER :: errorflag,icont,ifile,ifl,imass,ipatch,ivar,j,ncont,nvars 
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_global), POINTER :: global
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_plag), POINTER :: pplag
  TYPE(t_tile_plag), POINTER :: ptileplag  
  
! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion  
  
! ******************************************************************************
! Start, open file
! ******************************************************************************

  rcsidentstring = &
    '$RCSfile: PLAG_RFLU_WriteSolutionBinary.F90,v $ $Revision: 1.6 $'

  global => pregion%global

  CALL registerfunction(global,'PLAG_RFLU_WriteSolutionBinary',&
  'PLAG_RFLU_WriteSolutionBinary.F90')

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Writing binary particle file...'
  END IF ! global%verbLevel

  CALL buildfilenameunsteady(global,filedest_outdir,'.plag_sol', & 
                             pregion%iRegionGlobal,global%currentTime, & 
                             ifilename)

  ifile = if_solut
  OPEN(ifile,file=ifilename,form="UNFORMATTED",status="UNKNOWN",&
       iostat=errorflag)
  global%error = errorflag          
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_open,__line__,ifilename)
  END IF ! global%error  

! ==============================================================================
! Header and general information
! ==============================================================================

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_low ) THEN  
    WRITE(stdout,'(A,3X,A)') solver_name,'Header information...'
  END IF ! global%verbLevel

  sectionstring = '# ROCFLU particle file'
  WRITE(ifile) sectionstring
  
  sectionstring = '# Precision and range'
  WRITE(ifile) sectionstring
  WRITE(ifile) precision(1.0_rfreal),range(1.0_rfreal)
  
  sectionstring = '# Physical time'
  WRITE(ifile) sectionstring
  WRITE(ifile) global%currentTime 

! ==============================================================================
! Dimensions
! ==============================================================================
  
  pgrid => pregion%grid  
  pplag => pregion%plag
   
  ncont = pregion%plagInput%nCont   
   
  nvars = 13 ! Hard-coded for now
   
  sectionstring = '# Dimensions'
  WRITE(ifile) sectionstring
  WRITE(ifile) pplag%nPcls,nvars
  
! ==============================================================================
! State vector
! ==============================================================================

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_low ) THEN  
    WRITE(stdout,'(A,3X,A)') solver_name,'Conserved variables...'
  END IF ! global%verbLevel

  sectionstring = '# Particle x-momentum'
  WRITE(ifile) sectionstring
  WRITE(ifile) (pplag%cv(cv_plag_xmom,j),j=1,pplag%nPcls)

  sectionstring = '# Particle y-momentum'
  WRITE(ifile) sectionstring
  WRITE(ifile) (pplag%cv(cv_plag_ymom,j),j=1,pplag%nPcls)

  sectionstring = '# Particle z-momentum'
  WRITE(ifile) sectionstring
  WRITE(ifile) (pplag%cv(cv_plag_zmom,j),j=1,pplag%nPcls)
 
  sectionstring = '# Particle energy'
  WRITE(ifile) sectionstring
  WRITE(ifile) (pplag%cv(cv_plag_ener,j),j=1,pplag%nPcls) 

  sectionstring = '# Particle x-location'
  WRITE(ifile) sectionstring
  WRITE(ifile) (pplag%cv(cv_plag_xpos,j),j=1,pplag%nPcls)
  
  sectionstring = '# Particle y-location'
  WRITE(ifile) sectionstring
  WRITE(ifile) (pplag%cv(cv_plag_ypos,j),j=1,pplag%nPcls)
  
  sectionstring = '# Particle z-location'
  WRITE(ifile) sectionstring
  WRITE(ifile) (pplag%cv(cv_plag_zpos,j),j=1,pplag%nPcls)    
  
  sectionstring = '# Particle vapor energy'
  WRITE(ifile) sectionstring
  WRITE(ifile) (pplag%cv(cv_plag_enervapor,j),j=1,pplag%nPcls)    
 
  DO icont = 1,pregion%plagInput%nCont
    imass = pplag%cvPlagMass(icont)

    sectionstring = '# Particle mass'       
    WRITE(ifile) sectionstring
    WRITE(ifile) (pplag%cv(imass,j),j=1,pplag%nPcls)  
  END DO ! iCont
 
! ==============================================================================
! Additional variables
! ==============================================================================

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_low ) THEN  
    WRITE(stdout,'(A,3X,A)') solver_name,'Additional variables...'
  END IF ! global%verbLevel

  sectionstring = '# Particle superloading'
  WRITE(ifile) sectionstring
  WRITE(ifile) (pplag%arv(arv_plag_spload,j),j=1,pplag%nPcls)
 
  sectionstring = '# Particle initial identifier'
  WRITE(ifile) sectionstring
  WRITE(ifile) (pplag%aiv(aiv_plag_pidini,j),j=1,pplag%nPcls)
 
  sectionstring = '# Particle initial region'
  WRITE(ifile) sectionstring
  WRITE(ifile) (pplag%aiv(aiv_plag_regini,j),j=1,pplag%nPcls) 

  sectionstring = '# Particle cell'
  WRITE(ifile) sectionstring
  WRITE(ifile) (pplag%aiv(aiv_plag_icells,j),j=1,pplag%nPcls) 
  
! ==============================================================================
! Patch data
! ==============================================================================

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_low ) THEN  
    WRITE(stdout,'(A,3X,A)') solver_name,'Patch data...'
  END IF ! global%verbLevel

  sectionstring = '# Patch data'
  WRITE(ifile) sectionstring      
    
  DO ipatch = 1,pgrid%nPatches
    ppatch => pregion%patches(ipatch)
    
    IF ( (ppatch%bcType >= bc_injection .AND. ppatch%bcType <= bc_injection + bc_range) .OR. &
         (ppatch%bcType >= bc_inflow    .AND. ppatch%bcType <= bc_inflow    + bc_range)      )  THEN
      ptileplag   => ppatch%tilePlag      
      
      DO ifl = 1,ppatch%nBFaces
        WRITE(ifile) ptileplag%cv(cv_tile_momnrm,ifl), & 
                     ptileplag%cv(cv_tile_ener  ,ifl)
      END DO ! ifl      
      
      DO icont = 1,ncont
        imass = ptileplag%cvTileMass(icont)
        WRITE(ifile) (ptileplag%cv(imass,ifl), &
                      ifl=1,ppatch%nBFaces)
      END DO ! iCont
      
      DO ifl = 1,ppatch%nBFaces
        WRITE(ifile) ptileplag%dv(dv_tile_countdown,ifl), & 
                     ptileplag%dv(dv_tile_diam    ,ifl), & 
                     ptileplag%dv(dv_tile_spload  ,ifl)
      END DO ! ifl                               
    END IF ! pPatch%bcType
  END DO ! iPatch

! ==============================================================================
! End marker
! ==============================================================================

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_low ) THEN  
    WRITE(stdout,'(A,3X,A)') solver_name,'End marker...'
  END IF ! global%verbLevel

  sectionstring = '# End'
  WRITE(ifile) sectionstring  

! ==============================================================================
! Close file
! ==============================================================================

  CLOSE(ifile,iostat=errorflag)
  global%error = errorflag      
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_close,__line__,ifilename)
  END IF ! global%error
   
  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN   
    WRITE(stdout,'(A,1X,A)') solver_name,'Writing binary particle file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)
    
! ******************************************************************************
! End
! ******************************************************************************
 
END SUBROUTINE plag_rflu_writesolutionbinary


! ******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_RFLU_WriteSolutionBinary.F90,v $
! Revision 1.6  2008/12/06 08:44:35  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:48  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2006/09/18 20:37:02  fnajjar
! Activated tile datastructure for inflow bc
!
! Revision 1.3  2006/05/06 18:49:53  fnajjar
! Bug fix in write statement for string End
!
! Revision 1.2  2005/01/21 17:23:10  fnajjar
! Included vapor energy in IO capability
!
! Revision 1.1  2004/08/23 23:06:53  fnajjar
! Initial revision
!
! Revision 1.4  2004/06/16 23:03:09  fnajjar
! ******************************************************************************