INRT_BurnStatusUpdate.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: update Burning Status of Lagrangian particles
!
! Description: none.
!
! Input: region  = current region.
!
! Output: region%levels(iLev)%plag%aiv
!
! Notes: none.
!
!******************************************************************************
!
! $Id: INRT_BurnStatusUpdate.F90,v 1.3 2008/12/06 08:44:31 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE inrt_burnstatusupdate( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modpartlag,    ONLY : t_plag
  USE modinteract,   ONLY : t_inrt_interact
  USE moderror
  USE inrt_modparameters

#ifdef PLAG
  USE plag_modparameters
#endif
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), INTENT(INOUT), TARGET :: region

! ... loop variables
  INTEGER :: ipcls

! ... local variables
  REAL(RFREAL), PARAMETER :: diamalcutoff = 5.e-7_rfreal ! 0.5-micron

  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: npcls, ncont, icontal, icvalmass
#ifdef RFLO
  INTEGER :: ilev
#endif
  INTEGER, POINTER, DIMENSION(:,:) :: paiv

  LOGICAL :: vapornotused

  REAL(RFREAL) :: densal, massalcutoff, massal

  REAL(RFREAL), POINTER, DIMENSION(:,:) :: pcv

  TYPE(t_inrt_interact), POINTER :: pinrtburn
  TYPE(t_plag),          POINTER :: pplag
  TYPE(t_global),        POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: INRT_BurnStatusUpdate.F90,v $ $Revision: 1.3 $'

  global => region%global

  CALL registerfunction( global,'INRT_BurnStatusUpdate',&
  'INRT_BurnStatusUpdate.F90' )

#ifdef PLAG
! begin -----------------------------------------------------------------------

#ifdef RFLO
  ilev  =  region%currLevel
  pplag => region%levels(ilev)%plag
#endif
#ifdef RFLU
  pplag => region%plag
#endif

! Check if there are any particles --------------------------------------------

  npcls = 0
  IF (global%plagUsed) npcls = pplag%nPcls

  IF (npcls < 1) go to 9

! Set pointers and values -----------------------------------------------------

  paiv => pplag%aiv
  pcv  => pplag%cv

  pinrtburn => region%inrtInput%inrts(inrt_type_burning)

  ncont = region%plagInput%nCont

! Of 1:nCont types of particle constituents, iContAl is the index of Al

  icontal = pinrtburn%edges(inrt_burning_l_mass_x)%iNode(1) &
          - region%inrtInput%indPlag0

  IF (icontal < 1 .OR. icontal > ncont) THEN
    CALL errorstop( global,err_inrt_indexrange,__line__ )
  END IF ! iContAl

! Of 1:nCv conserved variables, iCvAlMass is the index of Al mass

  icvalmass = pplag%cvPlagMass(icontal)

  densal = region%plagInput%dens(icontal)

! set cutoff for amount of Aluminum mass considered negligible, based on the
! diameter that a particle would have if it consisted only of that Al mass.

  massalcutoff = (global%pi / 6._rfreal) * diamalcutoff**3 * densal

! vaporNotUsed is used to flag errors, so it is set .true. whenever
! the vapor energy method is something other than "used".

  vapornotused = pinrtburn%switches(inrt_swi_burning_vapor_meth) /= &
                 inrt_burning_vapor_meth_used

! Loop over all the particles -------------------------------------------------

  DO ipcls = 1,npcls

    SELECT CASE (paiv(aiv_plag_burnstat,ipcls))

    CASE (inrt_burnstat_off)

! --- Re-light model

! --- Nothing yet implemented:  particles not burning remain not burning

    CASE (inrt_burnstat_on)

! --- If vapor energy is present, the particle is always considered burning

      IF (pcv(cv_plag_enervapor,ipcls) > 0._rfreal) THEN

! ----- Flag error if vapor is not used, and yet, somehow, present

        IF (vapornotused) THEN
          CALL errorstop( global,err_inrt_enervapor,__line__ )
        END IF ! vaporNotUsed

      ELSE

! ----- Quench model

! ----- Currently this is hardwired to the condition that the Aluminum mass
! ----- is less than some small, positive amount.

        massal = pcv(icvalmass,ipcls)

        IF (massal < massalcutoff) THEN

          paiv(aiv_plag_burnstat,ipcls) = inrt_burnstat_off

        END IF ! massAl

      END IF ! pCv(CV_PLAG_ENERVAPOR,iPcls)

    CASE default

      CALL errorstop( global,err_reached_default,__line__ )

    END SELECT ! pAiv(AIV_PLAG_BURNSTAT,iPcls)

  END DO ! iPcls

! finalize --------------------------------------------------------------------

9 CONTINUE
#endif
  CALL deregisterfunction( global )

END SUBROUTINE inrt_burnstatusupdate

!******************************************************************************
!
! RCS Revision history:
!
! $Log: INRT_BurnStatusUpdate.F90,v $
! Revision 1.3  2008/12/06 08:44:31  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:44  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:56:12  fnajjar
! Initial revision after changing case
!
! Revision 1.2  2004/03/05 22:09:03  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.1  2004/03/02 21:47:29  jferry
! Added After Update interactions
!
!******************************************************************************