PLAG_ModDataStruct.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Suite of routines for manipulation of particle data structure.
!
! Description: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: PLAG_ModDataStruct.F90,v 1.5 2008/12/06 08:44:34 mtcampbe Exp $
!
! Copyright: (c) 2007 by the University of Illinois
!
! ******************************************************************************

MODULE plag_moddatastruct
  
  USE modglobal, ONLY: t_global
  USE modparameters
  USE moddatatypes
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modpartlag, ONLY: t_plag
  USE moddatastruct, ONLY: t_region
  USE moderror
  USE modmpi

  USE plag_modparameters

  IMPLICIT NONE

  PRIVATE
  PUBLIC :: plag_dstr_buildcell2pcllist, &
            plag_dstr_copyparticlewrapper, & 
            plag_dstr_createpcllistcsr, &
            plag_dstr_destroycell2pcllist, &
            plag_dstr_destroypcllistcsr, &
            plag_dstr_mergeparticlewrapper
        
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  
   
  CHARACTER(CHRLEN) :: RCSIdentString = & 
    '$RCSfile: PLAG_ModDataStruct.F90,v $ $Revision: 1.5 $'        
       
! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS







! ******************************************************************************
!
! Purpose: Build cell-to-particle list in CSR format.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: 
!   1. This routine builds the list of cells which have non-zero particles 
!      and the list of particles in CSR format as well as an access array for
!      the CSR list. 
!   2. In this routine, only memory for the list of cells and the access array
!      is allocated, NOT for the CSR list itself (see next note).
!   3. The actual CSR list is expected to have been created before this 
!      routine is called.
!
! ******************************************************************************

SUBROUTINE plag_dstr_buildcell2pcllist(pRegion)

  USE modsortsearch

  IMPLICIT NONE

! ******************************************************************************
! Declarations
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  TYPE(t_region), POINTER :: pregion
  
! ==============================================================================  
! Locals
! ==============================================================================  

  INTEGER :: errorflag,icg,icsr,iloc,ipcl
  INTEGER, DIMENSION(:), POINTER :: npclspercell
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_plag), POINTER :: pplag

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'PLAG_DSTR_BuildCell2PclList',&
  'PLAG_ModDataStruct.F90')

  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Building cell-to-particle list...'
    WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', &
                                     pregion%iRegionGlobal
  END IF ! global%verbLevel

! ******************************************************************************
! Set pointers and values
! ******************************************************************************

  pgrid => pregion%grid
  pplag => pregion%plag

  pplag%nCellsNzPcl    = 0 
  pplag%nCellsNzPclMax = min(1000,pgrid%nCells) ! Initial guess
  
! ******************************************************************************
! Build list of cells with non-zero particles and CSR info array which will be
! used to access actual CSR data structure
! ******************************************************************************

  CALL plag_dstr_createcell2pcllist(pregion)
  
  DO ipcl = 1,pplag%nPcls
    icg = pplag%aiv(aiv_plag_icells,ipcl)
  
    IF ( pplag%nCellsNzPcl > 0 ) THEN 
      CALL binarysearchinteger(pplag%icgNzPcl(1:pplag%nCellsNzPcl), & 
                               pplag%nCellsNzPcl,icg,iloc)

      IF ( iloc == element_not_found ) THEN
        IF ( pplag%nCellsNzPcl == pplag%nCellsNzPclMax ) THEN 
          CALL plag_dstr_recreatecell2pcllist(pregion)
        END IF ! pPlag%nCellsNzPcl
       
        pplag%nCellsNzPcl = pplag%nCellsNzPcl + 1
        pplag%icgNzPcl(pplag%nCellsNzPcl) = icg
        pplag%iPclPerCellCSRInfo(pplag%nCellsNzPcl) = 1
        
        CALL quicksortintegerinteger(pplag%icgNzPcl(1:pplag%nCellsNzPcl), &
             pplag%iPclPerCellCSRInfo(1:pplag%nCellsNzPcl),pplag%nCellsNzPcl)
      ELSE 
        pplag%iPclPerCellCSRInfo(iloc) = pplag%iPclPerCellCSRInfo(iloc) + 1
      END IF ! iLoc                         
    ELSE 
      pplag%nCellsNzPcl = 1
      pplag%icgNzPcl(1) = icg
      pplag%iPclPerCellCSRInfo(1) = 1 
    END IF ! pGrid%nCellsNzPcl
  END DO ! iPcl

  IF ( global%verbLevel > verbose_low ) THEN 
    WRITE(stdout,'(A,3X,A,1X,I6)') solver_name,'Number of cells with '// &
                                   'non-zero particles:',pplag%nCellsNzPcl
  END IF ! global%verbLevel

! ******************************************************************************
! Build actual CSR data structure
! ******************************************************************************

! ==============================================================================
! Finalize CSR info array and check for consistency 
! ==============================================================================

  DO icg = 2,pplag%nCellsNzPcl
    pplag%iPclPerCellCSRInfo(icg) = pplag%iPclPerCellCSRInfo(icg) & 
                                  + pplag%iPclPerCellCSRInfo(icg-1)
  END DO ! icg
  
  IF ( pplag%iPclPerCellCSRInfo(pplag%nCellsNzPcl) /= pplag%nPcls ) THEN 
    CALL errorstop(global,err_plag_dstr_invalid,__line__)
  END IF ! pPlag%iPclPerCellCSRInfo

  ALLOCATE(npclspercell(pgrid%nCells),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'nPclsPerCell')
  END IF ! global%error

  DO icg = 1,pgrid%nCells
    npclspercell(icg) = 0
  END DO ! icg

  DO ipcl = 1,pplag%nPcls
    icg = pplag%aiv(aiv_plag_icells,ipcl)

    CALL binarysearchinteger(pplag%icgNzPcl(1:pplag%nCellsNzPcl), &
                             pplag%nCellsNzPcl,icg,iloc)
    
    IF ( iloc /= element_not_found ) THEN 
      npclspercell(icg) = npclspercell(icg) + 1
      
      IF ( iloc > 1 ) THEN 
        icsr = pplag%iPclPerCellCSRInfo(iloc-1) + 1
      ELSE 
        icsr = 1
      END IF ! iLoc

      icsr = icsr + npclspercell(icg) - 1
      
      IF ( icsr > pplag%nPcls ) THEN ! Defensive coding
        CALL errorstop(global,err_plag_dstr_invalid,__line__)
      END IF ! iCSR
      
      pplag%iPclPerCellCSR(icsr) = ipcl
    ELSE 
      CALL errorstop(global,err_plag_dstr_invalid,__line__)
    END IF ! iLoc
  END DO ! iPcl

  DEALLOCATE(npclspercell,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'nPclsPerCell')
  END IF ! global%error

! ******************************************************************************
! End
! ******************************************************************************
    
  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Building cell-to-particle list done.'
  END IF ! global%verbLevel
    
  CALL deregisterfunction(global)

END SUBROUTINE plag_dstr_buildcell2pcllist







! ******************************************************************************
!
! Purpose: Add particle to data structure.
!
! Description: None.
!
! Input: 
!  global       Pointer to global data
!  pPlag        Pointer to particle data structure (origin)
!  pPlag2       Pointer to particle data structure (target)
!  iPcl         Index of particle in data structure (origin)
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE plag_dstr_copyparticle(global,pPlag,pPlag2,iPcl)

  IMPLICIT NONE

! ******************************************************************************
! Declarations
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  INTEGER, INTENT(IN) ::ipcl
  TYPE(t_global), POINTER :: global
  TYPE(t_plag), POINTER :: pplag,pplag2
  
! ==============================================================================  
! Locals
! ==============================================================================  

  INTEGER :: ivar

! ******************************************************************************
! Start
! ******************************************************************************

  CALL registerfunction(global,'PLAG_DSTR_CopyParticle',&
  'PLAG_ModDataStruct.F90')

! ******************************************************************************
! Start, increment counter, and check dimensions
! ******************************************************************************

  pplag2%nPcls = pplag2%nPcls + 1
  
  IF ( pplag2%nPcls > pplag2%nPclsMax ) THEN 
    CALL errorstop(global,err_plag_memoverflow,__line__)
  END IF ! pPlag2%nPcls 

  IF ( (lbound(pplag2%cv,1) /= lbound(pplag%cv,1)) .OR. & 
       (ubound(pplag2%cv,1) /= ubound(pplag%cv,1)) ) THEN 
    CALL errorstop(global,err_lubound_mismatch,__line__)
  END IF ! LBOUND 
  
  IF ( (lbound(pplag2%arv,1) /= lbound(pplag%arv,1)) .OR. & 
       (ubound(pplag2%arv,1) /= ubound(pplag%arv,1)) ) THEN 
    CALL errorstop(global,err_lubound_mismatch,__line__)
  END IF ! LBOUND
  
  IF ( (lbound(pplag2%aiv,1) /= lbound(pplag%aiv,1)) .OR. & 
       (ubound(pplag2%aiv,1) /= ubound(pplag%aiv,1)) ) THEN 
    CALL errorstop(global,err_lubound_mismatch,__line__)
  END IF ! LBOUND    

! ******************************************************************************
! Copy data
! ******************************************************************************

  DO ivar = 1,pplag2%nCv
    pplag2%cv(ivar,pplag2%nPcls) = pplag%cv(ivar,ipcl)
  END DO ! iVar

  DO ivar = 1,pplag2%nArv
    pplag2%arv(ivar,pplag2%nPcls) = pplag%arv(ivar,ipcl)
  END DO ! iVar

  DO ivar = 1,pplag2%nAiv
    pplag2%aiv(ivar,pplag2%nPcls) = pplag%aiv(ivar,ipcl)
  END DO ! iVar
  
! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE plag_dstr_copyparticle








! ******************************************************************************
!
! Purpose: Wrapper for adding particles to data structure.
!
! Description: None.
!
! Input: 
!  global       Pointer to global data
!  pPlag        Pointer to particle data structure (origin)
!  pPlag2       Pointer to particle data structure (target)
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE plag_dstr_copyparticlewrapper(global,pPlag,pPlag2)

  IMPLICIT NONE

! ******************************************************************************
! Declarations
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  TYPE(t_global), POINTER :: global
  TYPE(t_plag), POINTER :: pplag,pplag2
  
! ==============================================================================  
! Locals
! ==============================================================================  

  INTEGER :: ipcl

! ******************************************************************************
! Start
! ******************************************************************************

  CALL registerfunction(global,'PLAG_DSTR_CopyParticleWrapper',&
  'PLAG_ModDataStruct.F90')

! ******************************************************************************
! Start
! ******************************************************************************

  DO ipcl = 1,pplag%nPcls
    CALL plag_dstr_copyparticle(global,pplag,pplag2,ipcl)
  END DO ! iPcl
  
! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE plag_dstr_copyparticlewrapper







! ******************************************************************************
!
! Purpose: Allocate memory for cell-to-particle list.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE plag_dstr_createcell2pcllist(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Declarations
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  TYPE(t_region), POINTER :: pregion
  
! ==============================================================================  
! Locals
! ==============================================================================  

  INTEGER :: errorflag,icg
  TYPE(t_global), POINTER :: global
  TYPE(t_plag), POINTER :: pplag

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'PLAG_DSTR_CreateCell2PclList',&
  'PLAG_ModDataStruct.F90')

! ******************************************************************************
! Allocate memory
! ******************************************************************************

  pplag => pregion%plag

  ALLOCATE(pplag%icgNzPcl(pplag%nCellsNzPclMax),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'pPlag%icgNzPcl')
  END IF ! global%error
  
  ALLOCATE(pplag%iPclPerCellCSRInfo(pplag%nCellsNzPclMax),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'pPlag%iPclPerCellCSRInfo')
  END IF ! global%error  
  
  DO icg = 1,pplag%nCellsNzPclMax
    pplag%iPclPerCellCSRInfo(icg) = 0
  END DO ! icg
  
! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE plag_dstr_createcell2pcllist







! ******************************************************************************
!
! Purpose: Allocate memory for cell-to-particle list in CSR format.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE plag_dstr_createpcllistcsr(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Declarations
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  TYPE(t_region), POINTER :: pregion
  
! ==============================================================================  
! Locals
! ==============================================================================  

  INTEGER :: errorflag
  TYPE(t_global), POINTER :: global
  TYPE(t_plag), POINTER :: pplag

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'PLAG_DSTR_CreatePclListCSR',&
  'PLAG_ModDataStruct.F90')

! ******************************************************************************
! Allocate memory
! ******************************************************************************
  
  pplag => pregion%plag
  
  IF ( pplag%nPcls > 0 ) THEN 
    ALLOCATE(pplag%iPclPerCellCSR(pplag%nPcls),stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_allocate,__line__,'pPlag%iPclPerCellCSR')
    END IF ! global%error  
  END IF ! pPlag%nPcls

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE plag_dstr_createpcllistcsr






! ******************************************************************************
!
! Purpose: Deallocate memory for cell-to-particle list.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE plag_dstr_destroycell2pcllist(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Declarations
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  TYPE(t_region), POINTER :: pregion
  
! ==============================================================================  
! Locals
! ==============================================================================  

  INTEGER :: errorflag
  TYPE(t_global), POINTER :: global
  TYPE(t_plag), POINTER :: pplag

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'PLAG_DSTR_DestroyCell2PclList',&
  'PLAG_ModDataStruct.F90')

! ******************************************************************************
! Deallocate memory
! ******************************************************************************

  pplag => pregion%plag

  DEALLOCATE(pplag%icgNzPcl,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'pPlag%icgNzPcl')
  END IF ! global%error
  
  DEALLOCATE(pplag%iPclPerCellCSRInfo,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'pPlag%iPclPerCellCSRInfo')
  END IF ! global%error  
  
! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE plag_dstr_destroycell2pcllist






! ******************************************************************************
!
! Purpose: Deallocate memory for cell-to-particle list in CSR format.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE plag_dstr_destroypcllistcsr(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Declarations
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  TYPE(t_region), POINTER :: pregion
  
! ==============================================================================  
! Locals
! ==============================================================================  

  INTEGER :: errorflag
  TYPE(t_global), POINTER :: global
  TYPE(t_plag), POINTER :: pplag

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'PLAG_DSTR_DestroyPclListCSR',&
  'PLAG_ModDataStruct.F90')

! ******************************************************************************
! Allocate memory
! ******************************************************************************
  
  pplag => pregion%plag
  
  IF ( ASSOCIATED(pplag%iPclPerCellCSR) .EQV. .true. ) THEN 
    DEALLOCATE(pplag%iPclPerCellCSR,stat=errorflag)
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_deallocate,__line__,'pPlag%iPclPerCellCSR')
    END IF ! global%error  
  END IF ! ASSOCIATED

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE plag_dstr_destroypcllistcsr






! ******************************************************************************
!
! Purpose: Wrapper for merging particle data structures.
!
! Description: None.
!
! Input: 
!  global       Pointer to global data
!  pGrid        Pointer to grid data structure
!  pPlag        Pointer to particle data structure (origin)
!  pPlag2       Pointer to particle data structure (target)
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE plag_dstr_mergeparticlewrapper(pRegion,pPlag,pPlag2)

  IMPLICIT NONE

! ******************************************************************************
! Declarations
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  TYPE(t_plag), POINTER :: pplag,pplag2
  TYPE(t_region), POINTER :: pregion
  
! ==============================================================================  
! Locals
! ==============================================================================  

  INTEGER :: icg,icg2,ipcl,npclsnew,npclsold
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'PLAG_DSTR_MergeParticleWrapper',&
  'PLAG_ModDataStruct.F90')

! ******************************************************************************
! Set pointers
! ******************************************************************************

  pgrid => pregion%grid

! ******************************************************************************
! Copy particles and fix cell and region indices
! ******************************************************************************

  npclsold = pplag2%nPcls

  CALL plag_dstr_copyparticlewrapper(global,pplag,pplag2)

  npclsnew = pplag2%nPcls

  DO ipcl = npclsold+1,npclsnew
    icg2 = pplag2%aiv(aiv_plag_icells,ipcl)
    icg  = pgrid%pc2sc(icg2) 
  
    pplag2%aiv(aiv_plag_icells,ipcl) = icg
    pplag2%aiv(aiv_plag_regini,ipcl) = pregion%iRegionGlobal
  END DO ! iPcl
  
! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE plag_dstr_mergeparticlewrapper







! ******************************************************************************
!
! Purpose: Re-allocate memory for cell-to-particle list.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE plag_dstr_recreatecell2pcllist(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Declarations
! ******************************************************************************

! ==============================================================================  
! Arguments 
! ==============================================================================  

  TYPE(t_region), POINTER :: pregion
  
! ==============================================================================  
! Locals
! ==============================================================================  

  INTEGER :: errorflag,icl
  INTEGER, DIMENSION(:), POINTER :: temparray1,temparray2
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_plag), POINTER :: pplag

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'PLAG_DSTR_RecreateCell2PclList',&
  'PLAG_ModDataStruct.F90')

! ******************************************************************************
! Allocate temporary array and copy into it
! ******************************************************************************

  pgrid => pregion%grid
  pplag => pregion%plag

  ALLOCATE(temparray1(pplag%nCellsNzPcl),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'tempArray1')
  END IF ! global%error
  
  ALLOCATE(temparray2(pplag%nCellsNzPcl),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'tempArray2')
  END IF ! global%error
  
  DO icl = 1,pplag%nCellsNzPcl
    temparray1(icl) = pplag%icgNzPcl(icl)
    temparray2(icl) = pplag%iPclPerCellCSRInfo(icl)
  END DO ! icl

! ******************************************************************************
! Reallocate array, expand size
! ******************************************************************************
  
  CALL plag_dstr_destroycell2pcllist(pregion)
  
  pplag%nCellsNzPclMax = min(2*pplag%nCellsNzPclMax,pgrid%nCells)
  
  CALL plag_dstr_createcell2pcllist(pregion)

! ******************************************************************************
! Copy into expanded array and deallocate temporary array
! ******************************************************************************
  
  DO icl = 1,pplag%nCellsNzPcl
    pplag%icgNzPcl(icl)           = temparray1(icl) 
    pplag%iPclPerCellCSRInfo(icl) = temparray2(icl) 
  END DO ! icl  
  
  DEALLOCATE(temparray1,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'tempArray1')
  END IF ! global%error  
  
  DEALLOCATE(temparray2,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'tempArray2')
  END IF ! global%error  
  
! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE plag_dstr_recreatecell2pcllist






! ******************************************************************************
! End
! ******************************************************************************
  
END MODULE plag_moddatastruct

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_ModDataStruct.F90,v $
! Revision 1.5  2008/12/06 08:44:34  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:46  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2007/03/27 00:41:47  haselbac
! Bug fix: Incorrect loop limit in copying particle data
!
! Revision 1.2  2007/03/27 00:20:49  haselbac
! Substantial additions to allow faster initialization
!
! Revision 1.1  2007/03/12 23:33:29  haselbac
! Initial revision
!
! ******************************************************************************