PLAG_RFLU_InjectionDriver.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: main injection driver specific to RFLU
!          for the multiphase injection algorithm.
!
! Description: none.
!
! Input:
!   pRegion    Pointer to region data
!
! Output:
!   pPlag      Plag values for cv, aiv, arv of current region.
!   pTilePlag  Tile values for cv, dv of current region.
!
! Notes: none.
!
! ******************************************************************************
!
! $Id: PLAG_RFLU_InjectionDriver.F90,v 1.14 2008/12/06 08:44:35 mtcampbe Exp $
!
! Copyright: (c) 2004-2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE plag_rflu_injectiondriver(pRegion)

  USE moddatatypes
  USE modpartlag,    ONLY : t_plag, t_plag_input, t_tile_plag
  USE modbndpatch,   ONLY : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modgrid,       ONLY : t_grid
  USE moderror
  USE modparameters

  USE plag_modparameters
  USE inrt_modparameters
  USE plag_modinjection

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: bctype,burnstat,ejecmodel,icg,ifc,injcdiamdist,ipatch,&
             itile,iv1,iv2,iv3,iv4,nextidnumber,normdirflag,npatches,nvert
  INTEGER :: ifileplagtile
  INTEGER, POINTER, DIMENSION(:)   :: bf2c,pcvtilemass
  INTEGER, POINTER, DIMENSION(:,:) :: bf2v

  REAL(RFREAL) :: cellheight,injcbeta,pi,volmeanpart
  REAL(RFREAL) :: injcbetafac,injcbetafacinv,meansuperparticlevolume,spload

  REAL(RFREAL),          DIMENSION(3,4) :: xyzvertex

  REAL(RFREAL), POINTER, DIMENSION(:)   :: pvol
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: fc,fn,pxyz

  REAL(RFREAL), POINTER, DIMENSION(:,:) :: pcvtile,pdvtile

  TYPE(t_grid),      POINTER :: pgrid
  TYPE(t_global),    POINTER :: global
  TYPE(t_patch),     POINTER :: ppatch
  TYPE(t_plag),      POINTER :: pplag
  TYPE(t_tile_plag), POINTER :: ptileplag

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_RFLU_InjectionDriver.F90,v $ $Revision: 1.14 $'

  global => pregion%global

  CALL registerfunction( global, 'PLAG_RFLU_InjectionDriver',&
  'PLAG_RFLU_InjectionDriver.F90' )

! ******************************************************************************
! Set pointers and variables
! ******************************************************************************

  pgrid => pregion%grid
  pplag => pregion%plag

  npatches = pgrid%nPatches

  pi       = global%pi
  normdirflag = -1

  injcdiamdist  = pregion%plagInput%injcDiamDist
  injcbeta      = pregion%plagInput%injcBeta
  volmeanpart   = pi/6.0_rfreal * pregion%plagInput%injcDiamMean**3
  ejecmodel     = pregion%plagInput%ejecModel
  spload        = pregion%plagInput%spLoad

  IF ( ejecmodel == plag_ejec_cre ) THEN
    meansuperparticlevolume = volmeanpart *spload

    injcbetafac    = 2.0_rfreal *injcbeta *meansuperparticlevolume**2
    injcbetafacinv = 1.0_rfreal/injcbetafac
  ENDIF ! ejecModel

  pxyz        => pgrid%xyz

  pvol        => pgrid%vol

! ******************************************************************************
! Initial burning status of particles
! ******************************************************************************

! Currently all particles start off burning if the burning interaction is used

  IF (pregion%inrtInput%inrts(inrt_type_burning)%used) THEN
    burnstat = inrt_burnstat_on
  ELSE
    burnstat = inrt_burnstat_off
  ENDIF

! ******************************************************************************
! Loop over patches
! ******************************************************************************

  DO ipatch=1,npatches

    ppatch => pregion%patches(ipatch)

    bctype =  ppatch%bcType

    bf2c   => ppatch%bf2c
    bf2v   => ppatch%bf2v

    fc     => ppatch%fc
    fn     => ppatch%fn

!===============================================================================
!   Select injection boundary condition
!===============================================================================

    IF ( (bctype >= bc_injection .AND. bctype <= bc_injection + bc_range) .OR. &
         (bctype >= bc_inflow    .AND. bctype <= bc_inflow    + bc_range)      ) THEN 

!-------------------------------------------------------------------------------
!     Set tile pointers
!-------------------------------------------------------------------------------

      ptileplag => ppatch%tilePlag

      pcvtile     => ptileplag%cv
      pcvtilemass => ptileplag%cvTileMass
      pdvtile     => ptileplag%dv

!-------------------------------------------------------------------------------
!     Loop over face patches
!-------------------------------------------------------------------------------

      DO ifc = 1, ppatch%nBFaces
        itile = ifc
        icg   = bf2c(ifc)

!-------------------------------------------------------------------------------
!       Set cell height, element type and vertex coordinates
!-------------------------------------------------------------------------------

        cellheight = pvol(icg)/fn(xyzmag,ifc)

        iv1 = ppatch%bv(bf2v(1,ifc))
        iv2 = ppatch%bv(bf2v(2,ifc))
        iv3 = ppatch%bv(bf2v(3,ifc))

        xyzvertex(xcoord:zcoord,1) = pxyz(xcoord:zcoord,iv1)
        xyzvertex(xcoord:zcoord,2) = pxyz(xcoord:zcoord,iv2)
        xyzvertex(xcoord:zcoord,3) = pxyz(xcoord:zcoord,iv3)

        IF ( bf2v(4,ifc) == vert_none ) THEN
          nvert = 3
          iv4   = vert_none
          xyzvertex(xcoord:zcoord,4) = 0.0_rfreal
        ELSE
          nvert = 4
          iv4 = ppatch%bv(bf2v(4,ifc))
          xyzvertex(xcoord:zcoord,4) = pxyz(xcoord:zcoord,iv4)
        ENDIF ! iv4

!-------------------------------------------------------------------------------
!       Invoke injection algorithm
!-------------------------------------------------------------------------------

        SELECT CASE(ejecmodel)

!------------------------------------------------------------------------------
!         Ejection Model 1
!------------------------------------------------------------------------------

          CASE(plag_ejec_model1)
            CALL plag_invokeejecmodel1( pregion,pplag,ptileplag,           &
                                        itile,icg,burnstat,nvert,          &
                                        normdirflag,xyzvertex,volmeanpart, &
                                        fn(xcoord:zcoord,ifc),             &
                                        fc(xcoord:zcoord,ifc),             &
                                        cellheight                         )

!------------------------------------------------------------------------------
!         Conservative Random Ejection (CRE) Model
!------------------------------------------------------------------------------

          CASE(plag_ejec_cre)
            CALL plag_invokeconsrandejec( pregion,pplag,ptileplag,           &
                                          itile,icg,burnstat,nvert,          &
                                          normdirflag,xyzvertex,volmeanpart, &
                                          fn(xcoord:zcoord,ifc),             &
                                          fc(xcoord:zcoord,ifc),             &
                                          cellheight                         )

!------------------------------------------------------------------------------
!         Default case: trap error
!------------------------------------------------------------------------------

          CASE default
            CALL errorstop( global,err_reached_default,__line__ )
        END SELECT ! ejecModel      
      END DO ! ifc

!-------------------------------------------------------------------------------
!     Reset injected particle size
!-------------------------------------------------------------------------------

      ptileplag%nPclsInjc(:) = 0

    END IF ! bcType
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction( global )

END SUBROUTINE plag_rflu_injectiondriver

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_RFLU_InjectionDriver.F90,v $
! Revision 1.14  2008/12/06 08:44:35  mtcampbe
! Updated license.
!
! Revision 1.13  2008/11/19 22:17:48  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.12  2006/09/18 20:36:20  fnajjar
! Activated tile datastructure for inflow bc
!
! Revision 1.11  2006/04/07 15:19:24  haselbac
! Removed tabs
!
! Revision 1.10  2005/12/24 21:38:51  haselbac
! Cosmetics only
!
! Revision 1.9  2004/08/17 21:00:11  fnajjar
! Moved iv4 into IF statement for proper programming definition
!
! Revision 1.8  2004/08/15 20:36:41  fnajjar
! Bug fix for nVert, need to use bf2v instead of iv4
!
! Revision 1.7  2004/07/12 15:52:39  fnajjar
! Included interface and routine for conservative random ejection model
!
! Revision 1.6  2004/07/12 14:42:24  fnajjar
! Created proper interface to prepare for CRE ejection model
!
! Revision 1.5  2004/06/16 23:02:24  fnajjar
! Renamed variables for CRE kernel
!
! Revision 1.4  2004/05/21 23:28:45  fnajjar
! Bug fix for iv to properly access global face-to-vertex mapping and made io-cleanup
!
! Revision 1.3  2004/03/26 21:28:59  fnajjar
! Added aiv status flag at injection and properly activated burn status
!
! Revision 1.2  2004/03/25 21:16:06  jferry
! made initial BurnStatus depend on whether burning interaction is used
!
! Revision 1.1  2004/03/08 22:36:08  fnajjar
! Initial import of RFLU-specific injection routines
!
! ******************************************************************************