PLAG_AppendDataFromBuffers.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: append Lagrangian particle datastructure from buffers 
!          communicated via the patches. 
!
! Description: none.
!
! Input: regions = regions
!        iReg    = current region number.
!
! Output: regions(iReg)%levels%plag%aiv,arv,cv,dv,tv = Plag data.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PLAG_AppendDataFromBuffers.F90,v 1.4 2008/12/06 08:44:32 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_appenddatafrombuffers( region, iReg )

  USE moddatatypes
  USE modpartlag, ONLY    : t_plag, t_plag_input, t_buffer_plag
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global  
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection
  
  USE moderror
  USE modparameters
  USE plag_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region
  
  INTEGER        :: ireg

! ... loop variables
  INTEGER :: ipatch, ipcls

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: bctype, ibeg, ibuff, idir, iend, ilev,               &
             jbeg, jdir, jend, kbeg, kdir, kend,                  &
             lbound, n1, n2, nbuffsizedes, noff, npatches,        &
             npcls, npclsbufftot, npclsend, npclsprev, npclsstart 
   
  INTEGER, POINTER, DIMENSION(:,:) :: paiv,  paivbuff, paivold, paivoldbuff

  LOGICAL :: plagregionin, plagpatchdumcell

  REAL(RFREAL), POINTER, DIMENSION(:,:) :: parv, parvbuff,              &
                                           parvold, parvoldbuff,        &
                                           pcv, pcvbuff,                &
                                           pcvold, pcvoldbuff,          &
                                           pdv, pdvbuff,                &
                                           prhs, prhsbuff, prhssum,     &
                                           prhssumbuff, ptv, ptvbuff
  
  TYPE(t_patch),       POINTER :: ppatch
  TYPE(t_plag),        POINTER :: pplag 
  TYPE(t_buffer_plag), POINTER :: pbuffplag
  TYPE(t_global),      POINTER :: global
  
!******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_AppendDataFromBuffers.F90,v $ $Revision: 1.4 $'

  global => region%global
    
  CALL registerfunction( global, 'PLAG_AppendDataFromBuffers',&
  'PLAG_AppendDataFromBuffers.F90' )

! Get dimensions --------------------------------------------------------------

  ilev     = region%currLevel
  npatches = region%nPatches

  npcls        = region%levels(ilev)%plag%nPcls 
  npclsbufftot = region%plagInput%nPclsBuffTot
  npclsprev    = 0
  
! Set pointers ----------------------------------------------------------------
   
  pplag   => region%levels(ilev)%plag   
  paiv    => pplag%aiv
  parv    => pplag%arv
  pcv     => pplag%cv
  pdv     => pplag%dv
  ptv     => pplag%tv
  prhs    => pplag%rhs
  prhssum => pplag%rhsSum

  paivold    => pplag%aivOld
  parvold    => pplag%arvOld
  pcvold     => pplag%cvOld

! Loop over patches -----------------------------------------------------------

  DO ipatch=1,npatches

    ppatch  => region%levels(ilev)%patches(ipatch)
    bctype  = ppatch%bcType    
   
! - Get patch dimensions -----------------------------------------------------

    lbound = ppatch%lbound

    CALL rflo_getpatchindices( region,ppatch,ilev, &
                               ibeg,iend,jbeg,jend,kbeg,kend )
    CALL rflo_getpatchdirection( ppatch,idir,jdir,kdir )
       
! - Select communication boundary conditions ---------------------------------
        
    IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
        (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
        (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN 

        pbuffplag => ppatch%bufferPlag 
        paivbuff  => pbuffplag%aiv
        parvbuff  => pbuffplag%arv
        pcvbuff   => pbuffplag%cv
        pdvbuff   => pbuffplag%dv
        ptvbuff   => pbuffplag%tv
        prhsbuff  => pbuffplag%rhs
        prhssumbuff  => pbuffplag%rhsSum

        paivoldbuff  => pbuffplag%aivOld
        parvoldbuff  => pbuffplag%arvOld
        pcvoldbuff   => pbuffplag%cvOld
    
        npclsstart = 0
        npclsend   = 0
        npclsprev  = npcls
        
! - Get buffer size and start appending for non-null size ---------------------

        nbuffsizedes = pbuffplag%nBuffSizeDes

        IF ( nbuffsizedes /= 0 ) THEN 
        
! - Set loop extent-------------------------------------------------------------

          npclsstart = npcls+1
          npclsend   = npclsstart + (nbuffsizedes-1)
          
#ifdef PLAG_DEBUG
          WRITE(stdout,'(A,I2,3I6)') &
          '      PLAG_AppendDataFromBuffers-iReg: nBuffSizeDes,nPclsStart,nPclsEnd',&
           ireg, nbuffsizedes,npclsstart,npclsend
#endif


          DO ipcls = npclsstart, npclsend
          
            ibuff = ipcls-npclsstart+1
 
            paiv(:,ipcls) = paivbuff(:,ibuff)
            parv(:,ipcls) = parvbuff(:,ibuff)
            pcv(:,ipcls)  = pcvbuff( :,ibuff)
            pdv(:,ipcls)  = pdvbuff( :,ibuff)
            ptv(:,ipcls)  = ptvbuff( :,ibuff)
            prhs(:,ipcls) = prhsbuff(:,ibuff)
            prhssum(:,ipcls) = prhssumbuff(:,ibuff)

            paivold(:,ipcls) = paivoldbuff(:,ibuff)
            parvold(:,ipcls) = parvoldbuff(:,ibuff)
            pcvold(:,ipcls)  = pcvoldbuff( :,ibuff)
            
          END DO ! iPcls

! - Get new particle datasize and reset loop extent----------------------------
          
          npcls = npcls+nbuffsizedes
          region%levels(ilev)%plag%nPcls = npcls

        END IF ! nBuffSizeDes

    END IF ! bcType 

  ENDDO ! iPatch

#ifdef PLAG_DEBUG
  IF( npclsprev /= pplag%nPcls ) &
  WRITE(stdout,'(A,I4,2I8)') &
  '      PLAG_AppendDataFromBuffers-iReg: nPclsPrev,nPclsCurr',&
  ireg,npclsprev,pplag%nPcls
#endif 

! finalize --------------------------------------------------------------------

999 CONTINUE

  CALL deregisterfunction( global )

END SUBROUTINE plag_appenddatafrombuffers

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_AppendDataFromBuffers.F90,v $
! Revision 1.4  2008/12/06 08:44:32  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:45  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:23  haselbac
! Removed tabs
!
! Revision 1.1  2004/12/01 20:56:53  fnajjar
! Initial revision after changing case
!
! Revision 1.9  2004/04/09 23:01:42  fnajjar
! Put WRITE statements inside ifdef construct
!
! Revision 1.8  2003/05/27 19:14:16  fnajjar
! Removed distPartBurning and all pertinent LOGICAL datastructure
!
! Revision 1.7  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.6  2003/05/07 00:02:34  fnajjar
! Commented out I/O for nPcls
!
! Revision 1.5  2003/05/06 23:42:46  fnajjar
! Removed exit trap for zero nPcls to allow particles to be communicated
!
! Revision 1.4  2003/04/17 00:00:27  fnajjar
! Commented out I/O to STDOUT
!
! Revision 1.3  2003/02/28 21:44:13  fnajjar
! Initialize nPclsPrev and Exit for Null nPcls
!
! Revision 1.2  2003/01/23 17:21:57  f-najjar
! Removed Hidden TABs
!
! Revision 1.1  2003/01/16 22:42:09  f-najjar
! Initial import
!
!******************************************************************************