PLAG_RFLU_InitSolutionRandom.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Initialize particle solution in a region from random state
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: PLAG_RFLU_InitSolutionRandom.F90,v 1.13 2008/12/06 08:44:35 mtcampbe Exp $
!
! Copyright: (c) 2004-2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE plag_rflu_initsolutionrandom(pRegion)

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY: t_region
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modparameters
  
  USE modrandom, ONLY: rand1uniform
  
  USE plag_modparameters    
     
  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: errorflag,icont,infloopcntr,ipcl,npcls
  INTEGER, POINTER, DIMENSION(:) :: pcvplagmass
  INTEGER, POINTER, DIMENSION(:,:) :: paiv
  REAL(RFREAL) :: delfrac,diamdel,diammax,diammin,diam,heatcapsum,massratio, &
                  massfluxratiosum,massfluxratiosumr,massfluxratiolimit, &
                  masssum,npclsfrac,rn,sploaddel,sploadmax,sploadmin,spload, &
                  tempdel,tempmax,tempmin,temp,udel,umax,umin,u,vdel,vmin, &
                  vmax,v,wdel,wmin,wmax,w,xdel,xloc,xmax,xmin,ydel,yloc,ymax, &
                  ymin,zdel,zloc,zmax,zmin
  REAL(RFREAL), POINTER, DIMENSION(:) :: pdens,pinjcmassfluxratio,pspcheat
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: parv,pcv
  TYPE(t_global), POINTER :: global
  TYPE(t_grid),   POINTER :: pgrid

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = & 
    '$RCSfile: PLAG_RFLU_InitSolutionRandom.F90,v $ $Revision: 1.13 $'

  global => pregion%global

  CALL registerfunction(global,'PLAG_RFLU_InitSolutionRandom', &
                        'PLAG_RFLU_InitSolutionRandom.F90')
 
  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name, &
                          'Initializing particle solution from random state...'
  END IF ! global%verbLevel
  
! ******************************************************************************
! Set pointers and values
! ******************************************************************************

  pgrid => pregion%grid

  delfrac = 0.01_rfreal
  
  pregion%plag%nextIdNumber = pregion%plag%nPcls
  
  npcls       = pregion%plag%nPcls
  npclsfrac   = 0.1_rfreal    
  ipcl        = 0
  infloopcntr = 0 
  
  massfluxratiolimit = 1.0e-10_rfreal

! ******************************************************************************  
! Build bounding box. NOTE not from grid, but from user input
! ******************************************************************************

  xmin = pregion%plagInput%iniRandXMin
  xmax = pregion%plagInput%iniRandXMax
  ymin = pregion%plagInput%iniRandYMin
  ymax = pregion%plagInput%iniRandYMax
  zmin = pregion%plagInput%iniRandZMin
  zmax = pregion%plagInput%iniRandZMax

  xdel = xmax - xmin 
  ydel = ymax - ymin
  zdel = zmax - zmin

! ******************************************************************************
! Set pointers and values for PLAG infrastructure
! ******************************************************************************

  pdens    => pregion%plagInput%dens
  pspcheat => pregion%plagInput%spht
  pinjcmassfluxratio => pregion%plagInput%injcMassFluxRatio
  
  pcvplagmass => pregion%plag%cvPlagMass
  paiv => pregion%plag%aiv
  parv => pregion%plag%arv
  pcv  => pregion%plag%cv
  
  massfluxratiosum = sum(pinjcmassfluxratio)

! ==============================================================================  
! Set inverse of massFluxRatioSum to avoid division by zero 
! ==============================================================================  

  IF ( massfluxratiosum > massfluxratiolimit ) THEN 
    massfluxratiosumr = 1.0_rfreal/massfluxratiosum
  ELSE
    massfluxratiosumr = 1.0_rfreal
  END IF ! massFluxRatioSum 

  diammin   = pregion%plagInput%iniRandDiamMin
  diammax   = pregion%plagInput%iniRandDiamMax
  tempmin   = pregion%plagInput%iniRandTempMin
  tempmax   = pregion%plagInput%iniRandTempMax 
  sploadmin = pregion%plagInput%iniRandSpLoadMin
  sploadmax = pregion%plagInput%iniRandSpLoadMax

  umin      = pregion%plagInput%iniRandUMin
  umax      = pregion%plagInput%iniRandUMax
  vmin      = pregion%plagInput%iniRandVMin
  vmax      = pregion%plagInput%iniRandVMax
  wmin      = pregion%plagInput%iniRandWMin
  wmax      = pregion%plagInput%iniRandWMax
  
  diamdel   = diammax   - diammin
  tempdel   = tempmax   - tempmin
  sploaddel = sploadmax - sploadmin

  udel      = umax      - umin
  vdel      = vmax      - vmin
  wdel      = wmax      - wmin

! ******************************************************************************
! Define initial solution through an infinite loop. Exit loop once nPcls is 
! reached
! ******************************************************************************

  infloop: DO 
    infloopcntr = infloopcntr + 1

    IF ( ipcl == npcls ) THEN 
      EXIT infloop
    END IF ! iPcl
   
    ipcl = ipcl + 1

! ==============================================================================  
!   Set random particle data
! ==============================================================================  
     
    rn   = rand1uniform(pregion%randData) 
    xloc = xmin + xdel*rn

    rn   = rand1uniform(pregion%randData) 
    yloc = ymin + ydel*rn

    rn   = rand1uniform(pregion%randData) 
    zloc = zmin + zdel*rn

! TEMPORARY
!   Allows to create a cylindrical-configuration
!
!    IF ( yLoc*yLoc + zLoc*zLoc > 0.250_RFREAL ) THEN 
!      iPcl = iPcl - 1
!      infLoopCntr = infLoopCntr - 1
!      
!      CYCLE
!     END IF ! yLoc
! END TEMPORARY

    rn     = rand1uniform(pregion%randData) 
    diam   = diammin + diamdel*rn

    rn     = rand1uniform(pregion%randData) 
    temp   = tempmin  + tempdel*rn

    rn     = rand1uniform(pregion%randData) 
    spload = sploadmin + sploaddel*rn

    rn     = rand1uniform(pregion%randData) 
    u      = umin + udel*rn

    rn     = rand1uniform(pregion%randData) 
    v      = vmin + vdel*rn

    rn     = rand1uniform(pregion%randData) 
    w      = wmin + wdel*rn

! ==============================================================================  
!   Store data
! ==============================================================================

    pcv(cv_plag_xpos,ipcl) = xloc
    pcv(cv_plag_ypos,ipcl) = yloc
    pcv(cv_plag_zpos,ipcl) = zloc

    DO icont = 1,pregion%plagInput%nCont
      massratio = pinjcmassfluxratio(icont)*massfluxratiosumr
      pcv(pcvplagmass(icont),ipcl) = pdens(icont)*massratio*global%pi/6.0_rfreal &
                                   * diam**3
    END DO ! iCont

    heatcapsum = sum(pcv(pcvplagmass(:),ipcl)*pspcheat(:))
    masssum    = sum(pcv(pcvplagmass(:),ipcl))
    
    pcv(cv_plag_xmom,ipcl) = masssum*u
    pcv(cv_plag_ymom,ipcl) = masssum*v 
    pcv(cv_plag_zmom,ipcl) = masssum*w 
    pcv(cv_plag_ener,ipcl) = heatcapsum*temp
    
    parv(arv_plag_spload,ipcl) = spload
    paiv(aiv_plag_pidini,ipcl) = ipcl   
    paiv(aiv_plag_icells,ipcl) = crazy_value_int ! Value used in initialization
    paiv(aiv_plag_regini,ipcl) = crazy_value_int ! Value used in initialization

! ==============================================================================  
!   Write some info
! ==============================================================================  

    IF ( ipcl/REAL(nPcls,KIND=RFREAL) > npclsfrac ) then 
      npclsfrac = npclsfrac + 0.1_rfreal 

      IF ( global%verbLevel > verbose_low ) THEN 
        WRITE(stdout,'(A,3X,A,1X,I10,1X,A)') solver_name,'Generated',ipcl, & 
                                             'particles.'
      END IF ! global%verbLevel 
    END IF ! iPcl

! ------------------------------------------------------------------------------
!   Check for infinite loop
! ------------------------------------------------------------------------------        

    IF ( infloopcntr >= 100*npcls ) THEN 
      CALL errorstop(global,err_infinite_loop,__line__)
    END IF ! infLoopCntr
  END DO infloop

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name, &
          'Initializing particle solution from random state done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE plag_rflu_initsolutionrandom

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_RFLU_InitSolutionRandom.F90,v $
! Revision 1.13  2008/12/06 08:44:35  mtcampbe
! Updated license.
!
! Revision 1.12  2008/11/19 22:17:47  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.11  2007/03/27 00:22:31  haselbac
! Some simplifications
!
! Revision 1.10  2007/03/08 15:04:19  fnajjar
! Fixed bug for massFluxRatioSum being zero and avoiding division by zero
!
! Revision 1.9  2006/10/26 15:00:14  fnajjar
! Added computation of particle momentum based on random velocity field
!
! Revision 1.8  2006/09/18 20:34:26  fnajjar
! Increased FORMAT output to I10 for particle size
!
! Revision 1.7  2006/05/05 18:39:46  haselbac
! Changed logic so serial grid no longer needed
!
! Revision 1.4  2004/11/04 16:29:09  fnajjar
! Deleted call to PLAG_SetMaxDimensions and nPcls definition
!
! Revision 1.3  2004/10/11 22:10:54  haselbac
! Bug fix and cosmetics
!
! Revision 1.2  2004/10/11 19:38:48  fnajjar
! Renamed ininPlag to nPclsIni to follow naming convention
!
! Revision 1.1  2004/10/10 20:06:35  fnajjar
! Initial import
!
! ******************************************************************************