INRT_Initialize.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: initializes data structures for interactions
!
! Description: specifies data common to all interactions, then calls routines
!              specific to each interaction
!
! Input: region = data of current region.
!
! Output: fills in region%inrtInput
!
! Notes: none.
!
!******************************************************************************
!
! $Id: INRT_Initialize.F90,v 1.3 2008/12/06 08:44:31 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE inrt_initialize( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modinteract
  USE moderror
  USE inrt_modparameters

  IMPLICIT NONE

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region

! ... loop variables
  INTEGER :: iinrt,ipeul

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: nnodes,nplag,npeul
  INTEGER :: indmixt,indplag0,indpeul0,indintl
  INTEGER :: indplagjoint,indplagvapor,iplagjoint
  INTEGER :: errorflag

  TYPE(t_inrt_input),    POINTER :: input
  TYPE(t_inrt_interact), POINTER :: inrt
  TYPE(t_inrt_edge),     POINTER :: edge
  TYPE(t_global),        POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: INRT_Initialize.F90,v $ $Revision: 1.3 $'

  global => region%global

  CALL registerfunction( global,'INRT_Initialize',&
  'INRT_Initialize.F90' )

! begin -----------------------------------------------------------------------

  ALLOCATE( region%inrtInput,stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  input => region%inrtInput

! Determine the quantities needed to index the Activeness and Permission arrays

  nplag = 0

#ifdef PLAG
  IF (global%plagUsed) nplag = region%plagInput%nCont
#endif

! it does not matter which particle index is used to store momentum and energy
! that is common to all particle constituents.  We choose the first index:

  iplagjoint = 1

  npeul = 0

#ifdef RFLO
#ifdef PEUL
  IF (global%peulUsed) npeul = region%peulInput%nPtypes
#endif
#endif

#ifdef RFLU
#ifdef SPEC
  IF (global%specUsed) npeul = region%specInput%nSpecies
#endif
#endif

! Number of Nodes:
! 1     for Gas
! nPlag for particle constituent masses
! 1     for particle vapor energy
! nPeul for smoke masses
! 1     for Internal Node

  nnodes = 1 + nplag + 1 + npeul + 1

! Indices for Nodes

  indmixt  = 1
  indplag0 = indmixt
  indpeul0 = indplag0 + nplag + 1
  indintl  = indpeul0 + npeul + 1

  indplagjoint = indplag0 + iplagjoint
  indplagvapor = indplag0 + nplag + 1

! Store all the above information in region%inrtInput

  input%nNodes       = nnodes
  input%nPlag        = nplag
  input%nPeul        = npeul
  input%indMixt      = indmixt
  input%indPlag0     = indplag0
  input%indPeul0     = indpeul0
  input%indIntl      = indintl
  input%indPlagJoint = indplagjoint
  input%indPlagVapor = indplagvapor

! indicate that the maximum number of edges in a diagram is 0 so far

  input%maxConEdges  = 0 ! max over diagrams indexed by cells
  input%maxDisEdges  = 0 ! max over diagrams indexed by particles

! indicate that an INRT_DEFAULT section has not yet been read

  input%defaultRead  = .false.

! active phases are assumed to form a consistent system unless shown otherwise

  input%consistent   = .true.

! compute auxillary quantities by default (allow User override for testing)

  input%computeAux   = .true.

! allocate globActiveness and globPermission

  ALLOCATE( input%globActiveness(nnodes),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  ALLOCATE( input%globPermission(nnodes),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! give proper default values

  input%globActiveness = inrt_act_active
  input%globPermission = inrt_perm_pall

  input%globActiveness(indintl) = inrt_act_bad ! undefined for Internal Node

! allocate interactions

  ALLOCATE( input%inrts(inrt_type_total),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  DO iinrt = 1,inrt_type_total

    inrt => input%inrts(iinrt)

! - set default values for interactions

    inrt%name        = 'Not defined yet'
    inrt%used        = .false.
    inrt%pclsUsed    = .true.
    inrt%order       = 0
    inrt%nIntl       = 0
    inrt%nInputEdges = 0
    inrt%nSwitches   = 0
    inrt%nData       = 0
    inrt%nEdges      = 0

! - allocate activeness and permission

    ALLOCATE( inrt%activeness(nnodes),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

    ALLOCATE( inrt%permission(nnodes),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! - give proper default values

    inrt%activeness = inrt_act_bad  ! require to be overwritten later
    inrt%permission = inrt_perm_bad ! require to be overwritten later

! - nullify other pointers initially

    nullify( inrt%switches )
    nullify( inrt%data )
    nullify( inrt%edges )

  END DO ! iInrt

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE inrt_initialize

!******************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_Initialize.F90,v $
! Revision 1.3  2008/12/06 08:44:31  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:56:28  fnajjar
! Initial revision after changing case
!
! Revision 1.10  2004/07/28 15:29:20  jferry
! created global variable for spec use
!
! Revision 1.9  2004/07/27 21:30:00  jferry
! integrated maxConEdges and maxDisEdges variables more fully
!
! Revision 1.8  2004/07/23 22:43:16  jferry
! Integrated rocspecies into rocinteract
!
! Revision 1.7  2004/03/05 22:09:03  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.6  2004/03/02 21:47:29  jferry
! Added After Update interactions
!
! Revision 1.5  2003/04/03 21:10:18  jferry
! implemented additional safety checks for rocinteract
!
! Revision 1.4  2003/04/02 22:32:04  jferry
! codified Activeness and Permission structures for rocinteract
!
! Revision 1.3  2003/03/24 23:30:52  jferry
! overhauled rocinteract to allow interaction design to use user input
!
! Revision 1.2  2003/03/11 16:09:39  jferry
! Added comments
!
! Revision 1.1  2003/03/04 22:12:35  jferry
! Initial import of Rocinteract
!
!******************************************************************************