PEUL_AllocateDataBuffers.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: allocate data buffers (send & receive) for inter-region
!          communication for PEUL module.
!
! Description: none.
!
! Input: regions = data of all regions
!        iReg    = region number
!
! Output: regions%levels%patches%bufferPeul%... = send & receive buffers
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PEUL_AllocateDataBuffers.F90,v 1.3 2008/12/06 08:44:38 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_allocatedatabuffers( regions,iReg ) ! PUBLIC

  USE moddatatypes
  USE modparteul,    ONLY : t_peul, t_buffer_peul
  USE modbndpatch,   ONLY : t_patch
  USE moddatastruct, ONLY : t_region, t_level, t_dcelltransf
  USE modglobal,     ONLY : t_global
  USE moderror
  USE modparameters
  USE peul_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

  INTEGER, INTENT(IN)     :: ireg

! ... loop variables
  INTEGER :: ipatch, ilev, ir

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: bctype, iregsrc, n1, n2, n1src, n2src, ncv, neqs, neqssrc
  INTEGER :: ndc, ndcsrc, ndim, ndimsrc, errorflag

  TYPE(t_global),      POINTER :: global
  TYPE(t_level),       POINTER :: level
  TYPE(t_patch),       POINTER :: ppatch
  TYPE(t_buffer_peul), POINTER :: pbuffpeul
  TYPE(t_peul),        POINTER :: ppeul
  TYPE(t_dcelltransf), POINTER :: sendeccell,    recveccell
  TYPE(t_dcelltransf), POINTER :: sndpeuleccell, rcvpeuleccell

!******************************************************************************

  rcsidentstring = '$RCSfile: PEUL_AllocateDataBuffers.F90,v $ $Revision: 1.3 $'

  global => regions(ireg)%global

  CALL registerfunction( global,'RFLO_AllocateDataBuffers',&
  'PEUL_AllocateDataBuffers.F90' )

! data buffers for patches

  DO ilev=1,regions(ireg)%nGridLevels

    ppeul => regions(ireg)%levels(ilev)%peul

    ppeul%nRequests = 0
    ncv  =  ppeul%nCv

    DO ipatch=1,regions(ireg)%nPatches

      ppatch => regions(ireg)%levels(ilev)%patches(ipatch)
      bctype = ppatch%bcType

      pbuffpeul => ppatch%bufferPeul

      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
        iregsrc = ppatch%srcRegion
        IF (regions(iregsrc)%procid /= global%myProcid) THEN  ! other processor
          n1      = abs(ppatch%l1end   -ppatch%l1beg   ) + 2    ! large enough
          n2      = abs(ppatch%l2end   -ppatch%l2beg   ) + 2    ! for NODES!
          n1src   = abs(ppatch%srcL1end-ppatch%srcL1beg) + 2
          n2src   = abs(ppatch%srcL2end-ppatch%srcL2beg) + 2
          neqs    = ncv
          neqssrc = ncv
          ndc     = regions(ireg   )%nDumCells
          ndcsrc  = regions(iregsrc)%nDumCells
          ndim    = n1*n2*neqs*ndc
          ndimsrc = n1src*n2src*neqssrc*ndcsrc

          ALLOCATE( pbuffpeul%sendBuff(ndimsrc),stat=errorflag )
          global%error = errorflag
          IF (global%error /= err_none) &
            CALL errorstop( global,err_allocate,__line__ )

          ALLOCATE( pbuffpeul%recvBuff(ndim   ),stat=errorflag )
          global%error = errorflag
          IF (global%error /= err_none) &
            CALL errorstop( global,err_allocate,__line__ )

          pbuffpeul%nSendBuff = ndimsrc
          pbuffpeul%nRecvBuff = ndim
          ppeul%nRequests     = ppeul%nRequests + 1
          pbuffpeul%iRequest  = ppeul%nRequests
        ENDIF
      ELSE IF ((bctype>=bc_regionint  .AND. bctype<=bc_regionint +bc_range) .OR. &
               (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range)) THEN
        CALL errorstop( global,err_unknown_bc,__line__ )  ! #### TEMPORARY ####
      ENDIF  ! bcType

    ENDDO    ! iPatch

! Allocate array for send requests --------------------------------------------

#ifdef MPI
    ALLOCATE( ppeul%requests(ppeul%nRequests),stat=errorflag )
    global%error = errorflag
    IF (global%error /= err_none) THEN
      CALL errorstop( global, err_allocate,__line__,'pPeul%requests' )
    END IF ! global%error
#endif

  ENDDO      ! iLev

! data buffers for edge & corner cells

  IF (global%nProcAlloc > 1) THEN    ! only if multiple processors

    DO ilev=1,regions(ireg)%nGridLevels

! --- allocate send and receive region data

      level => regions(ireg)%levels(ilev)
      ncv   =  level%peul%nCv

      ALLOCATE( level%sndPeulEcCells(global%nRegions),stat=errorflag )
      ALLOCATE( level%rcvPeulEcCells(global%nRegions),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

      DO ir=1,global%nRegions
        sendeccell    => regions(ireg)%levels(ilev)%sendEcCells(ir)
        recveccell    => regions(ireg)%levels(ilev)%recvEcCells(ir)
        sndpeuleccell => regions(ireg)%levels(ilev)%sndPeulEcCells(ir)
        rcvpeuleccell => regions(ireg)%levels(ilev)%rcvPeulEcCells(ir)
        sndpeuleccell%nCells = sendeccell%nCells
        rcvpeuleccell%nCells = recveccell%nCells

        IF (sndpeuleccell%nCells > 0) THEN
          global%nRequests       = global%nRequests + 1
          sndpeuleccell%iRequest = global%nRequests
          ALLOCATE( sndpeuleccell%buff(sndpeuleccell%nCells*ncv), &
                    stat=errorflag )
          global%error = errorflag
          IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
        ENDIF
        IF (rcvpeuleccell%nCells > 0) THEN
          rcvpeuleccell%iRequest = -999999
          ALLOCATE( rcvpeuleccell%buff(rcvpeuleccell%nCells*ncv), &
                    stat=errorflag )
          global%error = errorflag
          IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
        ENDIF
      ENDDO    ! ir
    ENDDO      ! iLev

  ENDIF

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_allocatedatabuffers

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_AllocateDataBuffers.F90,v $
! Revision 1.3  2008/12/06 08:44:38  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:51  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:12  haselbac
! Initial revision after changing case
!
! Revision 1.5  2004/04/15 16:04:03  jferry
! minor formatting (removed trailing spaces)
!
! Revision 1.4  2004/03/02 21:44:07  jferry
! Added corner and edge cell data structures and routines
!
! Revision 1.3  2003/05/05 21:58:29  fnajjar
! Moved nRequests and nCv outside iPatch loop
!
! Revision 1.2  2003/05/05 21:49:50  fnajjar
! Moved pPeul pointer outside iPatch loop
!
! Revision 1.1  2003/04/09 14:32:06  fnajjar
! Initial Import of MPI-based rocsmoke
!
!******************************************************************************