PLAG_RFLU_InitSolSerial_3D.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Initialize particle solution in serial region in 3d.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to serial region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: PLAG_RFLU_InitSolSerial_3D.F90,v 1.3 2008/12/06 08:44:35 mtcampbe Exp $
!
! Copyright: (c) 2005-2007 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE plag_rflu_initsolserial_3d(pRegion)

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY: t_region
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modpartlag, ONLY: t_plag
  USE modparameters

  USE rflu_modfacelist, ONLY: rflu_createcell2facelist, & 
                              rflu_buildcell2facelist, & 
                              rflu_destroycell2facelist    
  USE rflu_modincelltest, ONLY: rflu_ict_testincell
  USE rflu_modoctree

  USE plag_modparameters    
  
  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: ccsize,errorflag,icg,icl,ipcl,ivar
  INTEGER, DIMENSION(:), ALLOCATABLE :: cc
  REAL(RFREAL) :: delfrac,xdel,xmax,xmin,xpcl,ydel,ymax,ymin,ypcl,zdel,zmax, &
                  zmin,zpcl
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_plag), POINTER :: pplag

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = & 
    '$RCSfile: PLAG_RFLU_InitSolSerial_3D.F90,v $ $Revision: 1.3 $'

  global => pregion%global

  CALL registerfunction(global,'PLAG_RFLU_InitSolSerial_3D', &
                        'PLAG_RFLU_InitSolSerial_3D.F90')
 
  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Initializing particle solution '// &
                             'for serial region in 3d...'
    WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', &
                                     pregion%iRegionGlobal
  END IF ! global%verbLevel

! ******************************************************************************
! Set pointers and values
! ******************************************************************************
  
  pgrid => pregion%grid
  
  pplag => pregion%plag  
    
  ccsize = min(100,pgrid%nCells) ! Must be larger than unity 

  delfrac = 0.01_rfreal

! ******************************************************************************
! Get (slightly enlarged) grid bounding box
! ******************************************************************************

  xmin = minval(pgrid%xyz(xcoord,1:pgrid%nVert))
  xmax = maxval(pgrid%xyz(xcoord,1:pgrid%nVert))
  ymin = minval(pgrid%xyz(ycoord,1:pgrid%nVert))
  ymax = maxval(pgrid%xyz(ycoord,1:pgrid%nVert))
  zmin = minval(pgrid%xyz(zcoord,1:pgrid%nVert))
  zmax = maxval(pgrid%xyz(zcoord,1:pgrid%nVert))

  xdel = xmax - xmin
  ydel = ymax - ymin
  zdel = zmax - zmin    

  xmin = xmin - delfrac*xdel
  xmax = xmax + delfrac*xdel
  ymin = ymin - delfrac*ydel
  ymax = ymax + delfrac*ydel
  zmin = zmin - delfrac*zdel
  zmax = zmax + delfrac*zdel    
       
! ******************************************************************************
! Build Octree and cell-to-face list
! ******************************************************************************

  CALL rflu_createoctree(global,pgrid%nCells)

  CALL rflu_buildoctree(pgrid%cofg(xcoord,1:pgrid%nCells), & 
                        pgrid%cofg(ycoord,1:pgrid%nCells), & 
                        pgrid%cofg(zcoord,1:pgrid%nCells), & 
                        xmin,xmax,ymin,ymax,zmin,zmax)

  ALLOCATE(cc(ccsize),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'cc')
  END IF ! global%error  

  CALL rflu_createcell2facelist(pregion)
  CALL rflu_buildcell2facelist(pregion)

! ******************************************************************************
! Loop over particles in serial region
! ******************************************************************************

  DO ipcl = 1,pplag%nPcls    

! ==============================================================================
!   Get particle location and get nearest cells from Octree
! ==============================================================================

    xpcl = pplag%cv(cv_plag_xpos,ipcl)
    ypcl = pplag%cv(cv_plag_ypos,ipcl)
    zpcl = pplag%cv(cv_plag_zpos,ipcl)

    CALL rflu_queryoctree(xpcl,ypcl,zpcl,ccsize,cc)

! ==============================================================================
!   Perform in-cell test on cells
! ==============================================================================

    cellloop: DO icl = 1,ccsize   
      icg = cc(icl)

      IF ( rflu_ict_testincell(pregion,xpcl,ypcl,zpcl,icg) .EQV. .true. ) THEN
        pplag%aiv(aiv_plag_icells,ipcl) = icg
        pplag%aiv(aiv_plag_regini,ipcl) = pregion%iRegionGlobal                         

        EXIT cellloop
      END IF ! RFLU_ICT_TestInCell
    END DO cellloop
  END DO ! iPclSerial
    
! ******************************************************************************
! Destroy Octree and cell-to-face list
! ******************************************************************************

  CALL rflu_destroyoctree(global)  

  DEALLOCATE(cc,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'cc')
  END IF ! global%error   

  CALL rflu_destroycell2facelist(pregion)        

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name, &
          'Initializing particle solution for serial region in 3d done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE plag_rflu_initsolserial_3d

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_RFLU_InitSolSerial_3D.F90,v $
! Revision 1.3  2008/12/06 08:44:35  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:47  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2007/03/15 21:58:29  haselbac
! Initial revision
!
! Revision 1.4  2007/03/09 20:32:37  fnajjar
! Fixed incorrect registration name
!
! Revision 1.3  2006/05/22 15:33:09  fnajjar
! Fixed bug for uninitialized delFrac
!
! Revision 1.2  2006/05/05 18:41:10  haselbac
! Fix from last ci
!
! Revision 1.1  2006/05/05 17:27:57  haselbac
! Initial revision
!
! ******************************************************************************