INRT_CalcDrag.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute interaction source for drag forces on Lagrangian particles.
!
! Description: none.
!
! Input: region  = current region.
!
! Output: region%levels(iLev)%plag%inrtSources
!
! Notes: none.
!
!******************************************************************************
!
! $Id: INRT_CalcDrag.F90,v 1.5 2008/12/06 08:44:31 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE inrt_calcdrag( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modpartlag,    ONLY : t_plag
  USE moderror
  USE modparameters
  USE inrt_modparameters

#ifdef PLAG
  USE plag_modparameters
#endif
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), INTENT(INOUT), TARGET :: region

! ... loop variables
  INTEGER :: ipcls

! ... local variables
  CHARACTER(CHRLEN)  :: rcsidentstring

  INTEGER :: dragmodel, icont, ncont, npcls
#ifdef RFLO
  INTEGER :: ilev
#endif
  INTEGER, POINTER, DIMENSION(:)   :: pcvplagmass

  REAL(RFREAL) :: diaml, massl, mixtvolr, pi, psil, &
                  relvelmagl, reyl, taulr
  REAL(RFREAL),          DIMENSION(3)   :: relvel, accell
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: pcv, pdv, ptv

  TYPE(t_plag)  , POINTER :: pplag
  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: INRT_CalcDrag.F90,v $ $Revision: 1.5 $'

  global => region%global

  CALL registerfunction( global,'INRT_CalcDrag',&
  'INRT_CalcDrag.F90' )

#ifdef PLAG
! begin -----------------------------------------------------------------------

! Check if there are any particles

  npcls = 0

#ifdef RFLO
  ilev  = region%currLevel
  IF (global%plagUsed) npcls = region%levels(ilev)%plag%nPcls
#endif
#ifdef RFLU
  IF (global%plagUsed) npcls = region%plag%nPcls
#endif

  IF (npcls < 1) go to 999

! Get dimensions --------------------------------------------------------------

  pi = global%pi

  ncont     = region%plagInput%nCont
  dragmodel = region%inrtInput%inrts(inrt_type_drag)%switches( &
    inrt_swi_drag_model)

! Set pointers ----------------------------------------------------------------

#ifdef RFLO
  pplag     => region%levels(ilev)%plag
#endif
#ifdef RFLU
  pplag     => region%plag
#endif

  pcv       => pplag%cv
  pdv       => pplag%dv
  ptv       => pplag%tv

  pcvplagmass => pplag%cvPlagMass

! Loop over all the particles -------------------------------------------------

  DO ipcls = 1,npcls

    diaml = pdv(dv_plag_diam,ipcls)

    massl = sum( pcv(pcvplagmass(:),ipcls) )

    taulr = 3.0_rfreal*pi*ptv(tv_plag_muelmixt,ipcls)* &
            diaml/massl

    relvel(1)   = pdv(dv_plag_uvelmixt,ipcls)-pdv(dv_plag_uvel,ipcls)
    relvel(2)   = pdv(dv_plag_vvelmixt,ipcls)-pdv(dv_plag_vvel,ipcls)
    relvel(3)   = pdv(dv_plag_wvelmixt,ipcls)-pdv(dv_plag_wvel,ipcls)

    SELECT CASE (dragmodel)

      CASE (inrt_drag_model_stokes)

        psil = 1.0_rfreal

      CASE (inrt_drag_model_sn)

        relvelmagl  = sqrt( relvel(1)*relvel(1)+ &
                            relvel(2)*relvel(2)+ &
                            relvel(3)*relvel(3)  )

        reyl = diaml * relvelmagl * pdv(dv_plag_densmixt,ipcls) / &
                                    ptv(tv_plag_muelmixt,ipcls)

        psil = 1.0_rfreal + 0.15_rfreal* (reyl**0.687_rfreal)

      CASE (inrt_drag_model_smrfld)

        relvelmagl  = sqrt( relvel(1)*relvel(1)+ &
                            relvel(2)*relvel(2)+ &
                            relvel(3)*relvel(3)  )

        reyl = diaml * relvelmagl * pdv(dv_plag_densmixt,ipcls) / &
                                    ptv(tv_plag_muelmixt,ipcls)

        psil = 112.0_rfreal/24.0_rfreal *reyl**(+0.02_rfreal)

      CASE default
        CALL errorstop( global,err_reached_default,__line__ )

    END SELECT ! dragModel

    accell(1) = psil*relvel(1)*taulr
    accell(2) = psil*relvel(2)*taulr
    accell(3) = psil*relvel(3)*taulr

! - fill the effect of the particles (L) on the gas (G).
! - the source terms will be added to the particle Rhs.

    pplag%inrtSources(inrt_drag_l_xmom_g,ipcls) = -massl*accell(1)
    pplag%inrtSources(inrt_drag_l_ymom_g,ipcls) = -massl*accell(2)
    pplag%inrtSources(inrt_drag_l_zmom_g,ipcls) = -massl*accell(3)

  END DO ! iPcls

! finalize --------------------------------------------------------------------

999  CONTINUE
#endif
  CALL deregisterfunction( global )

END SUBROUTINE inrt_calcdrag

!******************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_CalcDrag.F90,v $
! Revision 1.5  2008/12/06 08:44:31  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2007/03/08 14:59:36  fnajjar
! Fixed bug in Sommerfeld drag law for psiL
!
! Revision 1.2  2007/03/07 22:16:47  fnajjar
! Added Sommerfeld drag law
!
! Revision 1.1  2004/12/01 21:56:14  fnajjar
! Initial revision after changing case
!
! Revision 1.6  2004/03/05 22:09:03  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.5  2004/01/31 03:59:22  haselbac
! Initial integration for Rocflu and Rocpart
!
! Revision 1.4  2003/04/03 21:10:17  jferry
! implemented additional safety checks for rocinteract
!
! Revision 1.3  2003/04/02 22:32:03  jferry
! codified Activeness and Permission structures for rocinteract
!
! Revision 1.2  2003/03/11 16:09:39  jferry
! Added comments
!
! Revision 1.1  2003/03/04 22:12:35  jferry
! Initial import of Rocinteract
!
!******************************************************************************