INRT_SetParticleTemp.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: set temperature of burning particles to the boiling point of Al
!
! Description: none.
!
! Input: region  = current region.
!
! Output: region%levels(iLev)%plag%cv
!
! Notes:
!
!   It is the energy that is set of course, not the temperature itself.
!
!   If the boiling point of Al (or whatever constituent is burning) not between
!   500 K and 5000 K, an error is returned.
!
!******************************************************************************
!
! $Id: INRT_SetParticleTemp.F90,v 1.3 2008/12/06 08:44:32 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE inrt_setparticletemp( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modpartlag,    ONLY : t_plag
  USE modinteract,   ONLY : t_inrt_interact
  USE moderror
  USE inrt_modparameters

#ifdef PLAG
  USE plag_modparameters
#endif
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), INTENT(INOUT), TARGET :: region

! ... loop variables
  INTEGER :: ipcls

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: npcls, ncont, icvmassbeg, icvmassend, icontal, imatal
#ifdef RFLO
  INTEGER :: ilev
#endif
  INTEGER, POINTER, DIMENSION(:,:) :: paiv

  REAL(RFREAL) :: temptarg, masssum, kinener, heatcap, enertarg

  REAL(RFREAL), POINTER, DIMENSION(:)   :: pspcheat
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: pcv

  TYPE(t_inrt_interact), POINTER :: pinrtburn
  TYPE(t_plag),          POINTER :: pplag
  TYPE(t_global),        POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: INRT_SetParticleTemp.F90,v $ $Revision: 1.3 $'

  global => region%global

  CALL registerfunction( global,'INRT_SetParticleTemp',&
  'INRT_SetParticleTemp.F90' )

#ifdef PLAG
! begin -----------------------------------------------------------------------

#ifdef RFLO
  ilev  =  region%currLevel
  pplag => region%levels(ilev)%plag
#endif
#ifdef RFLU
  pplag => region%plag
#endif

! Check if there are any particles --------------------------------------------

  npcls = 0
  IF (global%plagUsed) npcls = pplag%nPcls

  IF (npcls < 1) go to 9

! Set pointers and values -----------------------------------------------------

  paiv => pplag%aiv
  pcv  => pplag%cv

  pinrtburn => region%inrtInput%inrts(inrt_type_burning)

  pspcheat => region%plagInput%spht
  ncont    =  region%plagInput%nCont

! Of 1:nCv conserved variables, iCvMassBeg is the first constituent mass index,
!                           and iCvmassEnd is the last one.

  icvmassbeg = pplag%cvPlagMass(1)
  icvmassend = pplag%cvPlagMass(ncont)

! Of 1:nCont types of particle constituents, iContAl is the index of Al

  icontal = pinrtburn%edges(inrt_burning_l_mass_x)%iNode(1) &
          - region%inrtInput%indPlag0

  IF (icontal < 1 .OR. icontal > ncont) THEN
    CALL errorstop( global,err_inrt_indexrange,__line__ )
  END IF ! iContAl

! Of 1:nMaterials types of materials, iMatAl is the index of Al

  imatal = region%plagInput%materialIndex(icontal)

  IF (imatal < 1 .OR. imatal > global%nMaterials) THEN
    CALL errorstop( global,err_inrt_indexrange,__line__ )
  END IF ! iMatAl

  temptarg = global%materials(imatal)%Tboil

  IF (temptarg < 500._rfreal .OR. temptarg > 10000._rfreal) THEN
    CALL errorstop( global,err_inrt_badval,__line__ )
  END IF ! tempTarg

! Loop over all the particles -------------------------------------------------

  DO ipcls = 1,npcls

    SELECT CASE (paiv(aiv_plag_burnstat,ipcls))

    CASE (inrt_burnstat_off)

      cycle

    CASE (inrt_burnstat_on)

      masssum = sum( pcv(icvmassbeg:icvmassend,ipcls) )

      kinener = dot_product( pcv(cv_plag_xmom:cv_plag_zmom,ipcls),    &
                             pcv(cv_plag_xmom:cv_plag_zmom,ipcls) ) * &
                0.5_rfreal / masssum

      heatcap = dot_product( pcv(icvmassbeg:icvmassend,ipcls),pspcheat(:) )

      enertarg = kinener + heatcap*temptarg

! --- Should have switch here for what to do with energy difference in the
! --- case of active particles.

! --- Current implementation: ignore energy difference
! --- This is justified for strongly burning particles, but may be
! --- a bad assumption when particles are weakly burning.

      pcv(cv_plag_ener,ipcls) = enertarg

    CASE default

      CALL errorstop( global,err_reached_default,__line__ )

    END SELECT ! pAiv(AIV_PLAG_BURNSTAT,iPcls)

  END DO ! iPcls

! finalize --------------------------------------------------------------------

9 CONTINUE
#endif
  CALL deregisterfunction( global )

END SUBROUTINE inrt_setparticletemp

!******************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_SetParticleTemp.F90,v $
! Revision 1.3  2008/12/06 08:44:32  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:56:43  fnajjar
! Initial revision after changing case
!
! Revision 1.2  2004/03/05 22:09:03  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.1  2004/03/02 21:47:29  jferry
! Added After Update interactions
!
!******************************************************************************