PERI_DerivedInputValues.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Set values derived from user input.
!
! Description: Global and user input parameters are used to derive derived 
!              variables which are mostly components of periInput data type 
!              (region%periInput) as rocperi data structure does not have
!              its own global data type. Derivations for CPR are based on 1D 
!              analysis can be found in AIAA-86-1447 (Traineau, Hervat and 
!              Kuentsmann). Derivations for channel flow follow Dean`s and
!              theoretical correlations.
!
! Input: regions = Input parameters for all regions.
!
! Output: regions = Derived variables stored as periInput data.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PERI_DerivedInputValues.F90,v 1.5 2008/12/06 08:44:36 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peri_derivedinputvalues( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modperiodic, ONLY   : t_peri_input
  USE modbndpatch, ONLY   : t_patch
  USE moderror
  USE modparameters
  USE peri_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring
  TYPE(t_global), POINTER     :: global
  TYPE(t_peri_input), POINTER :: input
  TYPE(t_patch), POINTER      :: patches(:)

! ... cpr local variables
  REAL(RFREAL) :: rgas, gamma, gogampls, cpreps, headpres, headtemp, headsv 
  REAL(RFREAL) :: minj, denom, choklen, delta, mfrat, phi, meanpgrad

! ... channel local variables
  REAL(RFREAL) :: ucubulk, skinfriction, tauwall
  LOGICAL      :: pgtauwall

!******************************************************************************

  rcsidentstring = '$RCSfile: PERI_DerivedInputValues.F90,v $'

  global => regions(1)%global
  CALL registerfunction( global,'PERI_DerivedInputValues',&
  'PERI_DerivedInputValues.F90' )

  pgtauwall = .false.

#ifdef RFLO
  DO ireg=1,global%nRegions

    IF (regions(ireg)%procid==global%myProcid .AND. &   ! region active and
        regions(ireg)%active==active) THEN              ! on my processor

      patches => regions(ireg)%levels(1)%patches(:)
#endif
#ifdef RFLU
  DO ireg = lbound(regions,1),ubound(regions,1)

      patches => regions(ireg)%patches(:)
#endif

      input => regions(ireg)%periInput
      IF (input%flowKind==peri_flow_cpr) THEN

! ----- get cpr head end pressure and temperature

        input%headPres = global%refPressure
        gamma          = global%refGamma
        rgas           = global%refCp*(1._rfreal - 1._rfreal/gamma)
        input%headTemp = global%refPressure/global%refDensity/rgas

! ----- derive initial mean pressure gradient from 1D analysis

        gogampls = gamma / (gamma + 1._rfreal)
        cpreps   = input%cprEpsilon
        headpres = input%headPres
        headtemp = input%headTemp
        headsv   = sqrt( gamma*rgas*headtemp )
        IF (patches(3)%bcType >= bc_injection .AND. &
            patches(3)%bcType <= bc_injection+ &
            bc_range) THEN
          minj = patches(3)%mixt%vals(bcdat_inject_mfrate,0)
        ELSE
          CALL errorstop( regions(ireg)%global,err_peri_cprbc,__line__, &
                          'cpr injection bc should be on patch 3 and 4' )
        ENDIF
        denom    = headsv*minj*sqrt( 2._rfreal*(gamma+1._rfreal) )
        choklen  = headpres*gamma/denom
        delta    = global%refLength
        mfrat    = 1._rfreal/cpreps/choklen
        phi      = sqrt(1._rfreal - mfrat*mfrat)
        meanpgrad= -gogampls*mfrat/phi*headpres/(choklen*delta)  ! dP/dx

! ----- cpr mean pressure gradient (in 'slow' coordinate)
        meanpgrad= meanpgrad/cpreps                              ! dP/dx_s

! ----- assign number of cpr variables and cpr mean values to permanent data str.

        input%nVar      = cpr_nvar
        input%minjRate  = minj
        input%meanPgrad = meanpgrad
        input%bulkmFlux = 2._rfreal*delta*minj/cpreps

      ELSEIF (input%flowKind==peri_flow_channel) THEN

! ----- meaning global reference parameters
!       global%refDensity = wall density
!       global%refRenum   = bulk Reynolds number
!       global%refVelocity= estimate bulk velocity
!       global%refLength  = half channel height

        IF (global%refRenum > cnl_critreyn) THEN  !turbulent
! ------- uc/ubulk, from Dean`s correlation:
          ucubulk = 1.28_rfreal*(2._rfreal*global%refRenum)**(-0.0116_rfreal)
          skinfriction = 0.073_rfreal*(2._rfreal*global%refRenum)**(-0.25_rfreal)
        ELSE  ! laminar
! ------- uc/ubulk, from laminar correlation:
          ucubulk = 1.5_rfreal
          skinfriction = 6._rfreal/(global%refRenum*ucubulk*ucubulk)
        ENDIF

! ----- initial estimate physical parameters:
        input%cnlCvel = ucubulk*global%refVelocity
        input%cnlUtau = global%refVelocity*(0.5_rfreal*skinfriction)**0.5_rfreal
        tauwall       = global%refDensity*input%cnlUtau**2._rfreal
        input%cnlRetau= input%cnlUtau/global%refVelocity*global%refRenum

! ----- initial pressure gradient and reference mass flux:
        input%meanPgrad = -tauwall/global%refLength
        input%bulkmFlux = 2._rfreal*global%refLength*global%refVelocity* &
                          global%refDensity

! ----- pressure gradient computation method:
        IF (input%pgradType == cnl_pgrad_tauwall) pgtauwall = .true.

      ELSEIF (input%flowKind==peri_flow_bola) THEN

      ENDIF ! flowKind

#ifdef RFLO
    ENDIF  ! region active and my processor
#endif
  ENDDO   ! iReg

! global pressure gradient computation method:

#ifdef RFLO
  DO ireg=1,global%nRegions

    IF (regions(ireg)%procid==global%myProcid .AND. &   ! region active and
        regions(ireg)%active==active) THEN              ! on my processor
#endif
#ifdef RFLU
  DO ireg = lbound(regions,1),ubound(regions,1)
#endif

      input => regions(ireg)%periInput
      IF (input%flowKind==peri_flow_channel) THEN
        IF (pgtauwall) input%pgradType = cnl_pgrad_tauwall
      ENDIF ! flowKind
#ifdef RFLO
    ENDIF   ! region active and my processor
#endif
  ENDDO     ! iReg

! Channel halfwidth delta and bulk mass flux are overruled in PERI_InitSolution
! with the actual values.

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peri_derivedinputvalues

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PERI_DerivedInputValues.F90,v $
! Revision 1.5  2008/12/06 08:44:36  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:49  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/08/19 15:40:09  mparmar
! Renamed patch variables
!
! Revision 1.2  2004/06/11 21:49:40  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/06/08 23:56:56  wasistho
! changed nomenclature
!
! Revision 1.5  2003/10/14 21:26:18  wasistho
! replace Uc by Ub in uTau = f(Cf) formulation
!
! Revision 1.4  2003/09/18 01:57:13  wasistho
! added ijksplit and pgradType in PERI_PgradUpdate
!
! Revision 1.3  2003/04/03 00:33:01  wasistho
! correct initial mflux channel flow
!
! Revision 1.2  2003/04/02 01:48:48  wasistho
! minimize CPR user input
!
! Revision 1.1.1.1  2003/03/29 03:36:30  wasistho
! install ROCPERI
!
!
!
!******************************************************************************