PEUL_DerivedInputValues.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: set values derived from user input for Eulerian particles.
!
! Description: none.
!
! Input: regions = input parameters for all regions.
!
! Output: regions = numerical parameters and no. of equations for each region.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PEUL_DerivedInputValues.F90,v 1.3 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_derivedinputvalues( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modparteul,    ONLY : t_peul_input, t_peul_ptype, t_peul
  USE moderror
  USE modparameters
  USE peul_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, ilev, iptype

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  TYPE(t_global),     POINTER :: global
  TYPE(t_peul_input), POINTER :: input
  TYPE(t_peul_ptype), POINTER :: ptype
  TYPE(t_peul),       POINTER :: peul

!******************************************************************************

  rcsidentstring = '$RCSfile: PEUL_DerivedInputValues.F90,v $ $Revision: 1.3 $'

  global => regions(1)%global

  CALL registerfunction( global,'PEUL_DerivedInputValues',&
  'PEUL_DerivedInputValues.F90' )

! global values ---------------------------------------------------------------

! (none currently)

! region related values -------------------------------------------------------

  DO ireg=lbound(regions,1),ubound(regions,1)

    input => regions(ireg)%peulInput

! - number of variables

    DO ilev=1,regions(ireg)%nGridLevels

      peul => regions(ireg)%levels(ilev)%peul

      peul%nCv1 = cv_peul_neqs
      peul%nDv1 = 0
      peul%nTv1 = 0

      peul%nCv  = input%nPtypes * peul%nCv1
      peul%nDv  = input%nPtypes * peul%nDv1
      peul%nTv  = input%nPtypes * peul%nTv1

    ENDDO ! iLev

! - Check peulInput quantities (none currently)

!-  Fill auxillary peulInput variables (none currently)

    DO iptype = 1,input%nPtypes

      ptype => input%ptypes(iptype)

! --- Check peulInput%ptypes quantities

      IF (.NOT. ASSOCIATED(ptype%material)) &
        CALL errorstop( global,err_val_undefined,__line__ )

      IF (ptype%material%molw <= 0._rfreal) &
        CALL errorstop( global,err_peul_badval,__line__ )

      IF (ptype%material%molw > 10._rfreal) THEN
        WRITE(stdout,*)
        WRITE(stdout,*) '### WARNING: Molecular weight suspiciously large: ', &
          ptype%material%molw
        WRITE(stdout,*) '###          E.g., in SI units carbon is 0.012'
        WRITE(stdout,*)
      ENDIF

      IF (ptype%material%dens <= 0._rfreal) &
        CALL errorstop( global,err_peul_badval,__line__ )

      IF (ptype%material%spht <= 0._rfreal) &
        CALL errorstop( global,err_peul_badval,__line__ )

      IF (ptype%diam <= 0._rfreal) &
        CALL errorstop( global,err_peul_badval,__line__ )

      IF (ptype%diam > 0.099_rfreal) THEN
        WRITE(stdout,*)
        WRITE(stdout,*) '### WARNING: Particle diameter suspiciously large: ', &
          ptype%diam
        WRITE(stdout,*) '###          Input units are meters'
        WRITE(stdout,*)
      ENDIF

      IF (ptype%puff < 1._rfreal) THEN
        IF (ptype%puff < 0.999_rfreal) THEN
          CALL errorstop( global,err_peul_badval,__line__ )
        ELSE
          ptype%puff = 1._rfreal
        ENDIF
      ENDIF

! --- Sc not actually used
!      IF (ptype%Sc <= 0._RFREAL) &
!        CALL ErrorStop( global,ERR_PEUL_BADVAL,__LINE__ )

! --- k2 not actually used
!      IF (ptype%vis2 < 0._RFREAL) &
!        CALL ErrorStop( global,ERR_PEUL_BADVAL,__LINE__ )

      IF (ptype%vis4 <= 0._rfreal) &
        CALL errorstop( global,err_peul_badval,__line__ )

      ptype%vis4 = 1._rfreal/ptype%vis4

      SELECT CASE (ptype%negReport)
      CASE (peul_neg_report_none)
      CASE (peul_neg_report_used)
      CASE default
        CALL errorstop( global,err_peul_badval,__line__ )
      END SELECT ! ptype%negReport

      SELECT CASE (ptype%clipModel)
      CASE (peul_clip_model_none)
      CASE (peul_clip_model_used)
      CASE default
        CALL errorstop( global,err_peul_badval,__line__ )
      END SELECT ! ptype%clipModel

      SELECT CASE (ptype%methodV)

      CASE (peul_methv_fluidvel)

      CASE (peul_methv_eqeul)

! ----- require Navier-Stokes for Eq. Eul. because it uses the velocity
! ----- gradient information computed in ViscousFluxes

        IF (regions(ireg)%mixtInput%flowModel /= flow_navst) THEN
          WRITE(stdout,*) '### PEUL: Eq. Eul. method requires Navier-Stokes'
          CALL errorstop( global,err_peul_badval,__line__ )
        END IF ! flowModel

        regions(ireg)%mixtInput%computeTv = .true.
        DO ilev=1,regions(ireg)%nGridLevels
          IF (regions(ireg)%levels(ilev)%mixt%nTv < 2) THEN
            regions(ireg)%levels(ilev)%mixt%nTv = 2
          END IF ! nTv
        END DO ! iLev
        IF (regions(ireg)%mixtInput%viscModel < visc_suthr .OR.  &
            regions(ireg)%mixtInput%viscModel > visc_antib) THEN
          CALL errorstop(global,err_unknown_viscmodel,__line__)
        END IF ! viscModel

      CASE default
        CALL errorstop( global,err_peul_badval,__line__ )

      END SELECT ! ptype%methodV

! --- Fill auxillary peulInput%ptypes variables

      ptype%denseff = ptype%material%dens / ptype%puff
      ptype%voleff  = ptype%diam**3 * global%pi / 6._rfreal
      ptype%volmat  = ptype%voleff / ptype%puff

! --- Note: include pressure correction: (1 - beta) factor
      ptype%tauVcoef = (ptype%denseff - 1._rfreal)*ptype%diam**2 / 18._rfreal

      ptype%maxConc = 0.7_rfreal*ptype%denseff

    ENDDO ! iPtype
  ENDDO  ! iReg

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_derivedinputvalues

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_DerivedInputValues.F90,v $
! Revision 1.3  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:51  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:32  haselbac
! Initial revision after changing case
!
! Revision 1.6  2004/08/02 16:38:40  jferry
! Added pressure correction to tau coefficient
!
! Revision 1.5  2004/07/30 22:47:36  jferry
! Implemented Equilibrium Eulerian method for Rocflu
!
! Revision 1.4  2004/05/03 15:09:42  jferry
! added equilibrium Eulerian capability for smoke
!
! Revision 1.3  2004/03/05 22:09:04  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.2  2003/03/11 16:04:57  jferry
! Created data type for material properties
!
! Revision 1.1  2003/02/11 22:52:50  jferry
! Initial import of Rocsmoke
!
!******************************************************************************