INRT_CalcBurning.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute interaction sources on Lagrangian particles
!          for the burning case.
!
! Description: none.
!
! Input: region  = current region.
!
! Output: region%levels(iLev)%plag%inrtSources
!
! Notes: none.
!
!******************************************************************************
!
! $Id: INRT_CalcBurning.F90,v 1.4 2008/12/06 08:44:31 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE inrt_calcburning( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modpartlag,    ONLY : t_plag
  USE modinteract
  USE moderror
  USE modparameters
  USE inrt_modparameters

#ifdef PLAG
  USE plag_modparameters
#endif
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), INTENT(INOUT), TARGET :: region

! ... loop variables
  INTEGER :: icont, ipcls, ipeuloutedge

! ... local variables
  CHARACTER(CHRLEN)  :: rcsidentstring

  INTEGER :: burnmodel, icontin, icontout, ncont, nedges, &
             npeuloutedges, npeuloxedges, ipeulox, npcls, icell
#ifdef RFLO
  INTEGER :: ilev
#endif
  INTEGER, POINTER, DIMENSION(:)   :: pcvplagmass
  INTEGER, POINTER, DIMENSION(:,:) :: paiv

  LOGICAL :: oxused, sendtovapor

  REAL(RFREAL) :: coeffheatlatent, coefflatentheat, coeffpeul, densal,  &
                  densal2o3, densratio, diaml, diffrel, doxh2rdoxnoh2,  &
                  expdiaml, exphermsen, exppresg, exptempg, expxieffg,  &
                  hcond, hevap, hreac, hsolid, heatlatent, mdotburn,    &
                  mfracl, molwal, molwal2o3, molwratio, presg, tempg,   &
                  volfracl, xico2, xieffg, xio2, xih2, xih2o, massmixt, &
                  massox, sendtemp

  REAL(RFREAL), POINTER, DIMENSION(:)   :: pdens, pmolw
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: pcv, pdv, pcvmixt, pcvpeul

  TYPE(t_inrt_input),    POINTER :: pinputinrt
  TYPE(t_inrt_interact), POINTER :: pinrtburn
  TYPE(t_plag),          POINTER :: pplag
  TYPE(t_global),        POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: INRT_CalcBurning.F90,v $ $Revision: 1.4 $'

  global => region%global

  CALL registerfunction( global,'INRT_CalcBurning',&
  'INRT_CalcBurning.F90' )

#ifdef PLAG
! begin =======================================================================

! Set grid-dependent pointers -------------------------------------------------

#ifdef RFLO
  ilev        =  region%currLevel
  pcvmixt     => region%levels(ilev)%mixt%cv
#ifdef PEUL
  pcvpeul     => region%levels(ilev)%peul%cv
#endif
  pplag       => region%levels(ilev)%plag
#endif

#ifdef RFLU
  pcvmixt     => region%mixt%cv
  pcvpeul     => region%spec%cv
  pplag       => region%plag
#endif

! Check if there are any particles

  npcls = 0
  IF (global%plagUsed) npcls = pplag%nPcls

  IF (npcls < 1) go to 999

! Set pointers ----------------------------------------------------------------

  paiv        => pplag%aiv
  pcv         => pplag%cv
  pdv         => pplag%dv

  pcvplagmass => pplag%cvPlagMass

  pdens       => region%plagInput%dens
  pmolw       => region%plagInput%molw

  pinputinrt  => region%inrtInput
  pinrtburn   => pinputinrt%inrts(inrt_type_burning)

! Get dimensions --------------------------------------------------------------

! Set parameters for oxidizer use

  npeuloxedges = 0
  oxused = (pinrtburn%switches(inrt_swi_burning_oxused) /= 0)

  IF (oxused) THEN

    npeuloxedges = 1
! - Extract index of oxidizer smoke type
    ipeulox = pinrtburn%edges(inrt_burning_s_mass_x0 + &
      npeuloxedges)%iNode(1) - pinputinrt%indPeul0

  END IF ! oxUsed

! Set other parameters

  ncont = region%plagInput%nCont

  nedges        = pinrtburn%nEdges
  npeuloutedges = nedges - npeuloxedges - inrt_burning_nedges0

  burnmodel       = pinrtburn%switches(inrt_swi_burning_model)
  coefflatentheat = pinrtburn%data(inrt_dat_burning_heat_coef)

  mfracl = pinrtburn%data(inrt_dat_burning_mfrc_plag)

! Extract index of AL (In) and AL2O3 (Out). "In" material represents ----------
! the material that will burn and "out" is the burning product

  icontin  = pinrtburn%edges(inrt_burning_l_mass_x)%iNode(1) &
           - pinputinrt%indPlag0
  icontout = pinrtburn%edges(inrt_burning_x_mass_l + npeuloxedges)%iNode(2) &
           - pinputinrt%indPlag0

  densal    = pdens(icontin)
  densal2o3 = pdens(icontout)
  densratio = densal/densal2o3

  molwal    = pmolw(icontin)
  molwal2o3 = pmolw(icontout)
  molwratio = molwal2o3/(2.0_rfreal*molwal)

! Set appropriate coefficients pertinent to burn Model ------------------------

  SELECT CASE (burnmodel)

    CASE (inrt_burning_model_beckstead)

! --- Exponents from Hermsens Model -------------------------------------------

      exphermsen = 1.9_rfreal
      expdiaml   = 3.0_rfreal-exphermsen

! --- Exponents for Burning Rate Variables ------------------------------------

      exptempg  = 1.57_rfreal
      exppresg  = 0.20_rfreal
      expxieffg = 0.39_rfreal

! --- Compute Measure of Availability of Oxidizing Species --------------------

      xico2 = 0.20_rfreal
      xio2  = 0.02_rfreal
      xih2o = 0.20_rfreal
      xih2  = 0.20_rfreal

! --- Will override this value of xiEffG if an oxidizer species is used

      xieffg = ( xio2 + 0.58_rfreal * xih2o + 0.22_rfreal * xico2 )

! --- Compute Relative Diffusivity Coefficient, D_rel -------------------------

! --- Define Ratio of Diffusivity of Oxidants with and without H2 -------------

      doxh2rdoxnoh2 = 3.7_rfreal

      diffrel = 1.0_rfreal + xih2 * ( doxh2rdoxnoh2 - 1.0_rfreal )

! --- Latent Heat for Energy Source -------------------------------------------

      hevap  = 10896.0_rfreal *1000.0_rfreal
      hreac  =  9543.0_rfreal *1000.0_rfreal
      hcond  = 29767.0_rfreal *1000.0_rfreal
      hsolid =     0.0_rfreal

      heatlatent = -hevap + hreac + hcond + hsolid

! --- Scale Latent heat by appropriate coefficient ----------------------------

      heatlatent = heatlatent*coefflatentheat

    CASE default
      CALL errorstop( global,err_reached_default,__line__ )

  END SELECT ! burnModel

  sendtovapor = (pinrtburn%switches(inrt_swi_burning_vapor_meth) /= &
                 inrt_burning_vapor_meth_none)

  sendtemp    = pinrtburn%data(inrt_dat_burning_vapor_temp)

  IF (sendtemp < 500._rfreal .OR. sendtemp > 10000._rfreal) THEN
    CALL errorstop( global,err_inrt_badval,__line__ )
  END IF ! sendTemp

! Loop over all the particles -------------------------------------------------

  DO ipcls = 1,npcls

    diaml = pdv(dv_plag_diam,ipcls)
    tempg = pdv(dv_plag_tempmixt,ipcls)
    presg = pdv(dv_plag_presmixt,ipcls)

    SELECT CASE (burnmodel)

      CASE (inrt_burning_model_beckstead)

! ----- Compute Particle Volume Fraction --------------------------------------

        volfracl =  pcv(pcvplagmass(icontin),ipcls)/             &
                  ( pcv(pcvplagmass(icontin),ipcls)              &
                  + pcv(pcvplagmass(icontout),ipcls) * densratio )

! ----- If oxidizer is used, compute xiEffG -----------------------------------

        IF (oxused) THEN

! ------- Compute gas and oxidizer mass in this cell

          icell = paiv(aiv_plag_icells,ipcls)

          massmixt = pcvmixt(cv_mixt_dens,icell)
#ifdef RFLO
#ifdef PEUL
          massox   = pcvpeul(ipeulox,icell)
#endif
#endif
#ifdef RFLU
          massox   = pcvpeul(ipeulox,icell)
#endif

          IF (massox <= 0._rfreal) THEN

            xieffg = 0._rfreal

          ELSE

! --------- Notes: this assumes that the molecular weights of the gas
! --------- and oxidizer are the same.  Technically, xiEffG should be
! --------- massOx / massMixt, but that would be too dangerous.

            xieffg = massox / (massmixt + massox)

          END IF ! massOx

        END IF ! oxUsed

! ----- Compute Mass Burning Rate of Al ---------------------------------------

        mdotburn = 2.885e-13_rfreal * densal * ( tempg**exptempg ) &
                     * ( xieffg**expxieffg ) * ( presg**exppresg ) &
                     * (  diaml**expdiaml  ) * diffrel * volfracl

      CASE default
        CALL errorstop( global,err_reached_default,__line__ )

    END SELECT ! burnModel

! - Fill the interaction source terms -----------------------------------------

    pplag%inrtSources(inrt_burning_g_mass_x,ipcls) = (molwratio - 1.0_rfreal) &
                                                   * mdotburn

    pplag%inrtSources(inrt_burning_l_mass_x,ipcls) = mdotburn

    IF (oxused) THEN
      pplag%inrtSources(inrt_burning_s_mass_x0 + npeuloxedges,ipcls) = &
        (molwratio - 1.0_rfreal) * mdotburn
    END IF ! oxUsed

    IF (sendtovapor .AND. tempg > sendtemp) THEN
      pplag%inrtSources(inrt_burning_x_ener_g  + npeuloxedges,ipcls) = &
        0.0_rfreal
      pplag%inrtSources(inrt_burning_x_ener_lv + npeuloxedges,ipcls) = &
        heatlatent*mdotburn
    ELSE
      pplag%inrtSources(inrt_burning_x_ener_g  + npeuloxedges,ipcls) = &
        heatlatent*mdotburn
      pplag%inrtSources(inrt_burning_x_ener_lv + npeuloxedges,ipcls) = &
        0.0_rfreal
    END IF ! sendToVapor

    pplag%inrtSources(inrt_burning_x_mass_g + npeuloxedges,ipcls) = 0.0_rfreal

    pplag%inrtSources(inrt_burning_x_mass_l + npeuloxedges,ipcls) = &
      mfracl*molwratio*mdotburn

    DO ipeuloutedge = 1,npeuloutedges
      coeffpeul = (1.0_rfreal-mfracl)*molwratio * &
                  pinrtburn%data(inrt_dat_burning_mfrc_peul0 + ipeuloutedge)

      pplag%inrtSources(inrt_burning_x_mass_s0 + npeuloxedges + ipeuloutedge, &
        ipcls) = coeffpeul*mdotburn
    END DO ! iPeulOutEdge

  END DO ! iPcls

! finalize --------------------------------------------------------------------

999  CONTINUE
#endif
  CALL deregisterfunction( global )

END SUBROUTINE inrt_calcburning

!******************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_CalcBurning.F90,v $
! Revision 1.4  2008/12/06 08:44:31  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/02/15 20:18:17  wasistho
! put peul within ifdef
!
! Revision 1.1  2004/12/01 21:56:13  fnajjar
! Initial revision after changing case
!
! Revision 1.9  2004/07/23 22:43:16  jferry
! Integrated rocspecies into rocinteract
!
! Revision 1.8  2004/03/05 22:09:03  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.7  2004/03/02 21:47:29  jferry
! Added After Update interactions
!
! Revision 1.6  2004/01/31 03:59:22  haselbac
! Initial integration for Rocflu and Rocpart
!
! Revision 1.5  2003/09/19 20:35:26  jferry
! Implemented oxidizer species for burning interaction
!
! Revision 1.4  2003/04/04 16:27:39  jferry
! fixed inconsistency in use of burn rate information
!
! Revision 1.3  2003/04/03 22:52:04  fnajjar
! Bug fix for INRT data
!
! Revision 1.2  2003/04/03 21:10:17  jferry
! implemented additional safety checks for rocinteract
!
! Revision 1.1  2003/04/03 16:19:28  fnajjar
! Initial Import of routines for burning and scouring
!
!******************************************************************************