PLAG_RFLU_InjcTileCalcRhs.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: computes the RHS for the multiphase injection algorithm
!          specific to RFLU.
!
! Description: None.
!
! Input: 
!   pRegion     Region pointer
!
! Output: None.
!
! Notes: None.
!
!******************************************************************************
!
! $Id: PLAG_RFLU_InjcTileCalcRhs.F90,v 1.8 2008/12/06 08:44:35 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_rflu_injctilecalcrhs( pRegion )

  USE moddatatypes
  USE modpartlag, ONLY    : t_plag_input, t_tile_plag
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global  
  USE moderror
  USE modparameters

  USE plag_modparameters

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
 
  INTEGER           :: bctype,c1,distrib,errorflag,i2dvals,icont,icvmass,ifc, &
                       ipatch,itile,ncont,npatches
                       
  INTEGER, POINTER, DIMENSION(:) :: bf2c,pcvtilemass

  REAL(RFREAL)  :: area,cp,heatcapsum,heatcapsumr,injcvelratio,&
                   massfluxlimit,massfluxsum,massfluxsumr,minj, &
                   nm,nx,ny,nz,rhomixtbcond,tinj,tiletemp,tilevelnrm               
  REAL(RFREAL), POINTER, DIMENSION(:)   :: injcmassfluxratio, injctemp, specheat
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: cv, fn, prhs, vals
    
  TYPE(t_global), POINTER    :: global
  TYPE(t_patch), POINTER     :: ppatch
  TYPE(t_tile_plag), POINTER :: ptileplag  

! TEMPORARY
  REAL(RFREAL)  :: heatcapratio,massfluxratio,rhoplag
! END TEMPORARY

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_RFLU_InjcTileCalcRhs.F90,v $ $Revision: 1.8 $'

  global => pregion%global

  CALL registerfunction(global,'PLAG_RFLU_InjcTileCalcRhs',&
  'PLAG_RFLU_InjcTileCalcRhs.F90')

! ******************************************************************************
! Set pointers and variables 
! ******************************************************************************

  ncont    = pregion%plagInput%nCont
  npatches = pregion%grid%nPatches

  injcvelratio = pregion%plagInput%injcVelRatio  
  injcmassfluxratio => pregion%plagInput%injcMassFluxRatio
  specheat          => pregion%plagInput%spht
  injctemp          => pregion%plagInput%injcTemp

  cv => pregion%mixt%cv

  massfluxlimit = 1.0e-10_rfreal

! ******************************************************************************  
! Loop over patches 
! ******************************************************************************

  DO ipatch=1,npatches

    ppatch => pregion%patches(ipatch)
    vals   => ppatch%mixt%vals
    
    bf2c   => ppatch%bf2c
    fn     => ppatch%fn
    
    bctype = ppatch%bcType
    distrib = ppatch%mixt%distrib

!===============================================================================
!   Select injection boundary condition 
!===============================================================================

    IF ( (bctype >= bc_injection .AND. bctype <= bc_injection + bc_range) .OR. &
         (bctype >= bc_inflow    .AND. bctype <= bc_inflow    + bc_range)      ) THEN 

!-------------------------------------------------------------------------------
!     Loop over face patches
!-------------------------------------------------------------------------------

      DO ifc = 1, ppatch%nBFaces
        itile = ifc
        c1 = bf2c(ifc)

        nx = fn(xcoord,ifc)
        ny = fn(ycoord,ifc)
        nz = fn(zcoord,ifc)
        nm = fn(xyzmag,ifc)

        i2dvals = distrib * ifc
        minj       = vals(bcdat_inject_mfrate,i2dvals)
        tinj       = vals(bcdat_inject_temp  ,i2dvals)

!-------------------------------------------------------------------------------
!       Compute mixture density on boundary 
!        Using a low-order projection based on cell value
!-------------------------------------------------------------------------------
        
        rhomixtbcond = cv(cv_mixt_dens,c1)

!-------------------------------------------------------------------------------
!       Update tile Rhs datastructure 
!-------------------------------------------------------------------------------

        ptileplag => ppatch%tilePlag
 
        prhs        => ptileplag%rhs
        pcvtilemass => ptileplag%cvTileMass

        SELECT CASE(bctype)

!-------------------------------------------------------------------------------
!        Injection 
!-------------------------------------------------------------------------------

         CASE(bc_injection) 
          massfluxsum = sum( minj * injcmassfluxratio(:) )
          heatcapsum  = dot_product( specheat, minj * injcmassfluxratio(:) )

          tiletemp    = tinj
          tilevelnrm  = injcvelratio * minj / rhomixtbcond
          area        = nm

          DO icont = 1, ncont
            icvmass = pcvtilemass(icont)
            prhs(icvmass,itile) = -area *minj *injcmassfluxratio(icont) 
          END DO ! iCont            
            
          prhs(cv_tile_momnrm,itile) = -area *massfluxsum *tilevelnrm
            
          prhs(cv_tile_ener  ,itile) = -area *                             &
                                    ( 0.5_rfreal*massfluxsum*tilevelnrm**2 &
                                    +            heatcapsum *tiletemp      )

!-------------------------------------------------------------------------------
!        Inflow based on velocity and temperature 
!-------------------------------------------------------------------------------

         CASE(bc_inflow_veltemp) 
          area        = nm

          massfluxsum = 0.0_rfreal
          heatcapsum  = 0.0_rfreal
          tilevelnrm  = 0.0_rfreal
          tiletemp    = 0.0_rfreal

          DO icont = 1, ncont
            rhoplag =  pregion%plagInput%dens(icont)
            massfluxsum = massfluxsum + injcmassfluxratio(icont) *rhoplag
            heatcapsum  = heatcapsum  + specheat(icont) *injcmassfluxratio(icont) *rhoplag 
          END DO ! iCont

! ==============================================================================
!         Set inverse of massFluxSum to avoid division by zero 
! ==============================================================================
  
          IF ( massfluxsum > massfluxlimit ) THEN
            massfluxsumr = 1.0_rfreal/massfluxsum
            heatcapsumr       = 1.0_rfreal/heatcapsum
          ELSE
            massfluxsumr = 1.0_rfreal
            heatcapsumr       = 1.0_rfreal
          END IF ! massFluxSum

          DO icont = 1, ncont
            icvmass = pcvtilemass(icont)
            rhoplag =  pregion%plagInput%dens(icont)

            massfluxratio =  injcmassfluxratio(icont) *rhoplag *massfluxsumr
            heatcapratio  =  injcmassfluxratio(icont) *rhoplag &
                          *  specheat(icont) *heatcapsumr

            tilevelnrm    = tilevelnrm +massfluxratio *injcmassfluxratio(icont)
            tiletemp      = tiletemp   +heatcapratio  *injctemp(icont)

            prhs(icvmass,itile) = -area * injcmassfluxratio(icont) *rhoplag
          END DO ! iCont

          prhs(cv_tile_momnrm,itile) = -area *massfluxsum *tilevelnrm

          prhs(cv_tile_ener  ,itile) = -area *                              &
                                     ( 0.5_rfreal*massfluxsum*tilevelnrm**2 &
                                     +            heatcapsum *tiletemp      )

!-------------------------------------------------------------------------------
!        Trap error for default 
!-------------------------------------------------------------------------------

         CASE default 
           CALL errorstop(global,err_reached_default,__line__)
        END SELECT ! bcType

      END DO ! ifc                                                        
    ENDIF    ! bcType 
  ENDDO      ! iPatch

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE plag_rflu_injctilecalcrhs

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_RFLU_InjcTileCalcRhs.F90,v $
! Revision 1.8  2008/12/06 08:44:35  mtcampbe
! Updated license.
!
! Revision 1.7  2008/11/19 22:17:48  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.6  2007/03/09 15:16:31  fnajjar
! Fixed bug for massFluxSum being zero and avoiding division by zero
!
! Revision 1.5  2006/09/18 20:35:30  fnajjar
! Activated tile datastructure for inflow bc and created proper particle bc
!
! Revision 1.4  2006/08/19 15:40:07  mparmar
! Renamed patch variables
!
! Revision 1.3  2006/04/07 15:19:24  haselbac
! Removed tabs
!
! Revision 1.2  2004/12/07 22:56:24  fnajjar
! Removed rhoVrel being obsolete
!
! Revision 1.1  2004/03/08 22:36:08  fnajjar
! Initial import of RFLU-specific injection routines
!
!******************************************************************************