PLAG_RFLU_InitSolutionScratch.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Initialize particle solution in a region from scratch.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: PLAG_RFLU_InitSolutionScratch.F90,v 1.16 2008/12/06 08:44:35 mtcampbe Exp $
!
! Copyright: (c) 2004-2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE plag_rflu_initsolutionscratch(pRegion)

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY: t_region
  USE modglobal, ONLY: t_global
  USE modparameters
   
  USE plag_modparameters    

  USE plag_rflu_modfindcells
  
  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: icont,ipcl
  INTEGER, POINTER, DIMENSION(:) :: pcvplagmass
  INTEGER, POINTER, DIMENSION(:,:) :: paiv
  REAL(RFREAL) :: heatcapsum,masssum,massratio,massfluxratiolimit, &
                  massfluxratiosum,massfluxratiosumr
  REAL(RFREAL), POINTER, DIMENSION(:)   :: pdens,pinjcmassfluxratio,pspcheat
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: parv, pcv
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = & 
    '$RCSfile: PLAG_RFLU_InitSolutionScratch.F90,v $ $Revision: 1.16 $'

  global => pregion%global

  CALL registerfunction(global,'PLAG_RFLU_InitSolutionScratch', &
                        'PLAG_RFLU_InitSolutionScratch.F90')
 
  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, &
                             'Initializing particle solution from scratch...'
  END IF ! global%verbLevel

! ******************************************************************************
! Set pointers and values
! ******************************************************************************

  pregion%plag%nextIdNumber = pregion%plag%nPcls
  
  pdens              => pregion%plagInput%dens
  pspcheat           => pregion%plagInput%spht
  pinjcmassfluxratio => pregion%plagInput%injcMassFluxRatio
  
  pcvplagmass => pregion%plag%cvPlagMass
  paiv        => pregion%plag%aiv
  parv        => pregion%plag%arv
  pcv         => pregion%plag%cv
  
  massfluxratiolimit = 1.0e-10_rfreal
  massfluxratiosum = sum(pinjcmassfluxratio)

! ==============================================================================
! Set inverse of massFluxRatioSum to avoid division by zero
! ==============================================================================
  
  IF ( massfluxratiosum > massfluxratiolimit ) THEN
    massfluxratiosumr = 1.0_rfreal/massfluxratiosum
  ELSE
    massfluxratiosumr = 1.0_rfreal
  END IF ! massFluxRatioSum 

! ******************************************************************************
! Define initial solution
! ******************************************************************************

  DO ipcl = 1,pregion%plag%nPcls
    pcv(cv_plag_xpos,ipcl) = pregion%plagInput%iniPosX(ipcl)
    pcv(cv_plag_ypos,ipcl) = pregion%plagInput%iniPosY(ipcl)
    pcv(cv_plag_zpos,ipcl) = pregion%plagInput%iniPosZ(ipcl)

    DO icont = 1,pregion%plagInput%nCont
      massratio = pinjcmassfluxratio(icont)*massfluxratiosumr
      pcv(pcvplagmass(icont),ipcl) = pdens(icont)*massratio*global%pi/ & 
        6.0_rfreal*pregion%plagInput%iniDiam(ipcl)**3
    END DO ! iCont

    heatcapsum = sum(pcv(pcvplagmass(:),ipcl)*pspcheat(:))
    masssum    = sum(pcv(pcvplagmass(:),ipcl)) 

    pcv(cv_plag_xmom,ipcl) = masssum*pregion%plagInput%iniVelX(ipcl)
    pcv(cv_plag_ymom,ipcl) = masssum*pregion%plagInput%iniVelY(ipcl)
    pcv(cv_plag_zmom,ipcl) = masssum*pregion%plagInput%iniVelZ(ipcl)
    pcv(cv_plag_ener,ipcl) = heatcapsum*pregion%plagInput%iniTemp(ipcl)
    
    parv(arv_plag_spload,ipcl) = pregion%plagInput%iniSpLoad(ipcl)
    paiv(aiv_plag_pidini,ipcl) = ipcl
    paiv(aiv_plag_icells,ipcl) = crazy_value_int ! Value used in initialization
    paiv(aiv_plag_regini,ipcl) = crazy_value_int     
  END DO ! iPcl

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name, &
          'Initializing particle solution from scratch done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE plag_rflu_initsolutionscratch

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_RFLU_InitSolutionScratch.F90,v $
! Revision 1.16  2008/12/06 08:44:35  mtcampbe
! Updated license.
!
! Revision 1.15  2008/11/19 22:17:47  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.14  2007/03/08 15:04:19  fnajjar
! Fixed bug for massFluxRatioSum being zero and avoiding division by zero
!
! Revision 1.13  2006/05/05 18:05:26  haselbac
! Added init of ICELLS and REGINI
!
! Revision 1.12  2005/04/27 14:57:58  fnajjar
! Included module call to PLAG_RFLU_ModFindCells
!
! Revision 1.11  2005/03/31 20:25:59  fnajjar
! Added initial particle velocities for scratch solution
!
! Revision 1.10  2005/03/11 02:27:29  haselbac
! Simplified locating particles
!
! Revision 1.9  2004/11/04 16:29:19  fnajjar
! Deleted nPcls definition
!
! Revision 1.8  2004/10/11 22:11:27  haselbac
! Bug fix and renamed procedures
!
! Revision 1.7  2004/10/10 17:05:54  fnajjar
! Cleanup of duplicate variables
!
! Revision 1.6  2004/10/09 21:22:07  haselbac
! Bug fix: Brute force approach also requires c2f data structure
!
! Revision 1.5  2004/10/08 22:10:30  haselbac
! Added brute-force search option for finding particle positions
!
! Revision 1.4  2004/08/20 23:28:46  fnajjar
! Aligned with Plag prep tool
!
! Revision 1.3  2004/03/15 21:08:48  haselbac
! Changed name of particle location routine
!
! Revision 1.2  2004/03/08 22:18:30  fnajjar
! Commented off section specific to CFVEL test case
!
! Revision 1.1  2004/02/26 21:00:47  haselbac
! Initial revision
!
! ******************************************************************************