RADI_DerivedInputValues.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Set values derived from user input.
!
! Description: Derived variables are set based on user input parameters.
!              Derived variables are components of radiInput data type 
!              (region%radiInput).
!
! Input: regions = input parameters for all regions.
!
! Output: regions = derived variables stored as part of radiInput data.
!
! Notes: Unlike mixture, derived parameters/variables are not necessarily dv.
!
!******************************************************************************
!
! $Id: RADI_DerivedInputValues.F90,v 1.4 2008/12/06 08:44:37 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

#ifdef RFLO
SUBROUTINE radi_derivedinputvalues( regions )
#endif
#ifdef RFLU
SUBROUTINE radi_derivedinputvalues
#endif

  USE moddatatypes
#ifdef RFLO  
  USE moddatastruct, ONLY : t_region
#endif
  USE modglobal, ONLY     : t_global
  USE modradiation, ONLY  : t_radi_input
  USE moderror
  USE modparameters
  USE radi_modparameters
  IMPLICIT NONE

#ifdef RFLO
! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, l, m, n
#endif

! ... local variables
  TYPE(t_global), POINTER     :: global
  TYPE(t_radi_input), POINTER :: input

  INTEGER      :: errorflag, angles(3,2)
  REAL(RFREAL) :: pi, twopi

!******************************************************************************

  global => regions(1)%global
  CALL registerfunction( global,'RADI_DerivedInputValues',&
  'RADI_DerivedInputValues.F90' )

! set local constants ---------------------------------------------------------

  pi    = global%pi
  twopi = 2._rfreal*pi

#ifdef RFLO
! global values ---------------------------------------------------------------

! region related data (all levels) --------------------------------------------

  DO ireg=1,global%nRegions

    IF (regions(ireg)%procid==global%myProcid .AND. &   ! region active and
        regions(ireg)%active==active) THEN              ! on my processor

      input => regions(ireg)%radiInput

! --- Stefan-Boltzman constant
      input%stBoltz = 5.67e-8_rfreal

! --- set logical value of radiUsed

      IF (input%radiModel /= radi_model_none) THEN
        regions(ireg)%mixtInput%radiUsed = .true.
      ENDIF

! --- set number of cv, dv and grad components

      input%nCv   = 0
      input%nGrad = 0 
      IF (input%radiModel == radi_model_fldtran) THEN
        input%nCv   = 1
        input%nGrad = 3
      ENDIF

      input%nDv   = 0
      IF ((input%radiModel /= radi_model_ross)    .AND. &
          (input%radiModel /= radi_model_fldsrc)  .AND. &
          (input%radiModel /= radi_model_fldtran)) THEN
        input%nDv   = 1
      ENDIF

! --- discrete ordinates and/or intensity angles of RTE models

      IF ((input%radiModel == radi_model_rtegray)  .OR. &
          (input%radiModel == radi_model_rteband)) THEN

        IF (input%solMethod == radi_num_dom4) THEN
          input%nOrdin = 4
          input%nAng   = input%nOrdin
        ELSEIF (input%solMethod == radi_num_dom8) THEN
          input%nOrdin = 8          
          input%nAng   = input%nOrdin
        ELSEIF (input%solMethod == radi_num_dom16) THEN
          input%nOrdin = 16          
          input%nAng   = input%nOrdin
        ELSEIF (input%solMethod == radi_num_fvm) THEN
          input%nAng = (input%nPol+1)*(input%nAzi+1)
        ENDIF ! solMethod
      ENDIF   ! radiModel

! --- assign angles read from input file to data structure

      ALLOCATE( input%angles(input%nAng,radi_angle_ncomp),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

      IF ((input%radiModel == radi_model_ross)  .OR. &
          (input%radiModel == radi_model_fldsrc) .OR. &
          (input%radiModel == radi_model_fldtran)) THEN
        READ(input%line(1),*,err=10,end=20) (input%angles(l,radi_angle_polar), &
                                             l=1,input%nAng )  
        READ(input%line(2),*,err=10,end=20) (input%angles(l,radi_angle_azimu), &
                                             l=1,input%nAng )  
        input%angles = input%angles*global%rad 

      ELSEIF ((input%radiModel == radi_model_rtegray)  .OR. &
              (input%radiModel == radi_model_rteband)) THEN
        IF (input%solMethod == radi_num_fvm) THEN
          DO m = 1,input%nPol+1
            DO l = 1,input%nAzi+1
              n = (m-1)*(input%nAzi+1) + l
              input%angles(n,radi_angle_azimu) =   pi*dble(l-1)/dble(input%nAzi)
              input%angles(n,radi_angle_polar) =twopi*dble(m-1)/dble(input%nPol)
            ENDDO
          ENDDO
        ELSE  ! DOM

        ENDIF ! solMethod
      ENDIF   ! radiModel

    ENDIF ! region active and my processor
  ENDDO   ! iReg
  
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )
  goto 999

10   CONTINUE
  CALL errorstop( global,err_file_read,__line__, &
                  'Error in reading real numbers from string' )
20   CONTINUE
  CALL errorstop( global,err_file_read,__line__, &
                  'Number of intensity angles is inconsistent' )

999  CONTINUE

END SUBROUTINE radi_derivedinputvalues

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RADI_DerivedInputValues.F90,v $
! Revision 1.4  2008/12/06 08:44:37  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:49  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2004/09/30 17:10:04  wasistho
! prepared for full FLD radiation model
!
! Revision 1.1  2004/09/22 02:35:49  wasistho
! changed file nomenclature from lower to upper case
!
! Revision 1.6  2004/09/22 01:31:23  wasistho
! switch LFD to FLD for flux limited diffusion
!
! Revision 1.5  2004/09/18 17:41:18  wasistho
! install Limited Flux Diffusion radiation
!
! Revision 1.4  2003/08/01 22:16:10  wasistho
! prepared rocrad for Genx
!
! Revision 1.3  2003/07/23 03:13:49  wasistho
! cured baby illness
!
! Revision 1.2  2003/07/22 03:05:41  wasistho
! include logical write-parameter
!
! Revision 1.1  2003/07/17 01:16:59  wasistho
! initial activation rocrad
!
!
!
!******************************************************************************