PLAG_RFLU_InitSolSerial_1D.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Initialize particle solution in serial region for 1d cases.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to serial region
!
! Output: None.
!
! Notes: 
!   1. Assume grid spacing is constant!
!   2. Assume cells are numbered in ascending order in direction of increasing
!      x-coordinate.
!
! ******************************************************************************
!
! $Id: PLAG_RFLU_InitSolSerial_1D.F90,v 1.4 2008/12/06 08:44:35 mtcampbe Exp $
!
! Copyright: (c) 2007 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE plag_rflu_initsolserial_1d(pRegion)

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY: t_region
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modpartlag, ONLY: t_plag
  USE modparameters

  USE rflu_modfacelist, ONLY: rflu_createcell2facelist, & 
                              rflu_buildcell2facelist, & 
                              rflu_destroycell2facelist    
  USE rflu_modincelltest, ONLY: rflu_ict_testincell

  USE plag_modparameters    
  
  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  LOGICAL :: foundflag
  CHARACTER(CHRLEN) :: errorstring,rcsidentstring
  INTEGER :: dicg,dicgdel,dicgmax,dicgmin,errorflag,icg,icg2,ipcl
  REAL(RFREAL) :: idx,xmax,xmin,xpcl,ypcl,zpcl
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_plag), POINTER :: pplag

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = & 
    '$RCSfile: PLAG_RFLU_InitSolSerial_1D.F90,v $ $Revision: 1.4 $'

  global => pregion%global

  CALL registerfunction(global,'PLAG_RFLU_InitSolSerial_1D', &
                        'PLAG_RFLU_InitSolSerial_1D.F90')
 
  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Initializing particle solution '// & 
                             'for serial region in 1d...'
    WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', &
                                     pregion%iRegionGlobal
  END IF ! global%verbLevel

! ******************************************************************************
! Set pointers and values
! ******************************************************************************
  
  pgrid => pregion%grid
  pplag => pregion%plag  

! ******************************************************************************
! Compute grid spacing
! ******************************************************************************

  xmin = minval(pgrid%xyz(xcoord,1:pgrid%nVert))
  xmax = maxval(pgrid%xyz(xcoord,1:pgrid%nVert))
  idx  = pgrid%nCells/(xmax-xmin)
       
! ******************************************************************************
! Build cell-to-face list (needed for in-cell test)
! ******************************************************************************

  CALL rflu_createcell2facelist(pregion)
  CALL rflu_buildcell2facelist(pregion)

! ******************************************************************************
! Loop over particles in serial region
! ******************************************************************************

  DO ipcl = 1,pplag%nPcls    

! ==============================================================================
!   Get particle location and determine cell which should contain this particle
! ==============================================================================

    xpcl = pplag%cv(cv_plag_xpos,ipcl)
    ypcl = pplag%cv(cv_plag_ypos,ipcl)
    zpcl = pplag%cv(cv_plag_zpos,ipcl)

    icg = int(1.0_rfreal + idx*(xpcl-xmin))

! ==============================================================================
!   Carry out in-cell test
! ==============================================================================

    IF ( rflu_ict_testincell(pregion,xpcl,ypcl,zpcl,icg) .EQV. .true. ) THEN
      pplag%aiv(aiv_plag_icells,ipcl) = icg
      pplag%aiv(aiv_plag_regini,ipcl) = pregion%iRegionGlobal

! ==============================================================================
!   If the in-cell test failed, then the only reason should be that particle is
!   located right on a face and may be regarded as being in adjacent cell due 
!   to machine precision issues, so check those cells, too.
! ==============================================================================

    ELSE 
      IF ( icg == 1 ) THEN 
        dicgmin = 1
        dicgmax = 1
        dicgdel = 1 
      ELSE IF ( icg == pgrid%nCells ) THEN 
        dicgmin = -1
        dicgmax = -1
        dicgdel =  1 
      ELSE 
        dicgmin = -1
        dicgmax =  1
        dicgdel =  2 
      END IF ! icg 

      foundflag = .false.

      DO dicg = dicgmin,dicgmax,dicgdel
        icg2 = icg + dicg

        IF ( rflu_ict_testincell(pregion,xpcl,ypcl,zpcl,icg2) .EQV. .true. ) THEN
          pplag%aiv(aiv_plag_icells,ipcl) = icg2
          pplag%aiv(aiv_plag_regini,ipcl) = pregion%iRegionGlobal

          foundflag = .true.
        END IF ! RFLU_ICT_TestInCell
      END DO ! dIcg

! ------------------------------------------------------------------------------
!     If that check fails, too, then there must be an error
! ------------------------------------------------------------------------------

      IF ( foundflag .EQV. .false. ) THEN 
        WRITE(errorstring,'(I6)') ipcl
        CALL errorstop(global,err_plag_pcl_not_found,__line__,trim(errorstring))
      END IF ! foundFlag 
    END IF ! RFLU_ICT_TestInCell
  END DO ! iPcl
    
! ******************************************************************************
! Destroy cell-to-face list
! ******************************************************************************

  CALL rflu_destroycell2facelist(pregion)        

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name, &
          'Initializing particle solution for serial region in 1d done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE plag_rflu_initsolserial_1d

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_RFLU_InitSolSerial_1D.F90,v $
! Revision 1.4  2008/12/06 08:44:35  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:47  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2007/03/27 00:22:01  haselbac
! Fixed indentation
!
! Revision 1.1  2007/03/15 21:58:29  haselbac
! Initial revision
!
! ******************************************************************************