INRT_PrintUserInput.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: write out user input for interactions for checking purposes.
!
! Description: none.
!
! Input: regions = user input.
!
! Output: to standard output.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: INRT_PrintUserInput.F90,v 1.3 2008/12/06 08:44:31 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE inrt_printuserinput( region ) ! PUBLIC

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modinteract
  USE moderror
  USE modparameters
  USE inrt_modparameters

  USE modinterfaces, ONLY : makenumberedkeys
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), INTENT(IN) :: region

! ... loop variables
  INTEGER :: iinrt,inod,ipeul,iswi,idat,iedge

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring
  CHARACTER(10)     :: peulstr(100),plagstr(100),tempstr
  CHARACTER(256)    :: edgestr

  INTEGER :: nnodes,nplag,npeul,ninrt,indmixt,indplag0,indpeul0,indintl
  INTEGER :: indplagvapor,maxconedges,maxdisedges

  TYPE(t_inrt_input),    POINTER :: input
  TYPE(t_inrt_interact), POINTER :: inrt
  TYPE(t_inrt_edge),     POINTER :: edge
  TYPE(t_global),        POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: INRT_PrintUserInput.F90,v $ $Revision: 1.3 $'

  global => region%global

  CALL registerfunction( global,'INRT_PrintUserInput',&
  'INRT_PrintUserInput.F90' )

! begin -----------------------------------------------------------------------

  input => region%inrtInput

  nnodes   = input%nNodes
  nplag    = input%nPlag
  npeul    = input%nPeul
  indmixt  = input%indMixt
  indplag0 = input%indPlag0
  indpeul0 = input%indPeul0
  indintl  = input%indIntl
  indplagvapor = input%indPlagVapor
  maxconedges  = input%maxConEdges
  maxdisedges  = input%maxDisEdges

! Determine total number of interactions used

  ninrt = 0
  DO iinrt = 1,inrt_type_total
    IF (input%inrts(iinrt)%used) ninrt = ninrt + 1
  END DO ! iInrt

! Make auxillary strings (used in the internal function nodeStr)

  CALL makenumberedkeys(plagstr,1,'L',1,nplag,1)
  CALL makenumberedkeys(peulstr,1,'S',1,npeul,1)

  IF (ninrt > 0) WRITE(stdout,*)
  WRITE(stdout,1010) solver_name//'     Number of interactions',ninrt

  IF (ninrt > 0) THEN

    WRITE(stdout,*)
    WRITE(stdout,1030) solver_name//'       *** Indexing ***'
    WRITE(stdout,1010) solver_name//'         nNodes      ', nnodes
    WRITE(stdout,1010) solver_name//'         nPlag       ', nplag
    WRITE(stdout,1010) solver_name//'         nPeul       ', npeul
    WRITE(stdout,1010) solver_name//'         indMixt     ', indmixt
    WRITE(stdout,1010) solver_name//'         indPlag0    ', indplag0
    WRITE(stdout,1010) solver_name//'         indPeul0    ', indpeul0
    WRITE(stdout,1010) solver_name//'         indIntl     ', indintl
    WRITE(stdout,1010) solver_name//'         indPlagJoint', input%indPlagJoint
    WRITE(stdout,1010) solver_name//'         indPlagVapor', indplagvapor
    WRITE(stdout,1010) solver_name//'         maxConEdges ', maxconedges
    WRITE(stdout,1010) solver_name//'         maxDisEdges ', maxdisedges
    WRITE(stdout,*)

    IF (input%consistent) THEN
      WRITE(stdout,1030) solver_name//'       *** Active Phases '// &
        'Consistent ***'
    ELSE
      WRITE(stdout,1030) solver_name//'       *** WARNING: Active Phases '// &
        'Inconsistent ***'
    END IF ! input%consistent
    WRITE(stdout,*)

    WRITE(stdout,1030) solver_name//'       *** Global Activeness ***'

    DO inod = 1,nnodes-1
      WRITE(stdout,3010) solver_name//'         '//trim(nodestr(inod)), &
        input%globActiveness(inod),'  '// &
        trim(fullactvstr(input%globActiveness(inod)))
    END DO ! iNod
    WRITE(stdout,*)

    WRITE(stdout,1030) solver_name//'       *** Global Permission levels ***'

    DO inod = 1,nnodes-1
      WRITE(stdout,3010) solver_name//'         '//trim(nodestr(inod)), &
        input%globPermission(inod),'  '// &
        trim(fullpermstr(input%globPermission(inod)))
    END DO ! iNod
    WRITE(stdout,*)

  END IF ! nInrt

  DO iinrt = 1,inrt_type_total

    inrt => input%inrts(iinrt)
    IF (.NOT. inrt%used) cycle

    WRITE(stdout,1010) solver_name//'       *** Interaction',iinrt

    WRITE(stdout,1030) solver_name//'         name          = '//trim(inrt%name)
    WRITE(stdout,1025) solver_name//'         pclsUsed     ',inrt%pclsUsed
    WRITE(stdout,1015) solver_name//'         order        ',inrt%order
    WRITE(stdout,1010) solver_name//'         nIntl        ',inrt%nIntl
    WRITE(stdout,1010) solver_name//'         nInputEdges  ',inrt%nInputEdges
    WRITE(stdout,1010) solver_name//'         nSwitches    ',inrt%nSwitches
    WRITE(stdout,1010) solver_name//'         nData        ',inrt%nData
    WRITE(stdout,1010) solver_name//'         nEdges       ',inrt%nEdges

    DO iswi = 1,inrt%nSwitches
      WRITE(stdout,2010) solver_name//'         Switch',iswi, &
        inrt%switches(iswi)
    END DO ! iSwi

    DO idat = 1,inrt%nData
      WRITE(stdout,2020) solver_name//'         Data  ',idat,inrt%data(idat)
    END DO ! iDat

    DO inod = 1,nnodes-1

      IF (inrt%activeness(inod) /= input%globActiveness(inod)) THEN
        WRITE(stdout,3010) solver_name//'         Activeness override: '// &
          trim(nodestr(inod)), inrt%activeness(inod),'  '// &
          trim(fullactvstr(inrt%activeness(inod)))
      END IF ! inrt%activeness(iNod)

      IF (inrt%permission(inod) /= input%globPermission(inod)) THEN
        WRITE(stdout,3010) solver_name//'         Permission override: '// &
          trim(nodestr(inod)), inrt%permission(inod),'  '// &
          trim(fullpermstr(inrt%permission(inod)))
      END IF ! inrt%permission(iNod)

    END DO ! iNod

    IF (inrt%nIntl > 0) THEN

      WRITE(stdout,3010) solver_name//'         Internal Activeness: '// &
        trim(nodestr(indintl)), inrt%activeness(indintl),'  '// &
        trim(fullactvstr(inrt%activeness(indintl)))

    END IF ! inrt%nIntl

    DO iedge = 1,inrt%nEdges

      edge => inrt%edges(iedge)

      edgestr = trim(nodestr(edge%iNode(1)))//' '//permstr(edge%token(1))// &
        '-----'//tedgestr(edge%tEdge)//'----'//permstr(edge%token(2))

      tempstr = trim(nodestr(edge%iNode(2)))

      IF (tempstr(1:1) == ' ') THEN
        edgestr = trim(edgestr)//trim(tempstr)
      ELSE
        edgestr = trim(edgestr)//' '//trim(tempstr)
      END IF

      WRITE(stdout,1030) solver_name//'         '//trim(edgestr)

    END DO ! iEdge

    WRITE(stdout,*)

  END DO ! iInrt

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

1010 FORMAT(a,' =',i3)
1015 FORMAT(a,' =',i9)
1025 FORMAT(a,' = ',l1)
1030 FORMAT(a)
2010 FORMAT(a,i2,' =',i3)
2020 FORMAT(a,i2,' =',es13.5)
3010 FORMAT(a,':',i3,a)

CONTAINS

  CHARACTER(13) FUNCTION defstr(eq)

    LOGICAL, INTENT(IN) :: eq

    IF (eq) THEN
      defstr = '(default)    '
    ELSE
      defstr = '(non-default)'
    END IF ! eq

  END FUNCTION defstr

  CHARACTER(10) FUNCTION nodestr(ind)

    INTEGER, INTENT(IN) :: ind

    IF (ind == indmixt) THEN
      nodestr = ' G'

    ELSE IF (indplag0 + 1 <= ind .AND. ind <= indplag0 + nplag) THEN
      nodestr = trim(plagstr(ind - indplag0))

    ELSE IF (indplagvapor == ind) THEN
      nodestr = 'LV'

    ELSE IF (indpeul0 + 1 <= ind .AND. ind <= indpeul0 + npeul) THEN
      nodestr = trim(peulstr(ind - indpeul0))

    ELSE IF (ind == indintl) THEN
      nodestr = ' X'

    ELSE
      CALL errorstop( global,err_reached_default,__line__ )

    END IF ! ind

  END FUNCTION nodestr

  CHARACTER(1) FUNCTION permstr(perm)

    INTEGER, INTENT(IN) :: perm

    SELECT CASE (perm)

    CASE (inrt_perm_block)
      permstr = 'x'

    CASE (inrt_perm_pmass)
      permstr = 'm'

    CASE (inrt_perm_pmome)
      permstr = 'o'

    CASE (inrt_perm_pall)
      permstr = '-'

    CASE default
      CALL errorstop( global,err_reached_default,__line__ )

    END SELECT ! perm

  END FUNCTION permstr

  CHARACTER(5) FUNCTION tedgestr(tEdge)

    INTEGER, INTENT(IN) :: tedge

    SELECT CASE (tedge)

    CASE (inrt_edge_bad)
      tedgestr = 'ERROR'

    CASE (inrt_edge_mass)
      tedgestr = 'MASS-'

    CASE (inrt_edge_mome_dum)
      tedgestr = 'DUMMY'

    CASE (inrt_edge_mome)
      tedgestr = 'MOME-'

    CASE (inrt_edge_ener)
      tedgestr = 'ENER-'

    CASE (inrt_edge_mass_gho)
      tedgestr = 'GMASS'

    CASE default
      CALL errorstop( global,err_reached_default,__line__ )

    END SELECT ! tEdge

  END FUNCTION tedgestr

  CHARACTER(20) FUNCTION fullactvstr(actv)

    INTEGER, INTENT(IN) :: actv

    SELECT CASE (actv)

    CASE (inrt_act_active)
      fullactvstr = '(active)'

    CASE (inrt_act_active-1)
      fullactvstr = '(passive)'

    CASE (:inrt_act_active-2)
      fullactvstr = '(very passive)'

    CASE default
      fullactvstr = '(Error!)'

    END SELECT ! actv

  END FUNCTION fullactvstr

  CHARACTER(40) FUNCTION fullpermstr(perm)

    INTEGER, INTENT(IN) :: perm

    SELECT CASE (perm)

    CASE (inrt_perm_block)
      fullpermstr = '(permit nothing)'

    CASE (inrt_perm_pmass)
      fullpermstr = '(permit mass only)'

    CASE (inrt_perm_pmome)
      fullpermstr = '(permit mass and momentum only)'

    CASE (inrt_perm_pall)
      fullpermstr = '(permit all)'

    CASE default
      fullpermstr = '(Error!)'

    END SELECT ! perm

  END FUNCTION fullpermstr

END SUBROUTINE inrt_printuserinput

!******************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_PrintUserInput.F90,v $
! Revision 1.3  2008/12/06 08:44:31  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:56:30  fnajjar
! Initial revision after changing case
!
! Revision 1.11  2004/07/28 15:42:12  jferry
! deleted defunct constructs: useDetangle, useSmokeDrag, useSmokeHeatTransfer
!
! Revision 1.10  2004/07/27 21:30:00  jferry
! integrated maxConEdges and maxDisEdges variables more fully
!
! Revision 1.9  2004/03/05 22:09:03  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.8  2004/03/02 21:48:09  jferry
! First phase of replacing Detangle interaction
!
! Revision 1.7  2003/09/19 20:35:26  jferry
! Implemented oxidizer species for burning interaction
!
! Revision 1.6  2003/04/07 18:26:16  jferry
! minor correction
!
! Revision 1.5  2003/04/03 21:10:18  jferry
! implemented additional safety checks for rocinteract
!
! Revision 1.4  2003/04/02 22:32:04  jferry
! codified Activeness and Permission structures for rocinteract
!
! Revision 1.3  2003/03/24 23:30:52  jferry
! overhauled rocinteract to allow interaction design to use user input
!
! Revision 1.2  2003/03/11 16:09:39  jferry
! Added comments
!
! Revision 1.1  2003/03/04 22:12:35  jferry
! Initial import of Rocinteract
!
!******************************************************************************