PLAG_RFLU_CorrectMixtProperties.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Correct the mixture properties using higher-order
!          interpolation schemed onto particle locations
!
! Description: none.
!
! Input: pRegion = current region.
!
! Output: region%levels%plag%dv 
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PLAG_RFLU_CorrectMixtProperties.F90,v 1.4 2008/12/06 08:44:35 mtcampbe Exp $
!
! Copyright: (c) 2005 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_rflu_correctmixtproperties(pRegion)

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modgrid, ONLY: t_grid
  USE modpartlag, ONLY    : t_plag, t_plag_input
  USE modmixture, ONLY    : t_mixt
  USE moderror  
  USE modparameters
  USE plag_modparameters

  USE modinterfaces, ONLY: mixtperf_r_m, & 
                           mixtperf_t_dpr

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  TYPE(t_region), POINTER :: pregion

! ==============================================================================  
! Locals
! ==============================================================================  

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: icg,indmol,intrplmixtmodel,ipcl,npcls
  INTEGER, POINTER, DIMENSION(:,:)    :: paiv
  
  REAL(RFREAL) :: dx,dy,dz,gc,mm,p,r
  REAL(RFREAL), POINTER, DIMENSION(:,:)    :: pcv,pdv,pdvmixt,pgvmixt
  REAL(RFREAL), POINTER, DIMENSION(:,:,:) :: pgrad
  
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_plag),   POINTER :: pplag 
  TYPE(t_mixt),   POINTER :: pmixt 
 
! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_RFLU_CorrectMixtProperties.F90,v $ $Revision: 1.4 $'

  global => pregion%global
  
  CALL registerfunction( global, 'PLAG_RFLU_CorrectMixtProperties',&
  'PLAG_RFLU_CorrectMixtProperties.F90' )

! ******************************************************************************
! Set variables and pointers
! ******************************************************************************

  pmixt => pregion%mixt 
  pgrid => pregion%grid
  pplag => pregion%plag

  pdvmixt => pmixt%dv
  pgvmixt => pmixt%gv

  npcls  = pregion%plag%nPcls
  indmol = pregion%mixtInput%indMol

  intrplmixtmodel = pregion%plagInput%intrplMixtModel

! ******************************************************************************
! Set pointers for mixture 
! ******************************************************************************

  pdvmixt => pmixt%dv
  pgvmixt => pmixt%gv

  pgrad => pregion%mixt%gradCell

! ******************************************************************************
! Set pointers for discrete particles 
! ******************************************************************************

  paiv    => pplag%aiv
  pcv     => pplag%cv  
  pdv     => pplag%dv

! ******************************************************************************
! Check that have primitive state vector
! ******************************************************************************

  IF ( pmixt%cvState /= cv_mixt_state_duvwp ) THEN 
    CALL errorstop(global,err_cv_state_invalid,__line__)
  END IF ! pMixt%cvState

! ******************************************************************************
! Trap error for inconsistent input deck
! ******************************************************************************

  IF ( intrplmixtmodel /= zeroth_order .AND. &
       pregion%mixtInput%spaceOrder == 1     ) THEN 
    CALL errorstop(global,err_plag_intrplmodel,__line__)
  END IF ! intrplMixtModel

! ******************************************************************************        
! Correct discrete particle dv
! ******************************************************************************
    
  SELECT CASE ( intrplmixtmodel )    
    CASE ( zeroth_order )
    CASE ( first_order  )        
      DO ipcl = 1, npcls
        icg = paiv(aiv_plag_icells,ipcl)

        dx = pcv(cv_plag_xpos,ipcl) - pgrid%cofg(xcoord,icg)
        dy = pcv(cv_plag_ypos,ipcl) - pgrid%cofg(ycoord,icg)
        dz = pcv(cv_plag_zpos,ipcl) - pgrid%cofg(zcoord,icg)                

        pdv(dv_plag_uvelmixt,ipcl) = pdv(dv_plag_uvelmixt,ipcl) & 
                                   + pgrad(xcoord,grc_mixt_xvel,icg)*dx &
                                   + pgrad(ycoord,grc_mixt_xvel,icg)*dy &
                                   + pgrad(zcoord,grc_mixt_xvel,icg)*dz
        pdv(dv_plag_vvelmixt,ipcl) = pdv(dv_plag_vvelmixt,ipcl) & 
                                   + pgrad(xcoord,grc_mixt_yvel,icg)*dx &
                                   + pgrad(ycoord,grc_mixt_yvel,icg)*dy &
                                   + pgrad(zcoord,grc_mixt_yvel,icg)*dz
        pdv(dv_plag_wvelmixt,ipcl) = pdv(dv_plag_wvelmixt,ipcl) & 
                                   + pgrad(xcoord,grc_mixt_zvel,icg)*dx &
                                   + pgrad(ycoord,grc_mixt_zvel,icg)*dy &
                                   + pgrad(zcoord,grc_mixt_zvel,icg)*dz
        pdv(dv_plag_presmixt,ipcl) = pdv(dv_plag_presmixt,ipcl) & 
                                   + pgrad(xcoord,grc_mixt_pres,icg)*dx &
                                   + pgrad(ycoord,grc_mixt_pres,icg)*dy &
                                   + pgrad(zcoord,grc_mixt_pres,icg)*dz
        pdv(dv_plag_densmixt,ipcl) = pdv(dv_plag_densmixt,ipcl) & 
                                   + pgrad(xcoord,grc_mixt_dens,icg)*dx &
                                   + pgrad(ycoord,grc_mixt_dens,icg)*dy &
                                   + pgrad(zcoord,grc_mixt_dens,icg)*dz 
      END DO ! iPcl
      
      SELECT CASE ( pregion%mixtInput%gasModel ) 
        CASE ( gas_model_tcperf,gas_model_mixt_tcperf )
          DO ipcl = 1,npcls      
            icg = paiv(aiv_plag_icells,ipcl)
          
            mm = pgvmixt(gv_mixt_mol,indmol*icg)
            gc = mixtperf_r_m(mm)
                  
            r = pdv(dv_plag_densmixt,ipcl)
            p = pdv(dv_plag_presmixt,ipcl)        
                  
            pdv(dv_plag_tempmixt,ipcl) = mixtperf_t_dpr(r,p,gc)
          END DO ! iPcl
        CASE default
          CALL errorstop( global,err_reached_default,__line__ )
      END SELECT ! pRegion%mixtInput%gasModel
      
    CASE ( second_order )
      CALL errorstop( global,err_reached_default,__line__ )
    CASE default
      CALL errorstop( global,err_reached_default,__line__ )     
  END SELECT  ! intrplMixtModel

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction( global )

END SUBROUTINE plag_rflu_correctmixtproperties

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_RFLU_CorrectMixtProperties.F90,v $
! Revision 1.4  2008/12/06 08:44:35  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:47  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:24  haselbac
! Removed tabs
!
! Revision 1.1  2005/11/30 22:26:54  fnajjar
! Initial version
!
!******************************************************************************