INRT_DefineBurning.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Defines the interaction Burning
!
! Description: none.
!
! Input: region = data of current region.
!
! Output: modifies region%inrtInput%inrts
!
! Notes:
!
!   Whereas INRT_Initialize sets up everything generic to all interactions,
!   this routine sets up things specific to this interaction.
!
!   In particular, this is where the designer
!
!   (a) gives values for all the interactions parameters (or leaves them
!       as default values given in INRT_Initialize).  These parameters are
!       described in ModInteract.
!
!   (b) defines the Edges of the interaction.  Here the type of an Edge is
!       given (i.e., whether it transports mass, momentum, or energy), as well
!       as the indices of the Nodes at either end.  For each momentum Edge
!       he must call the routine INRT_FinishMomentumEdge.
!
!******************************************************************************
!
! $Id: INRT_DefineBurning.F90,v 1.5 2008/12/06 08:44:31 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE inrt_defineburning( region,matIndIn,matIndOut,matIndOx, &
                               oxused,plagoutexists )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modinteract
  USE moderror
  USE modparameters
  USE inrt_modparameters

  USE inrt_modinterfaces, ONLY : inrt_allocateauxillary
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region
  INTEGER,        INTENT(IN)    :: matindin,matindout,matindox
  LOGICAL,        INTENT(INOUT) :: oxused
  LOGICAL,        INTENT(OUT)   :: plagoutexists

! ... loop variables
  INTEGER :: iplag,ipeul,ipeuloutedge

! ... local variables
  INTEGER, PARAMETER :: npeuloutedges_max = 10

  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: nplag,npeul,nedges,nplaginedges,nplagoutedges,npeuloutedges
  INTEGER :: npeuloxedges,matindplag,matindpeul
  INTEGER :: iplagin,iplagout,ipeulox,ipeuloxedge
  INTEGER :: ipeularr(npeuloutedges_max)

  TYPE(t_inrt_input),    POINTER :: input
  TYPE(t_inrt_interact), POINTER :: inrt
  TYPE(t_inrt_edge),     POINTER :: edge
  TYPE(t_global),        POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: INRT_DefineBurning.F90,v $ $Revision: 1.5 $'

  global => region%global

  CALL registerfunction( global,'INRT_DefineBurning',&
  'INRT_DefineBurning.F90' )

! begin -----------------------------------------------------------------------

! allocate memory for edges, switches and data

  input => region%inrtInput
  inrt  => input%inrts(inrt_type_burning)

  inrt%name = "Burning"

  nplag = input%nPlag
  npeul = input%nPeul

! loop over particle types looking for those with material index
! matIndIn or matIndOut

  nplaginedges  = 0
  nplagoutedges = 0
  DO iplag = 1,nplag

#ifdef PLAG
    matindplag = region%plagInput%materialIndex(iplag)
#endif

    IF (matindplag == matindin) THEN

      nplaginedges = nplaginedges + 1
      iplagin = iplag

    ELSE IF (matindplag == matindout) THEN

      nplagoutedges = nplagoutedges + 1
      iplagout = iplag

    END IF ! matIndPlag

  END DO ! iPlag

  IF (nplaginedges > 1 .OR. nplagoutedges > 1) &
    CALL errorstop( global,err_inrt_multplagmat,__line__ )

  IF (nplaginedges < 1) &
    CALL errorstop( global,err_inrt_missplagmat,__line__ )

  plagoutexists = .true.
  IF (nplagoutedges < 1) THEN
    plagoutexists = .false. ! flag that no transfer can occur for this Edge
    iplagout = iplagin      ! therefore the Node index used does not matter
  END IF ! nPlagOutEdges

! loop over smoke types looking for those with material index matIndOut
! or, if oxidizer is used, those with index matIndOx

  ipeuloutedge = 0
  ipeuloxedge  = 0
  DO ipeul = 1,npeul

#ifdef RFLO
#ifdef PEUL
    matindpeul = region%peulInput%ptypes(ipeul)%material%index
#endif
#endif
#ifdef RFLU
    matindpeul = region%specInput%specType(ipeul)%pMaterial%index
#endif

    IF (matindpeul == matindout) THEN

      ipeuloutedge = ipeuloutedge + 1

      IF (ipeuloutedge > npeuloutedges_max) &
        CALL errorstop( global,err_exceeds_decl_mem,__line__ )

      ipeularr(ipeuloutedge) = ipeul

    ELSE IF (oxused) THEN

      IF (matindpeul == matindox) THEN

        ipeuloxedge = ipeuloxedge + 1

        IF (ipeuloxedge > 1) &
          CALL errorstop( global,err_inrt_only1,__line__ )

        ipeulox = ipeul

      END IF ! matIndPeul

    END IF ! oxUsed

  END DO ! iPeul

  npeuloutedges = ipeuloutedge
  npeuloxedges  = ipeuloxedge
  nedges = inrt_burning_nedges0 + npeuloutedges + npeuloxedges

  IF (oxused .AND. npeuloxedges < 1) THEN
    WRITE(stdout,'(A)') solver_name//'### INRT_WARNING: no oxidizer smoke '// &
      'type: setting OX_USED = NO'
    oxused = .false.
  END IF

  CALL inrt_allocateauxillary(global,inrt,nedges, &
    inrt_swi_burning_total,inrt_dat_burning_total0 + npeuloutedges)

! set parameters for this interaction:  see comment in ModInteract

  inrt%nIntl       = 1
  inrt%nInputEdges = 2 + npeuloxedges

! define Edges

  edge => inrt%edges(inrt_burning_g_mass_x)

  edge%tEdge    = inrt_edge_mass
  edge%iNode(1) = input%indMixt
  edge%iNode(2) = input%indIntl

  edge => inrt%edges(inrt_burning_l_mass_x)

  edge%tEdge    = inrt_edge_mass
  edge%iNode(1) = input%indPlag0 + iplagin
  edge%iNode(2) = input%indIntl

  IF (npeuloxedges > 0) THEN

    edge => inrt%edges(inrt_burning_s_mass_x0 + npeuloxedges)

    edge%tEdge    = inrt_edge_mass_gho
    edge%iNode(1) = input%indPeul0 + ipeulox
    edge%iNode(2) = input%indIntl

  END IF ! nPeulOxEdges

  edge => inrt%edges(inrt_burning_x_ener_g + npeuloxedges)

  edge%tEdge    = inrt_edge_ener
  edge%iNode(1) = input%indIntl
  edge%iNode(2) = input%indMixt

  edge => inrt%edges(inrt_burning_x_ener_lv + npeuloxedges)

  edge%tEdge    = inrt_edge_ener
  edge%iNode(1) = input%indIntl
  edge%iNode(2) = input%indPlagVapor

  edge => inrt%edges(inrt_burning_x_mass_g + npeuloxedges)

  edge%tEdge    = inrt_edge_mass
  edge%iNode(1) = input%indIntl
  edge%iNode(2) = input%indMixt

  edge => inrt%edges(inrt_burning_x_mass_l + npeuloxedges)

  edge%tEdge    = inrt_edge_mass
  edge%iNode(1) = input%indIntl
  edge%iNode(2) = input%indPlag0 + iplagout

  DO ipeuloutedge = 1,npeuloutedges

    edge => inrt%edges(inrt_burning_x_mass_s0  + npeuloxedges + ipeuloutedge)

    edge%tEdge    = inrt_edge_mass
    edge%iNode(1) = input%indIntl
    edge%iNode(2) = input%indPeul0 + ipeularr(ipeuloutedge)

  END DO ! iPeulOutEdge

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE inrt_defineburning

!******************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_DefineBurning.F90,v $
! Revision 1.5  2008/12/06 08:44:31  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/02/15 20:40:00  wasistho
! put plag within ifdef
!
! Revision 1.2  2006/02/15 20:17:42  wasistho
! put peul within ifdef
!
! Revision 1.1  2004/12/01 21:56:21  fnajjar
! Initial revision after changing case
!
! Revision 1.9  2004/07/23 22:43:16  jferry
! Integrated rocspecies into rocinteract
!
! Revision 1.8  2004/03/08 21:57:36  jferry
! better error checking for burning without smoke case
!
! Revision 1.7  2004/03/02 21:47:29  jferry
! Added After Update interactions
!
! Revision 1.6  2003/09/25 15:47:58  jferry
! minor change: error message parameter altered
!
! Revision 1.5  2003/09/19 20:35:26  jferry
! Implemented oxidizer species for burning interaction
!
! Revision 1.4  2003/04/02 22:32:03  jferry
! codified Activeness and Permission structures for rocinteract
!
! Revision 1.3  2003/03/24 23:30:52  jferry
! overhauled rocinteract to allow interaction design to use user input
!
! Revision 1.2  2003/03/11 16:09:39  jferry
! Added comments
!
! Revision 1.1  2003/03/04 22:12:35  jferry
! Initial import of Rocinteract
!
!******************************************************************************