PLAG_CalcBreakup.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: invoke breakup model case for Lagrangian particles.
!
! Description: none.
!
! Input: region  = current region.
!
! Output: region%levels(iLev)%plag%cv
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PLAG_CalcBreakup.F90,v 1.3 2008/12/06 08:44:33 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_calcbreakup( region, iReg )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modpartlag,    ONLY : t_plag, t_plag_input
  USE moderror
  USE plag_modparameters

  IMPLICIT NONE

! ... parameters
  TYPE(t_region), INTENT(INOUT), TARGET :: region

  INTEGER, INTENT(IN) :: ireg

! ... loop variables
  INTEGER :: icont, ipcls

! ... local variables
  CHARACTER(CHRLEN)  :: rcsidentstring

  INTEGER :: breakupmodel, breakupwebswi, ncont, npcls
#ifdef RFLO
  INTEGER :: ilev
#endif
  INTEGER, POINTER, DIMENSION(:) :: pcvplagmass, pdvplagvolu

  REAL(RFREAL) :: breakupfac, breakupfacr, densg, diaml, diamlsplit, &
                  onethird, pi, presg, relvelmagl, surftensl,        &
                  surftenssum, volusum, volusumr, weberl, webercrit

  REAL(RFREAL),          DIMENSION(3)   :: relvel
  REAL(RFREAL), POINTER, DIMENSION(:)   :: psurftens
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: parv,pcv, pdv

  TYPE(t_plag),   POINTER :: pplag
  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_CalcBreakup.F90,v $ $Revision: 1.3 $'

  global => region%global

  CALL registerfunction( global,'PLAG_CalcBreakup',&
  'PLAG_CalcBreakup.F90' )

! begin =======================================================================

! Check if there are any particles

#ifdef RFLO
  ilev  = region%currLevel
  npcls = 0
  IF (global%plagUsed) npcls = region%levels(ilev)%plag%nPcls
#endif
#ifdef RFLU
  npcls = 0
  IF (global%plagUsed) npcls = region%plag%nPcls
#endif
  IF (npcls < 1) go to 999

! Set pointers ----------------------------------------------------------------

#ifdef RFLO
  pplag => region%levels(ilev)%plag
#endif
#ifdef RFLU
  pplag => region%plag
#endif

  parv  => pplag%arv
  pcv   => pplag%cv
  pdv   => pplag%dv

  pcvplagmass => pplag%cvPlagMass
  pdvplagvolu => pplag%dvPlagVolu
  psurftens   => region%plagInput%surftens

! Get dimensions --------------------------------------------------------------

  pi = global%pi
  onethird = 1.0_rfreal/3.0_rfreal

  ncont  = region%plagInput%nCont

  breakupmodel  = region%plagInput%breakupModel
  breakupwebswi = region%plagInput%breakupWebSwi
  breakupfac    = region%plagInput%breakupFac
  breakupfacr   = 1.0_rfreal/breakupfac

! Set appropriate coefficients pertinent to breakup Model ---------------------

  SELECT CASE (breakupmodel)

    CASE (plag_breakup_model1)
      webercrit = 10.0_rfreal

    CASE default
      CALL errorstop( global,err_reached_default,__line__ )

  END SELECT ! breakupModel

! Loop over all the particles -------------------------------------------------

  DO ipcls = 1,npcls

! - Extract gas properties ----------------------------------------------------

    densg = pdv(dv_plag_densmixt,ipcls)

! - Compute Particle surface tension ------------------------------------------

    volusum  = sum( pdv(pdvplagvolu(:),ipcls) )
    volusumr = 1.0_rfreal/volusum

    surftenssum = sum( pdv(pdvplagvolu(:),ipcls) * psurftens(:) )

    surftensl =  surftenssum * volusumr

    diaml = pdv(dv_plag_diam,ipcls)

! - Compute relative velocities and its magnitude ----------------------------

    relvel(1) = pdv(dv_plag_uvelmixt,ipcls)-pdv(dv_plag_uvel,ipcls)
    relvel(2) = pdv(dv_plag_vvelmixt,ipcls)-pdv(dv_plag_vvel,ipcls)
    relvel(3) = pdv(dv_plag_wvelmixt,ipcls)-pdv(dv_plag_wvel,ipcls)

    relvelmagl  = relvel(1)*relvel(1) &
                + relvel(2)*relvel(2) &
                + relvel(3)*relvel(3)

! - Compute weber number ------------------------------------------------------

    weberl = densg * diaml * relvelmagl / surftensl

! - Check if critical weber number is met -------------------------------------

    IF ( weberl >= webercrit ) THEN

#ifdef PLAG_DEBUG
      WRITE(*,'(A,3X,I3,3X,I4,3X,1PE12.5)') &
      'PLAG_CalcBreakup-Critical We reached: iReg, iPcls, We = ',&
       ireg, ipcls, weberl
#endif

! -- Redefine breakupFactor based on critical Weber, if needed ----------------

      IF ( breakupwebswi == plag_breakup_webswi1 ) THEN
        breakupfac  = ( densg * diaml * relvelmagl /( surftensl *webercrit ) ) **3
        breakupfacr = 1.0_rfreal/breakupfac

#ifdef PLAG_DEBUG
      WRITE(*,'(A,3X,I3,3X,I4,3X,1PE12.5)') &
      'PLAG_CalcBreakup-Breakup Switch Active: iReg, iPcls, breakupFac = ',&
       ireg, ipcls, breakupfac
#endif

      END IF ! breakupSwi

! -- Update cv and arv values --------------------------------------------------

      DO icont = 1, ncont
       pcv(pcvplagmass(icont),ipcls) = pcv(pcvplagmass(icont),ipcls)*breakupfacr
      END DO ! iCont

      pcv(cv_plag_xmom,ipcls) = pcv(cv_plag_xmom,ipcls) * breakupfacr
      pcv(cv_plag_ymom,ipcls) = pcv(cv_plag_ymom,ipcls) * breakupfacr
      pcv(cv_plag_zmom,ipcls) = pcv(cv_plag_zmom,ipcls) * breakupfacr
      pcv(cv_plag_ener,ipcls) = pcv(cv_plag_ener,ipcls) * breakupfacr
      pcv(cv_plag_enervapor,ipcls) = pcv(cv_plag_enervapor,ipcls) * breakupfacr

      parv(arv_plag_spload,ipcls) = parv(arv_plag_spload,ipcls)* breakupfac
    END IF ! weberL

  END DO ! iPcls

! finalize --------------------------------------------------------------------

999  CONTINUE

  CALL deregisterfunction( global )

END SUBROUTINE plag_calcbreakup

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_CalcBreakup.F90,v $
! Revision 1.3  2008/12/06 08:44:33  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:45  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 20:57:00  fnajjar
! Initial revision after changing case
!
! Revision 1.5  2004/03/25 21:16:43  jferry
! fixed Vapor Energy bug
!
! Revision 1.4  2004/03/05 22:09:03  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.3  2004/02/06 21:18:20  fnajjar
! Initial Integration of Rocpart with Rocflu
!
! Revision 1.2  2003/09/15 20:26:54  fnajjar
! Corrected breakupFac and removed cubeRootFac
!
! Revision 1.1  2003/09/13 20:15:13  fnajjar
! Initialimport of breakup model
!
!******************************************************************************