TURB_CalcStrainRate.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute strain rate tensor S_ij from any given velocity gradients.
!
! Description: The strain rate tensors are computed for i, j and k faces.
!
! Input: region  = data of current region
!        ibn,ien = begin and end nodes index
!        grIndx  = ID index of the velocity gradients
!        gradi,j,k  = velocity gradients at i, j and k faces
!
! Output: sRateI,J,K = strain rate tensor at i, j and k faces
!
! Notes: Strain rate values at all nodes are defined.
!        RFLU data structure makes use only of I components arrays.
!
!******************************************************************************
!
! $Id: TURB_CalcStrainRate.F90,v 1.5 2008/12/06 08:44:41 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

#ifdef RFLO
SUBROUTINE turb_calcstrainrate( region,ibn,ien,grIndx,gradi,gradj,gradk, &
                                sratei,sratej,sratek )
#endif
#ifdef RFLU
SUBROUTINE turb_calcstrainrate( region,ibn,ien,grIndx,gradf,sRateI )
#endif

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region
  INTEGER        :: ibn, ien
#ifdef RFLO
  INTEGER        :: grindx(9)
  REAL(RFREAL), POINTER :: gradi(:,:),gradj(:,:),gradk(:,:)
  REAL(RFREAL), POINTER :: sratei(:,:),sratej(:,:),sratek(:,:)
#endif
#ifdef RFLU
  INTEGER        :: grindx(3)
  REAL(RFREAL), POINTER :: gradf(:,:,:)
  REAL(RFREAL), POINTER :: sratei(:,:)
#endif

! ... loop variables
  INTEGER :: in

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  REAL(RFREAL)          :: oo3,div
  REAL(RFREAL)          :: ux,uy,uz,vx,vy,vz,wx,wy,wz

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_CalcStrainRate.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_CalcStrainRate',&
  'TURB_CalcStrainRate.F90' )

  oo3 = 1.0_rfreal/3.0_rfreal

! get strain rate tensor at cell faces --------------------------------------

  DO in = ibn,ien

! - strain rate tensor at I faces

#ifdef RFLO
    ux  = gradi(grindx(1),in)
    vx  = gradi(grindx(2),in)
    wx  = gradi(grindx(3),in)
    uy  = gradi(grindx(4),in)
    vy  = gradi(grindx(5),in)
    wy  = gradi(grindx(6),in)
    uz  = gradi(grindx(7),in)
    vz  = gradi(grindx(8),in)
    wz  = gradi(grindx(9),in)
#endif
#ifdef RFLU
    ux  = gradf(xcoord,grindx(1),in)
    uy  = gradf(ycoord,grindx(1),in)
    uz  = gradf(zcoord,grindx(1),in)
    vx  = gradf(xcoord,grindx(2),in)
    vy  = gradf(ycoord,grindx(2),in)
    vz  = gradf(zcoord,grindx(2),in)
    wx  = gradf(xcoord,grindx(3),in)
    wy  = gradf(ycoord,grindx(3),in)
    wz  = gradf(zcoord,grindx(3),in)
#endif

    div = oo3*(ux+vy+wz)

    sratei(e11,in) = 2.0_rfreal*(ux-div)
    sratei(e12,in) = uy+vx
    sratei(e13,in) = uz+wx

    sratei(e22,in) = 2.0_rfreal*(vy-div)
    sratei(e23,in) = vz+wy

    sratei(e33,in) = 2.0_rfreal*(wz-div)

#ifdef RFLO
! - strain rate tensor at J faces

    ux  = gradj(grindx(1),in)
    vx  = gradj(grindx(2),in)
    wx  = gradj(grindx(3),in)
    uy  = gradj(grindx(4),in)
    vy  = gradj(grindx(5),in)
    wy  = gradj(grindx(6),in)
    uz  = gradj(grindx(7),in)
    vz  = gradj(grindx(8),in)
    wz  = gradj(grindx(9),in)

    div = oo3*(ux+vy+wz)

    sratej(e11,in) = 2.0_rfreal*(ux-div)
    sratej(e12,in) = uy+vx
    sratej(e13,in) = uz+wx

    sratej(e22,in) = 2.0_rfreal*(vy-div)
    sratej(e23,in) = vz+wy

    sratej(e33,in) = 2.0_rfreal*(wz-div)

! - strain rate tensor at K faces

    ux  = gradk(grindx(1),in)
    vx  = gradk(grindx(2),in)
    wx  = gradk(grindx(3),in)
    uy  = gradk(grindx(4),in)
    vy  = gradk(grindx(5),in)
    wy  = gradk(grindx(6),in)
    uz  = gradk(grindx(7),in)
    vz  = gradk(grindx(8),in)
    wz  = gradk(grindx(9),in)

    div = oo3*(ux+vy+wz)

    sratek(e11,in) = 2.0_rfreal*(ux-div)
    sratek(e12,in) = uy+vx
    sratek(e13,in) = uz+wx

    sratek(e22,in) = 2.0_rfreal*(vy-div)
    sratek(e23,in) = vz+wy

    sratek(e33,in) = 2.0_rfreal*(wz-div)
#endif

  ENDDO     ! iN

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_calcstrainrate

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: TURB_CalcStrainRate.F90,v $
! Revision 1.5  2008/12/06 08:44:41  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:53  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2004/05/17 20:32:55  wasistho
! reordering gradIndx for more efficient cache memory addressing
!
! Revision 1.2  2004/03/19 02:44:55  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.1  2002/10/14 23:55:29  wasistho
! Install Rocturb
!
!
!******************************************************************************