PLAG_RFLU_ReadSolutionBinary.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Read flow file for particles in binary ROCFLU format.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: PLAG_RFLU_ReadSolutionBinary.F90,v 1.6 2008/12/06 08:44:35 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE plag_rflu_readsolutionbinary(pRegion)

  USE modglobal, ONLY: t_global
  USE moddatatypes
  USE modparameters
  USE moderror
  USE modgrid, ONLY: t_grid
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region 
  USE modpartlag, ONLY: t_plag,t_tile_plag     
  USE modmpi

  USE plag_modparameters

  USE modbuildfilenames, ONLY: buildfilenameunsteady

  IMPLICIT NONE
  
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  
   
! ==============================================================================
! Local variables
! ==============================================================================

  CHARACTER(CHRLEN) :: errorstring,ifilename,sectionstring,rcsidentstring, & 
                       timestring1,timestring2
  INTEGER :: errorflag,icont,ifile,ifl,imass,ipatch,ivars,j,loopcounter,ncont, &
             npcls,npclsexpected,nvars,nvarsexpected,precactual,precexpected, &
             rangeactual,rangeexpected
  INTEGER, DIMENSION(:,:), POINTER :: paiv
  REAL(RFREAL) :: currenttime
  REAL(RFREAL), DIMENSION(:,:), POINTER :: parv,pcv
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_global), POINTER :: global
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_plag), POINTER :: pplag
  TYPE(t_tile_plag), POINTER :: ptileplag  
  
! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion  
  
! ******************************************************************************
! Start, open file
! ******************************************************************************

  rcsidentstring = &
    '$RCSfile: PLAG_RFLU_ReadSolutionBinary.F90,v $ $Revision: 1.6 $'

  global => pregion%global

  CALL registerfunction(global,'PLAG_RFLU_ReadSolutionBinary',&
  'PLAG_RFLU_ReadSolutionBinary.F90')

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Reading binary particle file...'
  END IF ! global%verbLevel

  CALL buildfilenameunsteady(global,filedest_outdir,'.plag_sol', & 
                             pregion%iRegionGlobal,global%currentTime, & 
                             ifilename)

  ifile = if_solut
  OPEN(ifile,file=ifilename,form="UNFORMATTED",status="OLD",iostat=errorflag)
  global%error = errorflag          
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_open,__line__,ifilename)
  END IF ! global%error  

! ==============================================================================
! Header and general information
! ==============================================================================

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_low ) THEN  
    WRITE(stdout,'(A,3X,A)') solver_name,'Header information...'
  END IF ! global%verbLevel

  READ(ifile) sectionstring
  IF ( trim(sectionstring) /= '# ROCFLU particle file' ) THEN 
    CALL errorstop(global,err_invalid_marker,__line__,sectionstring) 
  END IF ! TRIM  
  
! -----------------------------------------------------------------------------
! Precision and range
! -----------------------------------------------------------------------------
    
  READ(ifile) sectionstring
  IF ( trim(sectionstring) /= '# Precision and range' ) THEN 
    CALL errorstop(global,err_invalid_marker,__line__,sectionstring) 
  END IF ! TRIM  
  
  precexpected  = precision(1.0_rfreal)
  rangeexpected = range(1.0_rfreal)
  
  READ(ifile) precactual,rangeactual
  IF ( precactual < precexpected .OR. rangeactual < rangeexpected ) THEN 
    CALL errorstop(global,err_prec_range,__line__)
  END IF ! precActual
  
! -----------------------------------------------------------------------------
! Initial residual and physical time
! -----------------------------------------------------------------------------
    
  READ(ifile) sectionstring
  IF ( trim(sectionstring) /= '# Physical time' ) THEN 
    CALL errorstop(global,err_invalid_marker,__line__,ifilename)
  END IF ! TRIM    
   
  READ(ifile) currenttime 

#ifndef GENX  
  IF ( global%flowType == flow_unsteady ) THEN
    IF ( global%currentTime < 0.0_rfreal ) THEN
      global%currentTime = currenttime
    ELSE
      WRITE(timestring1,'(1PE11.5)') global%currentTime
      WRITE(timestring2,'(1PE11.5)') currenttime          
      IF ( trim(timestring1) /= trim(timestring2) ) THEN
        CALL errorstop(global,err_time_solution,__line__,trim(ifilename))
      END IF ! global%currentTime 
    END IF ! global%currentTime
  END IF ! global%flowType  
#endif  

! ==============================================================================
! Dimensions
! ==============================================================================
  
  pgrid => pregion%grid  
  pplag => pregion%plag
   
  ncont = pregion%plagInput%nCont 
   
  nvarsexpected = 13 ! Hard-coded for now
  npclsexpected = pplag%nPcls    
  
  READ(ifile) sectionstring
  IF ( trim(sectionstring) /= '# Dimensions' ) THEN 
    CALL errorstop(global,err_invalid_marker,__line__,sectionstring) 
  END IF ! TRIM

  READ(ifile) npcls,nvars
  
  IF ( npcls /= npclsexpected ) THEN 
    WRITE(errorstring,'(A,1X,I6,1X,A,1X,I6)') 'Specified:',npcls, & 
                                              'but expected:',npclsexpected
    CALL errorstop(global,err_plag_invalid_npcls,__line__,errorstring)
  END IF ! nCellsExpected     
  
  IF ( nvars /= nvarsexpected ) THEN 
    WRITE(errorstring,'(A,1X,I6,1X,A,1X,I6)') 'Specified:',nvars, & 
                                              'but expected:',nvarsexpected  
    CALL errorstop(global,err_invalid_nvars,__line__)
  END IF ! nVarsExpected    

! ==============================================================================
! Rest of file
! ==============================================================================

  icont       = 0
  ivars       = 0
  loopcounter = 0

  DO ! set up infinite loop
    loopcounter = loopcounter + 1
  
    READ(ifile) sectionstring

    SELECT CASE ( trim(sectionstring) ) 

! ------------------------------------------------------------------------------
!     Particle x-momentum
! ------------------------------------------------------------------------------

      CASE ( '# Particle x-momentum' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle x-momentum...'
        END IF ! global%verbLevel    
      
        pcv => pregion%plag%cv
      
        ivars = ivars + 1
        READ(ifile) (pcv(cv_plag_xmom,j),j=1,pplag%nPcls)

! ------------------------------------------------------------------------------
!     Particle y-momentum
! ------------------------------------------------------------------------------

      CASE ( '# Particle y-momentum' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle y-momentum...'
        END IF ! global%verbLevel    
      
        pcv => pregion%plag%cv
      
        ivars = ivars + 1
        READ(ifile) (pcv(cv_plag_ymom,j),j=1,pplag%nPcls)

! ------------------------------------------------------------------------------
!     Particle z-momentum
! ------------------------------------------------------------------------------

      CASE ( '# Particle z-momentum' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle z-momentum...'
        END IF ! global%verbLevel    
      
        pcv => pregion%plag%cv
      
        ivars = ivars + 1
        READ(ifile) (pcv(cv_plag_zmom,j),j=1,pplag%nPcls)

! ------------------------------------------------------------------------------
!     Particle energy
! ------------------------------------------------------------------------------

      CASE ( '# Particle energy' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle energy...'
        END IF ! global%verbLevel    
      
        pcv => pregion%plag%cv
      
        ivars = ivars + 1
        READ(ifile) (pcv(cv_plag_ener,j),j=1,pplag%nPcls)

! ------------------------------------------------------------------------------
!     Particle x-location
! ------------------------------------------------------------------------------

      CASE ( '# Particle x-location' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle x-location...'
        END IF ! global%verbLevel    
      
        pcv => pregion%plag%cv
      
        ivars = ivars + 1
        READ(ifile) (pcv(cv_plag_xpos,j),j=1,pplag%nPcls)

! ------------------------------------------------------------------------------
!     Particle y-location
! ------------------------------------------------------------------------------

      CASE ( '# Particle y-location' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle y-location...'
        END IF ! global%verbLevel    
      
        pcv => pregion%plag%cv
      
        ivars = ivars + 1
        READ(ifile) (pcv(cv_plag_ypos,j),j=1,pplag%nPcls)

! ------------------------------------------------------------------------------
!     Particle z-location
! ------------------------------------------------------------------------------

      CASE ( '# Particle z-location' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle z-location...'
        END IF ! global%verbLevel    
      
        pcv => pregion%plag%cv
      
        ivars = ivars + 1
        READ(ifile) (pcv(cv_plag_zpos,j),j=1,pplag%nPcls)

! ------------------------------------------------------------------------------
!     Particle vapor energy
! ------------------------------------------------------------------------------

      CASE ( '# Particle vapor energy' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle vapor energy...'
        END IF ! global%verbLevel    
      
        pcv => pregion%plag%cv
      
        ivars = ivars + 1
        READ(ifile) (pcv(cv_plag_enervapor,j),j=1,pplag%nPcls)

! ------------------------------------------------------------------------------
!     Particle mass
! ------------------------------------------------------------------------------

      CASE ( '# Particle mass' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle mass...'
        END IF ! global%verbLevel    
      
        pcv => pregion%plag%cv
      
        IF ( icont == 0 ) THEN 
          ivars = ivars + 1
        END IF ! iCont
              
        icont = icont + 1
        imass = pplag%cvPlagMass(icont)
        
        READ(ifile) (pcv(imass,j),j=1,pplag%nPcls)

! ------------------------------------------------------------------------------
!     Particle superloading
! ------------------------------------------------------------------------------

      CASE ( '# Particle superloading' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle superloading...'
        END IF ! global%verbLevel    
      
        parv => pregion%plag%arv
      
        ivars = ivars + 1
        READ(ifile) (parv(arv_plag_spload,j),j=1,pplag%nPcls)

! ------------------------------------------------------------------------------
!     Particle initial identifier
! ------------------------------------------------------------------------------

      CASE ( '# Particle initial identifier' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle initial identifier...'
        END IF ! global%verbLevel    
      
        paiv => pregion%plag%aiv
      
        ivars = ivars + 1
        READ(ifile) (paiv(aiv_plag_pidini,j),j=1,pplag%nPcls)

! ------------------------------------------------------------------------------
!     Particle initial region
! ------------------------------------------------------------------------------

      CASE ( '# Particle initial region' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle initial region...'
        END IF ! global%verbLevel    
      
        paiv => pregion%plag%aiv
      
        ivars = ivars + 1
        READ(ifile) (paiv(aiv_plag_regini,j),j=1,pplag%nPcls)
        
! ------------------------------------------------------------------------------
!     Particle cell
! ------------------------------------------------------------------------------

      CASE ( '# Particle cell' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Particle cell...'
        END IF ! global%verbLevel    
      
        paiv => pregion%plag%aiv
      
        ivars = ivars + 1
        READ(ifile) (paiv(aiv_plag_icells,j),j=1,pplag%nPcls)        

! ------------------------------------------------------------------------------
!     Patch data
! ------------------------------------------------------------------------------

      CASE ( '# Patch data' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'Patch data...'
        END IF ! global%verbLevel                
      
        DO ipatch = 1,pgrid%nPatches
          ppatch => pregion%patches(ipatch)

         IF ( (ppatch%bcType >= bc_injection .AND. ppatch%bcType <= bc_injection + bc_range) .OR. &
              (ppatch%bcType >= bc_inflow    .AND. ppatch%bcType <= bc_inflow    + bc_range)      )  THEN
            ptileplag   => ppatch%tilePlag 

            DO ifl = 1,ppatch%nBFaces
              READ(ifile) ptileplag%cv(cv_tile_momnrm,ifl), & 
                          ptileplag%cv(cv_tile_ener  ,ifl)
            END DO ! ifl 
            
            DO icont = 1,ncont
              imass = ptileplag%cvTileMass(icont)
              READ(ifile) (ptileplag%cv(imass,ifl), &
                           ifl=1,ppatch%nBFaces)
            END DO ! iCont            
            
            DO ifl = 1,ppatch%nBFaces
              READ(ifile) ptileplag%dv(dv_tile_countdown,ifl), & 
                          ptileplag%dv(dv_tile_diam    ,ifl), & 
                          ptileplag%dv(dv_tile_spload  ,ifl)
            END DO ! ifl                                    
          END IF ! pPatch%bcType
        END DO ! iPatch

! ------------------------------------------------------------------------------
!     End marker
! ------------------------------------------------------------------------------ 
      
      CASE ( '# End' ) 
        IF ( global%myProcid == masterproc .AND. & 
             global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,'End marker...'
        END IF ! global%verbLevel           
      
        EXIT
      
! ------------------------------------------------------------------------------
!     Invalid section string
! ------------------------------------------------------------------------------ 
      
      CASE default
        IF ( global%verbLevel > verbose_low ) THEN  
          WRITE(stdout,'(A,3X,A)') solver_name,sectionstring
        END IF ! verbosityLevel           
      
        CALL errorstop(global,err_invalid_marker,__line__,sectionstring)        
             
    END SELECT ! TRIM
  
! ------------------------------------------------------------------------------
!   Guard against infinite loop - might be unnecessary because of read errors?
! ------------------------------------------------------------------------------  
  
    IF ( loopcounter >= limit_infinite_loop ) THEN 
      CALL errorstop(global,err_infinite_loop,__line__)
    END IF ! loopCounter
  
  END DO ! <empty>

! ==============================================================================
! Check and information about number of variables read
! ==============================================================================

  IF ( ivars /= nvars ) THEN 
    CALL errorstop(global,err_invalid_nvars,__line__)
  END IF ! iVar
  
! ==============================================================================
! Close file
! ==============================================================================

  CLOSE(ifile,iostat=errorflag)
  global%error = errorflag      
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_close,__line__,ifilename)
  END IF ! global%error
   
  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN   
    WRITE(stdout,'(A,1X,A)') solver_name,'Reading binary particle file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)
    
! ******************************************************************************
! End
! ******************************************************************************
 
END SUBROUTINE plag_rflu_readsolutionbinary


! ******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_RFLU_ReadSolutionBinary.F90,v $
! Revision 1.6  2008/12/06 08:44:35  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:48  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2007/03/31 23:56:17  haselbac
! Removed superfluous close parentheses
!
! Revision 1.3  2006/09/18 20:37:02  fnajjar
! Activated tile datastructure for inflow bc
!
! Revision 1.2  2005/01/21 17:23:10  fnajjar
! Included vapor energy in IO capability
!
! Revision 1.1  2004/08/23 23:06:53  fnajjar
! Initial revision
!
! ******************************************************************************