PERI_coCnlInitSolutionFlu.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Initialisation of channel flow solution
!
! Description: initial solution is laminar channel flow
!
! Input: region = data of current region
!
! Output: channel solution to start simulation
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PERI_coCnlInitSolutionFlu.F90,v 1.5 2008/12/06 08:44:36 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peri_cocnlinitsolution( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : mixtperf_eo_dgpvm
  USE moderror
  USE modparameters
  USE peri_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE (t_region) :: region

! ... loop variables
  INTEGER :: ijkc, ijkv

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER  :: ijkcr, ijkn, ijkn1
  REAL(RFREAL), POINTER :: xyz(:,:), cofg(:,:), cv(:,:)
  REAL(RFREAL) :: rgas, yc, muel, refmeanpgrad, delta
  REAL(RFREAL) :: rho, pres, vm, eo, xyzcell(3), twopi, xmin, xmax, zmin, zmax
  REAL(RFREAL) :: lambda,ampl,umax,nxwav,nywav,nzwav,span,extn,fy,yscale,ywaves

!******************************************************************************

  rcsidentstring = '$RCSfile: PERI_coCnlInitSolutionFlu.F90,v $ $Revision: 1.5 $'

  global => region%global
  CALL registerfunction( global,'PERI_CoCnlInitSolution',&
  'PERI_coCnlInitSolutionFlu.F90' )

! get parameters and pointers ----------------------------------------------

  xyz  => region%grid%xyz
  cofg => region%grid%cofg
  cv   => region%mixt%cv

  IF ((global%flowType==flow_unsteady .AND. &
       global%currentTime < peri_real_small) .OR. &
      (global%flowType==flow_steady .AND. global%currentIter==0)) THEN

! - get parameters and set conservative variables
    
    delta = global%refLength
    muel  = global%refVisc
    rho   = global%refDensity
    pres  = global%refPressure
    refmeanpgrad = region%periInput%meanPgrad
    cv(cv_mixt_dens,:) = rho
    cv(cv_mixt_ymom,:) = 0._rfreal
    cv(cv_mixt_zmom,:) = 0._rfreal

    DO ijkc = 1, region%grid%nCellsTot

      yc = cofg(ycoord,ijkc)
      cv(cv_mixt_xmom,ijkc) = -0.5_rfreal/muel*refmeanpgrad* &
                               (delta*delta - yc*yc)*rho

      vm = sqrt( cv(cv_mixt_xmom,ijkc)*cv(cv_mixt_xmom,ijkc) + &
                 cv(cv_mixt_ymom,ijkc)*cv(cv_mixt_ymom,ijkc) + &        
                 cv(cv_mixt_zmom,ijkc)*cv(cv_mixt_zmom,ijkc))/rho
      eo = mixtperf_eo_dgpvm(rho,global%refGamma,pres,vm)
      cv(cv_mixt_ener,ijkc) = rho*eo
    END DO

! - add perturbations, first define xMin/Max, zMin/Max

    xmin =  100000._rfreal
    xmax = -100000._rfreal
    zmin =  100000._rfreal
    zmax = -100000._rfreal
    DO ijkv = 1,region%grid%nVertTot
      xmin = min( xmin, xyz(xcoord,ijkv) )
      xmax = max( xmax, xyz(xcoord,ijkv) )
      zmin = min( zmin, xyz(zcoord,ijkv) )
      zmax = max( zmax, xyz(zcoord,ijkv) )
    ENDDO

    lambda = 5._rfreal
    ampl   = 0.2_rfreal
    umax   = -0.5_rfreal/muel*refmeanpgrad*delta*delta
    nxwav  = 4._rfreal
    nywav  = 2._rfreal
    nzwav  = 2._rfreal
    span   = zmax-zmin
    extn   = xmax-xmin
    twopi  = 2._rfreal*global%pi

    DO ijkc = 1,region%grid%nCellsTot

! --- X and Z momentum components

      xyzcell(1:3) = cofg(xcoord:zcoord,ijkc)

      yscale = (delta - abs( xyzcell(2) ))/delta
      ywaves = sin( nywav*yscale*twopi )
      fy     = ampl*(lambda*yscale)**2/ &
               (1._rfreal + (lambda*yscale)**4)  ! normal envelope
      fy     = ywaves*fy                         ! normal oscillations

      cv(cv_mixt_xmom,ijkc) = cv(cv_mixt_xmom,ijkc) + &
                              cv(cv_mixt_dens,ijkc)*umax* &
                            ( fy*sin( nxwav*xyzcell(1)/extn*twopi )+ &
                              fy*sin( nzwav*xyzcell(3)/span*twopi ) ) 
      cv(cv_mixt_zmom,ijkc) = cv(cv_mixt_zmom,ijkc) + &
                              cv(cv_mixt_dens,ijkc)*umax* &
                            ( fy*sin( nxwav*xyzcell(1)/extn*twopi )+ &
                              fy*sin( nzwav*xyzcell(3)/span*twopi ) ) 

! --- Y momentum component

!      yscale = xyzCell(2)/delta
!      ywaves = SIN( nYwav/2*yscale*twopi )
!      yscale = (delta - ABS( xyzCell(2) ))/delta
!      fy     = ampl*(lambda*yscale)**2/ &
!               (1._RFREAL + (lambda*yscale)**4)  ! normal envelope
!      fy     = ywaves*fy                         ! normal oscillations

!      cv(CV_MIXT_YMOM,ijkC) = cv(CV_MIXT_YMOM,ijkC) + &
!                              cv(CV_MIXT_DENS,ijkC)*umax* &
!                            ( fy*COS( nXwav*xyzCell(1)/extn*twopi )+ &
!                              fy*COS( nZwav*xyzCell(3)/span*twopi ) ) 

    END DO

  ELSE

! - previous pressure gradient is read from main solution file

    region%periInput%meanPgrad = global%moduleVar(1)
    write(*,*) global%myProcId,' channel MeanPgrad ', region%periInput%meanPgrad

  ENDIF       

! finalize --------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peri_cocnlinitsolution

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PERI_coCnlInitSolutionFlu.F90,v $
! Revision 1.5  2008/12/06 08:44:36  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:49  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2004/06/17 20:03:14  wasistho
! compiled with RFLU
!
! Revision 1.2  2004/06/17 00:50:09  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/06/09 01:10:26  wasistho
! changed nomenclature
!
!
!
!******************************************************************************