BcondInflowPerf_GL.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! *****************************************************************************
!
! Purpose: Set inflow boundary condition for one cell for gas-liquid model.
!
! Input: 
!   bcOptType  boundary treatment: subsonic, supersonic, or mixed  
!   Bp         compressibility at const. pressure
!   Bt         compressibility at const. temperature
!   cvg        specific heat of gas at constant volume (boundary cell)
!   cvl        specific heat of liquid at constant volume (boundary cell)
!   cvv        specific heat of vapor at constant volume (boundary cell)
!   po         reference pressure
!   ro         reference density
!   to         reference Temperature
!   rl         given density
!   rel        given energy
!   ru/v/wl    given velocity components
!   nx/y/z     components of normalized face vector (outward facing)
!   Rg         gas constant
!   Rv         vapor constant
!   rgpgl      given density of gas * volume fraction of gas 
!   rvpvl      given density of vapor * volume fraction of vapor 
!   pl         given pressure
!   press      given total pressure 
!   temp       given total temperature
!
! Output:
!   rr        density at boundary
!   ru/v/wr   density * velocity components at boundary
!   rer       density * total internal energy at boundary
!   rgpgr     density of gas * volume fraction of gas at boundary
!   rvpvr     density of vapor * volume fraction of vapor at boundary
!   pr        pressure at boundary
!
! Notes: None.
!
! *****************************************************************************
!
! $Id: 
!
! Copyright: (c) 2006 by the University of Illinois
!
! *****************************************************************************

SUBROUTINE bcondinflowperf_gl(bcOptType,ro,po,to,Bp,Bt,cvl,cvv,cvg,Rg,Rv,ur,&  
                              vr,wr,vfgr,vfvr,vflr,temp,press,nx,ny,nz,rl, & 
                              rul,rvl,rwl,rel,rgpgl,rvpvl,pl,rr,rur,rvr, &
                              rwr,rer,rgpgr,rvpvr,pr)
  
  USE moddatatypes
  USE modglobal , ONLY : t_global
  USE modparameters
  USE modtools, ONLY : makenonzero

  USE modinterfaces, ONLY: mixtgasliq_c, &
                           mixtliq_c2_bp, & 
                           mixtperf_c2_grt, &
                           mixtliq_d_dobpppobttto, &
                           mixtperf_d_prt, &
                           mixtperf_t_cveovm2
  IMPLICIT NONE
 
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================
  
  INTEGER, INTENT(IN) :: bcopttype
  REAL(RFREAL), INTENT(IN) :: bp,bt,cvg,cvl,cvv,nx,ny,nz,pl,po,press,rel, & 
                              rg,rgpgl,rl,ro,rul,rv,rvl,rvpvl,rwl,temp,to, &
                              ur,vfgr,vflr,vfvr,vr,wr
  REAL(RFREAL), INTENT(OUT):: pr,rer,rgpgr,rr,rur,rvr,rvpvr,rwr
  TYPE(t_global), POINTER :: global
   
! ==============================================================================
! Locals
! ==============================================================================
  
  REAL(RFREAL) :: bg2i,bg2l,bl2i,bl2l,bv2i,bv2l,cg2i,cg2l,cl2i,cl2l,cmi,cmi2, &
                  cml,cv2i,cv2l,cvmi,cvml,el,rgi,rhogl,rhogr,rholl,rholr, & 
                  rhovl,rhovr,rli,rlpll,rtcvtr,rti,rvi,tl,tr,ul,vfgi,vfgl, &
                  vfli,vfll,vfvi,vfvl,vl,vml2,vmr2,wl 

! ******************************************************************************
! Start
! ******************************************************************************

  rli = mixtliq_d_dobpppobttto(ro,bp,bt,press,po,temp,to)
  rvi = mixtperf_d_prt(press,rv,temp)
  rgi = mixtperf_d_prt(press,rg,temp)

  vfli = vflr 
  vfvi = vfvr 
  vfgi = vfgr 

  cl2i = mixtliq_c2_bp(bp)
  cv2i = mixtperf_c2_grt(1.0_rfreal,rv,temp)
  cg2i = mixtperf_c2_grt(1.0_rfreal,rg,temp)

  bl2i = -bt/bp
  bv2i = rvi*rv
  bg2i = rgi*rg

  rti  = rli*vfli + rvi*vfvi + rgi*vfgi
  cvmi = (rli*vfli*cvl + rvi*vfvi*cvv + rgi*vfgi*cvg)/rti
  cmi  = mixtgasliq_c(cvmi,rti,press,rli,rvi,rgi,vfli,vfvi,vfgi,cl2i, &
                      cv2i,cg2i,bl2i,bv2i,bg2i)
  cmi2 = cmi*cmi
  vmr2 = ur*ur + vr*vr + wr*wr
 
! ==============================================================================
! Supersonic inflow
! ==============================================================================
           
  IF ( vmr2 > cmi2 )  THEN  
    rr    = rti
    rur   = rr*ur
    rvr   = rr*vr
    rwr   = rr*wr
    rer   = rti*cvmi*temp + 0.5_rfreal*rr*vmr2
    rgpgr = rgi*vfgi
    rvpvr = rvi*vfvi
    pr    = press

! ==============================================================================
! Subsonic outflow
! ==============================================================================
     
  ELSE   
    ul = rul/rl
    vl = rvl/rl
    wl = rwl/rl

    vml2  = ul*ul + vl*vl + wl*wl
    rlpll = rl - rvpvl - rgpgl
    cvml  = (rlpll*cvl + rvpvl*cvv + rgpgl*cvg)/rl          
    el    = rel/rl
    tl    = mixtperf_t_cveovm2(cvml,el,vml2)

    rholl = mixtliq_d_dobpppobttto(ro,bp,bt,pl,po,tl,to)
    rhovl = mixtperf_d_prt(pl,rv,tl)
    rhogl = mixtperf_d_prt(pl,rg,tl)

    vfll = rlpll/rholl
    vfvl = rvpvl/rhovl
    vfgl = rgpgl/rhogl

    cl2l = mixtliq_c2_bp(bp)
    cv2l = mixtperf_c2_grt(1.0_rfreal,rv,tl)
    cg2l = mixtperf_c2_grt(1.0_rfreal,rg,tl)

    bl2l = -bt/bp
    bv2l = rhovl*rv
    bg2l = rhogl*rg
    cml  = mixtgasliq_c(cvml,rl,pl,rholl,rhovl,rhogl,vfll,vfvl,vfgl,cl2l, &
                        cv2l,cg2l,bl2l,bv2l,bg2l) 
    pr   = pl + (sqrt(vmr2) - sqrt(vml2))*rl*cml

    rholr = mixtliq_d_dobpppobttto(ro,bp,bt,pr,po,temp,to)
    rhovr = mixtperf_d_prt(pr,rv,temp)
    rhogr = mixtperf_d_prt(pr,rg,temp)

    rr     = rholr*vflr + rhovr*vfvr + rhogr*vfgr
    rtcvtr = rholr*vflr*cvl + rhovr*vfvr*cvv + rhogr*vfgr*cvg
    rer    = rtcvtr*temp + 0.5_rfreal*rr*vmr2
    rur    = rr*ur
    rvr    = rr*vr
    rwr    = rr*wr
    rgpgr  = rhogr*vfgr
    rvpvr  = rhovr*vfvr
  END IF ! vmr2

! ******************************************************************************
! End
! ******************************************************************************
 
END SUBROUTINE bcondinflowperf_gl

! *****************************************************************************
!
! RCS Revision history:
!
! $Log: BcondInflowPerf_GL.F90,v $
! Revision 1.3  2008/12/06 08:44:08  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:22  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2006/03/26 20:20:42  haselbac
! Initial revision
!
! *****************************************************************************